Question

我正在尝试使用PHP Toolkit 20.0和Enterprise SOAP API将“机会”批量上传到Salesforce。

我发现这样做的方法是创建一个Opportunity对象，然后通过SOAP API在Salesforce中创建它，然后在响应中我使用Id并将其用于每个1..n OpportunityLineItems那个机会存在。

这不是非常有效，因为它使用2个SOAP API调用，并且当批量使用时会占用大量资源并且容易超时。（由于API调用有限，我不想一次性减少发送的金额）

因此，有没有办法在单个API调用中创建Opportunity及其OpportunityLineItems？

我尝试了以下内容：

$opp = new stdClass();
$opp->Name = 'Opp1';
$opp->StageName = 'Closed Won';
$opp->Account = new stdClass();
$opp->Account->Custom_ID__c = '1234';
$opp->Pricebook2Id = '...'; 
$opp->OpportunityLineItems = array();
$opp->OpportunityLineItems[0] = new stdClass();
$opp->OpportunityLineItems[0]->Description = 'Product name';
$opp->OpportunityLineItems[0]->Quantity = 1;
$opp->OpportunityLineItems[0]->UnitPrice = 10.00;
...
$opp->OpportunityLineItems[n] = new stdClass();
$opp->OpportunityLineItems[n]->Description = 'Product name';
$opp->OpportunityLineItems[n]->Quantity = 1;
$opp->OpportunityLineItems[n]->UnitPrice = 10.00;

但结果是：
INVALID_FIELD: No such column 'OpportunityLineItems' on entity 'Opportunity'. If you are attempting to use a custom field, be sure to append the '__c' after the custom field name. Please reference your WSDL or the describe call for the appropriate names.
由于WSDL文件声明OpportunityLineItems的类型为tns:QueryResult而不是ens:

，因此可以预期

Answer 1

编辑：完成大修以显示如何同时添加多个opps。如果你能以某种方式错开他们的创作（将它们存储在你的本地数据库中，只有当你有一些/足够的时间已经过去/用户按下“刷新队列”按钮）时应该是有用的。

警告，现在代码实际上看起来更可怕，您可能最好首先在编辑历史记录中检查previous version。

创建一个接受带有2个参数的传入请求并尝试插入它们的Apex类并不会太难。转到设置 - ＆gt;开发 - ＆gt;类 - ＆gt;新建并试试这个：

global with sharing class OpportunityLinkedInsert{

    static webservice Opportunity insertSingle(Opportunity opp, OpportunityLineItem[] lines){
        if(opp == null || lines == null){
            throw new IntegrationException('Invalid data');
        }
        Opportunity[] result = insertMultiple(new List<Opportunity>{opp}, new List<List<OpportunityLineItem>>{lines});
        return result[0]; // I imagine you want the Id back :) 
    }

    /*  I think SOAP doesn't handle method overloading well so this method has different name.
        'lines' are list of lists (jagged array if you like) so opps[i] will be inserted and then lines[i] will be linked to it etc.

        You can insert up to 10,000 rows in one go with this function (remember to count items in both arrays).
    */
    static webservice List<Opportunity> insertMultiple(List<Opportunity> opps, List<List<OpportunityLineItem>> lines){
        if(opps == null || lines == null || opps.size() == 0 || opps.size() != lines.size()){
            throw new IntegrationException('Invalid data');
        }
        insert opps;

        // I need to flatten the structure before I insert it.
        List<OpportunityLineItem> linesToInsert = new List<OpportunityLineItem>();

        for(Integer i = 0; i < opps.size(); ++i){
            List<OpportunityLineItem> linesForOne = lines[i];
            if(linesForOne != null && !linesForOne.isEmpty()){
                for(Integer j = 0; j < linesForOne.size(); ++j){
                    linesForOne[j].OpportunityId = opps[i].Id;
                }
                linesToInsert.addAll(linesForOne);
            }
        }
        insert linesToInsert;
        return opps;
    }

    // helper class to throw custom errors
    public class IntegrationException extends Exception{}
}

在进入生产组织之前，您还需要一个单元测试课程。这样的事情应该做（在100％可用之前需要填充更多的东西，see this question for more info）。

@isTest
public class OpportunityLinkedInsertTest{
    private static List<Opportunity> opps;
    private static List<List<OpportunityLineItem>> items;

    @isTest
    public static void checSingleOppkErrorFlow(){
        try{
            OpportunityLinkedInsert.insertSingle(null, null);
            System.assert(false, 'It should have failed on null values');
        } catch(Exception e){
            System.assertEquals('Invalid data',e.getMessage());
        }
    }

    @isTest
    public static void checkMultiOppErrorFlow(){
        prepareTestData();
        opps.remove(1);

        try{
            OpportunityLinkedInsert.insertMultiple(opps, items);
            System.assert(false, 'It should have failed on list size mismatch');
        } catch(Exception e){
            System.assertEquals('Invalid data',e.getMessage());
        }
    }

    @isTest
    public static void checkSuccessFlow(){
        prepareTestData();
        List<Opportunity> insertResults = OpportunityLinkedInsert.insertMultiple(opps, items);

        List<Opportunity> check = [SELECT Id, Name, 
            (SELECT Id FROM OpportunityLineItems) 
            FROM Opportunity 
            WHERE Id IN :insertResults 
            ORDER BY Name];
        System.assertEquals(items[0].size(), check[0].OpportunityLineItems.size(), 'Opp 1 should have 1 product added to it');
        System.assertEquals(items[1].size(), check[0].OpportunityLineItems.size(), 'Opp 3 should have 1 products');
    }

    // Helper method we can reuse in several tests. Creates 2 Opportunities with different number of line items.
    private static void prepareTestData(){
        opps = new List<Opportunity>{
            new Opportunity(Name = 'Opp 1', StageName = 'Prospecting', CloseDate = System.today() + 10),
            new Opportunity(Name = 'Opp 2', StageName = 'Closed Won', CloseDate = System.today())
        };

        // You might have to fill in more fields here!
        // Products are quite painful to insert with all their standard/custom pricebook dependencies etc...
        items = new List<List<OpportunityLineItem>>{
            new List<OpportunityLineItem>{
                new OpportunityLineItem(Description = 'Opp 1, Product 1', Quantity = 1, UnitPrice = 10)
            },
            new List<OpportunityLineItem>{
                new OpportunityLineItem(Description = 'Opp 2, Product 1', Quantity = 1, UnitPrice = 10),
                new OpportunityLineItem(Description = 'Opp 2, Product 2', Quantity = 1, UnitPrice = 10),
                new OpportunityLineItem(Description = 'Opp 2, Product 3', Quantity = 1, UnitPrice = 10)
            }
        };
    }
}

这几乎与Apex代码有关。

如果任一插入失败，您将收到SOAP异常。在事务，ACID等方面，这也有所改善 - 如果您的订单项的插入失败，您是否准备从PHP端清理它？如果在Salesforce中设置了一些自动电子邮件通知等并已发送，该怎么办？在Apex的一次调用中，它将确保整个请求将被回滚，就像存储过程在数据库中工作一样。

尝试在沙箱中创建这些类，然后在类列表中找到第一个类。它将具有生成WSDL文件的链接，您可以使用该文件生成PHP类。转到第二个，您将看到“运行测试”按钮。在将测试推送到生产组织之前，您必须确保测试通过 - 但这对您来说是programming on the platform的全新世界：）

Salesforce：将OpportunityLineItems创建为PHP中的Opportunity的一部分

1 个答案: