Question

将动态xml数据解析为html表时遇到问题。 XML如下。

<results>
  <result id="1" desc="Voltage and current">
    <measure desc="VOLT" value="1.0" />
    <measure desc="AMPERE" value="2.0" />
  </result>
  <result id="2" desc="Current-1">
    <measure desc="AMPERE" value="5.0" />
  </result>
</results>

我想要一个html表，如：

ID   DESC                VOLT   AMPERE
1    Voltage and current 1.0    2.0
2    Current-1                  5.0

注意第二个电压列的空单元格。 ID和DESC取自result / @ id和result / @desc，其余列名应来自measure / @desc

没有列名应该重复，我设法编写了那么远，但是当我开始添加我的度量时，我需要将每个度量/ @desc与表中的正确列匹配。我尝试使用双嵌套循环来首先匹配所有唯一列名，然后再次循环所有度量以匹配列标题。但xslt解析器向我扔了一个NPE！很抱歉，我无法在未连接的计算机上显示任何代码。

我在SO上浏览了这么多Q / A但对我的具体问题没有任何帮助。

提前致谢

注意：我能够以任何方式更改XML格式，以便在任何人提出更整洁的格式时更容易解析。

Answer 1

如果您使用的是XSLT1.0，则可以使用一种名为“Muenchian”分组的技术来获取不同的度量描述，这些描述将形成头行的基础，并且还可用于输出每行的值。

首先，您可以通过 @desc 属性

定义用于查找度量元素的键

<xsl:key name="measures" match="measure" use="@desc" />

然后，要获得不同的度量描述，您可以迭代组中首先出现的度量元素，用于给定的 @desc 属性

<xsl:apply-templates 
   select="result/measure[generate-id() = generate-id(key('measures', @desc)[1])]"
   mode="header" />

然后，对于标题，您只需要一个模板来输出描述。

<xsl:template match="measure" mode="header">
   <th>
      <xsl:value-of select="@desc" />
   </th>
</xsl:template>

对于每个结果行，会执行类似的操作，并迭代所有不同的度量值，但唯一的区别是您必须传递当前的结果 element作为参数，供以后使用。

<xsl:apply-templates 
   select="/results/result/measure[generate-id() = generate-id(key('measures', @desc)[1])]" 
   mode="data">
  <xsl:with-param name="result" select="." />
</xsl:apply-templates>

然后，在此次匹配度量的模板中，您可以使用匹配的 @desc 访问结果元素中的度量属性（和id没有这样的属性，没有输出任何单元格）

<xsl:template match="measure" mode="data">
   <xsl:param name="result" />
   <td>
      <xsl:value-of select="$result/measure[@desc = current()/@desc]/@value" />
   </td>
</xsl:template>

这是完整的XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>
   <xsl:key name="measures" match="measure" use="@desc" />

   <xsl:template match="/results">
      <table>
         <tr>
            <th>ID</th>
            <th>DESC</th>
            <xsl:apply-templates select="result/measure[generate-id() = generate-id(key('measures', @desc)[1])]" mode="header" />
         </tr>
         <xsl:apply-templates select="result" />
      </table>
   </xsl:template>

   <xsl:template match="result">
      <tr>
         <td><xsl:value-of select="@id" /></td>
         <td><xsl:value-of select="@desc" /></td>
         <xsl:apply-templates select="/results/result/measure[generate-id() = generate-id(key('measures', @desc)[1])]" mode="data">
            <xsl:with-param name="result" select="." />
         </xsl:apply-templates>
      </tr>
   </xsl:template>

   <xsl:template match="measure" mode="header">
      <th>
         <xsl:value-of select="@desc" />
      </th>
   </xsl:template>

   <xsl:template match="measure" mode="data">
      <xsl:param name="result" />
      <td>
         <xsl:value-of select="$result/measure[@desc = current()/@desc]/@value" />
      </td>
   </xsl:template>
</xsl:stylesheet>

请注意使用模式属性，因为您有两个与度量元素匹配的模板，这些模板以不同的方式运行。

当应用于输入XML时，输出以下内容

<table>
   <tr>
      <th>ID</th>
      <th>DESC</th>
      <th>VOLT</th>
      <th>AMPERE</th>
   </tr>
   <tr>
      <td>1</td>
      <td>Voltage and current</td>
      <td>1.0</td>
      <td>2.0</td>
   </tr>
   <tr>
      <td>2</td>
      <td>Current-1</td>
      <td/>
      <td>5.0</td>
   </tr>
</table>

将动态XML解析为html表

1 个答案: