Question

我遇到以下脚本的问题，我们希望将其用作登录脚本的一部分，以检查软件是否已安装，如果没有，请安装它：

:STEP1
for /f "delims= " %%a in (C:\software-dist.txt) do (
if "%%a"=="Softwarename1" goto STEP2
)
\\server\share\software1.exe
echo Softwarename1 >> C:\software-dist.txt

:STEP2
for /f "delims= " %%a in (C:\software-dist.txt) do (
if "%%a"=="Software name 2" goto END
)
\\server\share\software2.exe /Q
echo Software name 2 >> C:\software-dist.txt

:END

代码是STEP1工作得很好 - 这里软件的名称只有一个单词“ Softwarename1 ”。但是，STEP2中的代码不起作用 - 此处软件的名称被写为3个单独的单词“软件名称2 ”（每个单词之间的空格）。每次运行脚本时， c：\ software-dist.txt 都会使用另一行“软件名称2 ”进行更新。

任何想法我做错了什么？

Answer 1

lc在他的评论中指出了这个问题，但没有明确提供明显的解决方案。

您正在将标记分隔符设置为空格。您需要使用"DELIMS="禁用DELIMS选项。

for /f "delims=" %%a in (C:\software-dist.txt) do ...

此外，您的ECHO语句末尾有一个额外的空格，导致该行在以后再次测试时不匹配。如果删除空格，则将2视为stderr的句柄。一个解决方法是添加括号。

(echo Software name 2) >> C:\software-dist.txt

但是有一个更简单，更快速的解决方案。您可以使用FINDSTR确定文件中是否存在特定行。

:Step1
>nul findstr /xc:"Softwarename1" "C:\software-dist.txt" || (
  "\\server\share\%%F"
  >>"C:\software-dist.txt%" echo Softwarename1
)

:Step2
>nul findstr /xc:"Software name 2" "C:\software-dist.txt" || (
  "\\server\share\%%F"
  >>"C:\software-dist.txt%" echo Software name 2
)

通过添加变量和FOR循环，代码更短，更易于维护。

set "file=C:\software-dist.txt"
for %%F in ("Softwarename1" "Software name 2") do (
  >nul findstr /xc:%%F "%file%" || (
    "\\server\share\%%~F"
    (echo %%~F)>>"%file%"
  )
)

软件安装脚本

1 个答案: