我有一个String，我需要将每个单词的第一个字母转换为大写，并使用xsl将其转换为小写，例如，
输入字符串= dInEsh sAchdeV kApil Muk
期望输出字符串= Dinesh Sachdev Kapil Muk
虽然，我知道我必须使用翻译功能，但是如何将每个单词的第一个章程翻译成大写字母，并使用XSLT 1.0将其全部翻译成小写
由于
答案 0 :(得分：13)
以下不是“好”，我确信有人（主要是Dimitri）可以提出更简单的东西（特别是在XSLT 2.0中）......但我tested this and it works
<xsl:template name="CamelCase">
<xsl:param name="text"/>
<xsl:choose>
<xsl:when test="contains($text,' ')">
<xsl:call-template name="CamelCaseWord">
<xsl:with-param name="text" select="substring-before($text,' ')"/>
</xsl:call-template>
<xsl:text> </xsl:text>
<xsl:call-template name="CamelCase">
<xsl:with-param name="text" select="substring-after($text,' ')"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:call-template name="CamelCaseWord">
<xsl:with-param name="text" select="$text"/>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template name="CamelCaseWord">
<xsl:param name="text"/>
<xsl:value-of select="translate(substring($text,1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ')" /><xsl:value-of select="translate(substring($text,2,string-length($text)-1),'ABCDEFGHIJKLMNOPQRSTUVWXYZ','abcdefghijklmnopqrstuvwxyz')" />
</xsl:template>
基本的想法是你调用CamelCase，如果它找到一个空格，那么它在空格（即第一个单词）之前的所有上运行CamelCaseWord然后再次使用之后的所有内容（即句子的其余部分）调用CamelCase。否则，如果没有找到空格（因为它已经到了句子中的最后一个单词），那么它只是调用CamelCaseWord。
CamelCaseWord模板只是将第一个字符从低层翻译为高层（如有必要），将所有剩余字符从高层翻译为低层（如有必要）。
所以称之为你......
<xsl:call-template name="CamelCase">
<xsl:with-param name="text">dInEsh sAchdeV kApil Muk</xsl:with-param>
</xsl:call-template>
答案 1 :(得分：4)
其他
我错过了问题中的1.0要求。这只适用于2.0版本。
下面的原始答案。
我相信这一段时间对我有用。声明一个函数：
<xsl:function name="my:titleCase" as="xs:string">
<xsl:param name="s" as="xs:string"/>
<xsl:choose>
<xsl:when test="lower-case($s)=('and','or')">
<xsl:value-of select="lower-case($s)"/>
</xsl:when>
<xsl:when test="$s=upper-case($s)">
<xsl:value-of select="$s"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="concat(upper-case(substring($s, 1, 1)), lower-case(substring($s, 2)))"/>
</xsl:otherwise>
</xsl:choose>
</xsl:function>
并使用它：
<xsl:sequence select="string-join(for $x in tokenize($text,'\s') return my:titleCase($x),' ')"/>
归功于 samjudson =＆gt; http://p2p.wrox.com/xslt/80938-title-case-string.html
答案 2 :(得分：3)
这是一个8岁的FXSL 1.x（一个完全用XSLT 1.0编写的XSLT 1.0库）解决方案：
测试strSplit到Words10.xsl：
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ext="http://exslt.org/common"
>
<xsl:import href="strSplitWordDel.xsl"/>
<!-- To be applied on: test-strSplit-to-Words10.xml -->
<xsl:output indent="yes" omit-xml-declaration="yes"/>
<xsl:variable name="vLower"
select="'abcdefgijklmnopqrstuvwxyz'"/>
<xsl:variable name="vUpper"
select="'ABCDEFGIJKLMNOPQRSTUVWXYZ'"/>
<xsl:template match="/">
<xsl:variable name="vwordNodes">
<xsl:call-template name="str-split-word-del">
<xsl:with-param name="pStr" select="/"/>
<xsl:with-param name="pDelimiters"
select="', .(	 '"/>
</xsl:call-template>
</xsl:variable>
<xsl:apply-templates select="ext:node-set($vwordNodes)/*"/>
</xsl:template>
<xsl:template match="word">
<xsl:choose>
<xsl:when test="not(position() = last())">
<xsl:value-of
select="translate(substring(.,1,1),$vLower,$vUpper)"/>
<xsl:value-of select="substring(.,2)"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="."/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="delim">
<xsl:value-of select="."/>
</xsl:template>
</xsl:stylesheet>
将此转换应用于以下XML文档（test-strSplit-to-Words10.xml）时：
<t>004.lightning crashes (live).mp3</t>
结果是：
004.Lightning Crashes (Live).mp3
应用于此XML文档（您提供的示例）：
dInEsh sAchdeV kApil Muk
结果是：
DInEsh SAchdeV KApil Muk
只需一点点，我们就可以获得此代码：
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ext="http://exslt.org/common"
>
<xsl:import href="strSplitWordDel.xsl"/>
<!-- To be applied on: test-strSplit-to-Words10.xml -->
<xsl:output indent="yes" omit-xml-declaration="yes"/>
<xsl:variable name="vLower"
select="'abcdefgijklmnopqrstuvwxyz'"/>
<xsl:variable name="vUpper"
select="'ABCDEFGIJKLMNOPQRSTUVWXYZ'"/>
<xsl:template match="/">
<xsl:variable name="vwordNodes">
<xsl:call-template name="str-split-word-del">
<xsl:with-param name="pStr" select="/"/>
<xsl:with-param name="pDelimiters"
select="', .(	 '"/>
</xsl:call-template>
</xsl:variable>
<xsl:apply-templates select="ext:node-set($vwordNodes)/*"/>
</xsl:template>
<xsl:template match="word">
<xsl:value-of
select="translate(substring(.,1,1),$vLower,$vUpper)"/>
<xsl:value-of select="translate(substring(.,2), $vUpper, $vLower)"/>
</xsl:template>
<xsl:template match="delim">
<xsl:value-of select="."/>
</xsl:template>
</xsl:stylesheet>
现在产生想要的结果：
Dinesh Sachdev Kapil Muk
<强>解释：
FXSL 的str-split-word-del模板可用于标记为（可能多于一个）分隔符指定为字符串参数。
答案 3 :(得分：2)
你也可以试试这个：
http://www.xsltfunctions.com/xsl/functx_camel-case-to-words.html
<xsl:function name="functx:words-to-camel-case" as="xs:string"
xmlns:functx="http://www.functx.com">
<xsl:param name="arg" as="xs:string?"/>
<xsl:sequence select="
string-join((tokenize($arg,'\s+')[1],
for $word in tokenize($arg,'\s+')[position() > 1]
return functx:capitalize-first($word))
,'')
"/>
</xsl:function>
并向后： http://www.xsltfunctions.com/xsl/functx_words-to-camel-case.html
scp答案 4 :(得分：1)
这是另一个简短的解决方案。它使用纯XSL-T 2.0。我知道OP需要XSL-T 1.0，但由于这个页面在Google上排名第一，因为xsl-t标题案例功能＆＃39;在2015年，这似乎更相关：
<xsl:function name="xx:fixCase">
<xsl:param name="text" />
<xsl:for-each select="tokenize($text,' ')">
<xsl:value-of select="upper-case(substring(.,1,1))" />
<xsl:value-of select="lower-case(substring(.,2))" />
<xsl:if test="position() ne last()">
<xsl:text> </xsl:text>
</xsl:if>
</xsl:for-each>
</xsl:function>
哪里＆＃39; xx＆＃39;是你自己的命名空间。
答案 5 :(得分：0)
XQUERY上的这个功能：
将Xquery函数用于Camel案例。
declare function xf:toCamelCase($text as xs:string?) as xs:string{
if(contains($text,' ')) then
fn:concat(xf:CamelCaseWord(substring-before($text,' ')),' ', xf:toCamelCase(substring-after($text,' ')))
else
xf:CamelCaseWord($text)
};
declare function xf:CamelCaseWord($text as xs:string?) as xs:string{
fn:concat( translate(substring($text,1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ'),
translate(substring($text,2,string-length($text)-1),'ABCDEFGHIJKLMNOPQRSTUVWXYZ','abcdefghijklmnopqrstuvwxyz'))
};
答案 6 :(得分：0)
一个非常简短的解决方案，利用EXSLT的split()函数：
<xsl:variable name='text' select='"dInEsh sAchdeV kApil Muk"' />
<xsl:variable name='lowers' select='"abcdefghijklmnopqrstuvwxyz"' />
<xsl:variable name='uppers' select='"ABCDEFGHIJKLMNOPQRSTUVWXYZ"' />
<xsl:template match="/">
<xsl:for-each select='str:split($text, " ")'>
<xsl:value-of select='concat(
translate(substring(., 1, 1), $lowers, $uppers),
translate(substring(., 2), $uppers, $lowers),
" "
)' />
</xsl:for-each>
</xsl:template>
答案 7 :(得分：0)
可以使用单行表达式来实现。 试试这个
string-join(for $x in tokenize($text,'\s') return concat(upper-case(substring($x, 1, 1)), lower-case(substring($x, 2))),' ')
注意-已通过Orbeon Forms公式进行了验证。