Question

仅仅为了我自己的教育，有什么简洁的方法来转换一些数组，以便每个数组都与哈希的键相关联，所有这些哈希最终都在一个数组中？

为了让事情更清楚，假设我有一些像这样的数组：

my @n = ( 1,    2,    3 );
my @f = ( 3.14, 1.21, 0.75 );
my @s = ( 'a',  'b',  'c' );

我想要一组看起来像这样的哈希：

my %h = ( number => 1, float => 3.14, string => 'a' );

简单的C风格迭代是一个显而易见的解决方案：

for ( my $i = 0; $i < @n; $i++ ) {
    my %h = ();
    $h{number} = $n[$i];
    $h{float}  = $f[$i];
    $h{string} = $s[$i];
    push @a, \%h;
}

略微更多Perlish：

for (0..$#n) {
    push @c, { number => $n[$_], float => $f[$_], string => $s[$_] };
}

或者如果我想要简洁而不关心破坏数组：

for (0..$#n) {
    push @a, { number => shift @n, float => shift @f, string => shift @s };
}

使用List::MoreUtils：

use List::MoreUtils qw (each_array);
my $it = each_array @n, @f, @s;
while ( my ($n, $f, $s) = $it->() ) {
    push @a, { number => $n, float => $f, string => $s };
}

因此，根据TMTOWTDI的精神，我缺少哪些其他解决方案？

Answer 1

使用切片不可读：

@{ $d[$_] }{qw/number float string/} = ($n[$_], $f[$_], $s[$_]) for 0 .. $#n;

Answer 2

my @array = map { number => $n[$_], float => $f[$_], string => $s[$_] }, 0 .. $#n;

我不是Perl家伙，只是一个建议：）

Answer 3

此程序可满足您的需求

use strict;
use warnings;

my @n = ( 1,    2,    3 );
my @f = ( 3.14, 1.21, 0.75 );
my @s = ( 'a',  'b',  'c' );

my @data;
for my $i (0 .. $#n) {
  @{$data[$i]}{ qw/ number float string / } = map $_->[$i], \(@n, @f, @s);
}

use Data::Dump;
dd \@data;

<强>输出

[
  { float => 3.14, number => 1, string => "a" },
  { float => 1.21, number => 2, string => "b" },
  { float => 0.75, number => 3, string => "c" },
]

或者您可能更喜欢使用List::MoreUtils库的each_array函数的解决方案。该程序的输出与我之前的解决方案相同。

use strict;
use warnings;

use List::MoreUtils 'each_array';

my @n = ( 1,    2,    3 );
my @f = ( 3.14, 1.21, 0.75 );
my @s = ( 'a',  'b',  'c' );

my $iter = each_array(@n, @f, @s);
my @data;
while ( my @values = $iter->() ) {
  my $i = $iter->('index');
  @{ $data[$i] }{ qw/ number float string / } = @values;
}

use Data::Dump;
dd \@data;

Answer 4

这使用List::MoreUtils

中的一些实用程序

mesh集成数组列表
part分区数组

来自_POSINT的Params::Util来判断是否。{3}} next参数是一个正整数。

use List::MoreUtils qw<mesh part>; # integrate and partition arrays
use Params::Util    qw<_POSINT>;   # test number positive

# accept size number if positive int, otherwise we will be returning pairs. 
sub by (@) { 
   my $num = &_POSINT ? shift : 2;
   my $i   = -1;
   return part { int( ++$i / $num ) } @_;
}

my @n      = qw< 1    2    3 >;
my @f      = qw< 3.14 1.21 0.75 >;
my @s      = qw< a    b    c >;
my @fields = qw<number float string>;

my @results = map { +{ mesh @fields, @$_ } } by 3 => mesh @n, @f, @s;

当然，使用它，你可以像这样列出数据：

my @results 
    = map { +{ mesh @fields, @$_ } } 
      by 3 => qw< 1 3.14 a
                  2 1.21 b
                  3 0.75 c
                >
    ;

跳过第一个mesh。布局指示数据的结构（就像代码一样。）

将数组元素放入Perl中的哈希数组中

4 个答案: