Question

让 n 为整数， A = {2,3，...，10}，我想按以下步骤操作：

将 n 除以2，因此有提醒 r ₂和商 q _{2 。}
将 q ₂除以3，因此提醒 r ₃和商 q <子> 3 。
我们重复此操作，直到商数小于下一个数字。
将最后一个商与先前的提醒一起写下来。

例如n = 45

45/2 .......    r_2=1, q_2=22
22/3 .......    r_3=1, q_3=7
 7/4 .......    r_4=3, q_4=1

因为 q ₄ = 1小于下一个数字，即5，我们休息。

结果是 q ₄ r ₄ r ₃ r ₂，等于1311。

感谢您的帮助。

我做了这个，但它不起作用

n = 45;
i = 2;
list = {Mod[n, i]};

While[Quotient[n, i] >= i + 1, n == Quotient[n, i]; i++; 
   AppendTo[list, Mod[n, i]];
   If[Quotient[n, i] < i + 1, Break[]]; AppendTo[list, Quotient[n, i]]];

list
Row[Reverse[list]]

给出了

{1, 0, 15, 1, 11, 0, 9, 3, 7, 3}
Row[{3, 7, 3, 9, 0, 11, 1, 15, 0, 1}]

这不是我想要的结果。

Answer 1

您可以使用以下内容：

f[n_Integer] := 
 NestWhileList[
   {QuotientRemainder[#[[1, 1]], #[[2]] + 1], #[[2]] + 1} &,
   {{n}, 1},
   #[[1, 1]] != 0 &
 ] // Rest

f[45]

{{{22, 1}, 2}, {{7, 1}, 3}, {{1, 3}, 4}, {{0, 1}, 5}}

您可以使用Part获取所需的任何输出位。

如果您可以处理语法，这是一种更高级的方法：

f2[n_Integer]    := Reap[f2[{n, 0}, 2]][[2, 1, 2 ;;]] // Reverse

f2[{q_, r_}, i_] := f2[Sow @ r; QuotientRemainder[q, i], i + 1]

f2[{0, r_}, i_]  := Sow @ r

f2[45]

{1, 3, 1, 1}

Answer 2

这是代码：

A = Table[i, {i, 2, 10}]; (* array of numbers *)
n = 45; (* initial value *)
ans = {}; (* future answer which is now empty list *)
For[i = 1, i <= Length[A], i++, (* looping over A *)
 If[n < A[[i]], (* exit condition *)
  ans = Append[ans, n]; (* appending last n when exit *)
  Break[]
  ];
 qr = QuotientRemainder[n, A[[i]]]; (* calculating both quotient and reminder *)
 ans = Append[ans, qr[[2]]]; (* adding second member to the answer *)
 Print[qr]; (* printing *)
 n = qr[[1]]; (* using first member as new n to process *)
 ];
ans (* printing result in Mathematica manner *)

它给出了

{1, 1, 3, 1}

将数字转换为mathematica中的变量库

2 个答案: