Question

我正在寻找关于如何最好地处理我的问题的一些指导。

我有一个类似于以下的XML文档，但规模较大。

<NewDataSet>
  <Table Attri1="Attri1Val" Attri2="Attri2Val" Attri3="Attri3Val" Attri4="Attri4Val" Attri5="Attri5Val" Attri6="Attri6Val" Attri7="Attri7" />
</NewDataSet>

我需要将Table节点中的某些属性（例如Attri2和Attri5）移动到Table节点中的元素中，但是我需要保留其余的属性。

最好的方法是什么？数据比例大约是显示的3-4倍。

编辑：预期产出：

<NewDataSet>
  <Table Attri1="Attri1Val" Attri3="Attri3Val" Attri4="Attri4Val" Attri6="Attri6Val" Attri7="Attri7">
    <Attri2>Attri2Val</Attri2>
    <Attri5>Attri5Val</Attri5>
  </Table>
</NewDataSet>

复杂性不是真正的问题，更多的是数据的规模以及处理它的最佳方式。

Answer 1

使用

<xsl:template match="@* | node()">
  <xsl:copy>
     <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="Table">
  <xsl:copy>
    <xsl:apply-templates select="@*[not(name() = 'Attri2') and not(name() = 'Attri5')]"/>
     <xsl:apply-templates select="@Attri2 | @Attri5 | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="Table/@Attri2 | Table/@Attri5">
 <xsl:element name="{name()}">
   <xsl:value-of select="."/>
 </xsl:element>
</xsl:template>

[编辑] 属性的名称比较有点难看，但可能会对您的样本有所帮助。我们真正需要的是@* execpt (@Attri2, @Attri5)，只有XPath 2.0。使用XPath 1.0，等价物是

<xsl:template match="Table">
  <xsl:copy>
    <xsl:variable name="all-attributes" select="@*"/>
    <xsl:variable name="to-be-transformed" select="@Attri2 | @Attri5"/>
    <xsl:apply-templates select="$all-attributes[count(. | $to-be-transformed) != count($to-be-transformed)]"/>
     <xsl:apply-templates select="$to-be-transformed | node()"/>
  </xsl:copy>
</xsl:template>

Answer 2

此通用转换可以处理任何长度的属性集，其名称可以在转换外部指定：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pToTransform" select="'|Attri2|Attri5|'"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="Table">
  <xsl:copy>
      <xsl:apply-templates select=
         "@*[not(contains($pToTransform, concat('|',name(),'|')))] | node()"/>
      <xsl:apply-templates mode="makeElement"
        select="@*[contains($pToTransform, concat('|',name(),'|'))]"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="@*" mode="makeElement">
  <xsl:element name="{name()}" namespace="{namespace-uri()}">
   <xsl:value-of select="."/>
  </xsl:element>
 </xsl:template>
</xsl:stylesheet>

将此转换应用于提供的XML文档时：

<NewDataSet>
    <Table Attri1="Attri1Val" Attri2="Attri2Val"
    Attri3="Attri3Val" Attri4="Attri4Val"
    Attri5="Attri5Val" Attri6="Attri6Val"
    Attri7="Attri7" />
</NewDataSet>

产生了想要的正确结果：

<NewDataSet>
   <Table Attri1="Attri1Val" Attri3="Attri3Val" Attri4="Attri4Val" Attri6="Attri6Val" Attri7="Attri7">
      <Attri2>Attri2Val</Attri2>
      <Attri5>Attri5Val</Attri5>
   </Table>
</NewDataSet>

XSLT - 移动特定属性的最佳实践

2 个答案: