Question

这里我有一个actionscript3代码，我在其中创建一个对象数组。基本上在数组中是同一对象的多个实例。我想创建一个事件监听器，它调用一个将对象旋转90度的函数f0。我的问题是我找不到一种方法来为数组中的每个对象设置唯一标识符，所以当我单击一个对象时，我希望它旋转，但只有数组的第一个元素旋转。我还希望将旋转居中，以便对象不会在（0,0）中旋转。

package
{
import flash.display.Graphics;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
import flash.geom.ColorTransform;
import flash.geom.Matrix;
import flash.geom.Point;
import flash.geom.ColorTransform;

public class Main extends Sprite
{
    var array = new Array();
    var i:int;


    public function Main():void
    {
        if (stage) init();
        else addEventListener(Event.ADDED_TO_STAGE, init);
    }



private function init(e:Event = null):void
    {

        for (var i:int = 0; i < 10; i++)
        {
            var asd:Sprite = new Sprite();
            asd.graphics.beginFill(0x0000ff);
            asd.graphics.drawRect(0, 0, 60, 60);
            array.push(asd);
            addChild(array[i]);
            array[i].x = 60 * i ;
            array[i].y = 60 * i ;
            array[i].addEventListener(MouseEvent.CLICK, f0);
            if (i % 2 == 0) {
            asd.graphics.lineTo(asd.x + 60, asd.y + 60);
            }
            removeEventListener(Event.ADDED_TO_STAGE, init);
        }
    }
private function f0(e:Event):void
    {
        array[i].rotation += 90;
    }
}

}

Answer 1

event.target指向添加了事件处理程序的对象，您可以使用它来旋转正确的精灵。

private function init(e:Event = null):void 
{
    for (var i:int = 0; i < 10; i++) 
    {
       createObject(i);
    }
}

private function createObject(index:int):void
{
    var asd:Sprite = new Sprite(); 
    asd.graphics.beginFill(0x0000ff); 
    asd.graphics.drawRect(0, 0, 60, 60); 
    array.push(asd); 
    addChild(asd); 
    array[index].x = 60 * index ;
    array[index].y = 60 * index ;
    array[index].addEventListener(MouseEvent.CLICK, f0);
    if (index % 2 == 0) { 
       asd.graphics.lineTo(asd.x + 60, asd.y + 60);
    }

}

private function f0(e:Event):void
{
    e.target.rotation += 90; 
}

要围绕它的中心旋转对象，您可以执行以下操作：

private function rotateAroundCenter (ob:DisplayObject, angleDegrees:Number):void
{
    var matrix:Matrix = ob.transform.matrix; 

    var rect:Rectangle = ob.getBounds(this.parent); 

    matrix.translate(- (rect.left + (rect.width/2)), - (rect.top + (rect.height/2))); 

    matrix.rotate((angleDegrees/180)*Math.PI); 

    matrix.translate(rect.left + (rect.width / 2), rect.top + (rect.height / 2));

    ob.transform.matrix = matrix;
}

这会将对象中心转换为（0,0）旋转它，然后将对象转换回它的原始位置。它仅在对象具有父对象且宽度高度不为零时才有效。

在actionscript3中为对象数组分配唯一标识符

1 个答案: