Question

我知道这是一个坏主意的所有原因。如果一个应用程序窃取输入焦点我不喜欢它，但这纯粹是个人使用，我希望它发生;它不会打扰任何东西。

（好奇：我在NetBeans中运行单元测试，生成日志文件。当我的后台应用程序看到日志文件的时间戳更改时，我希望它解析日志文件并转到前面显示结果）

This question没有帮助，也没有谷歌搜索。 BringToFront()似乎没有工作很长时间，我找不到任何替代方案。

有什么想法吗？

Answer 1

这里有一些简单的功能，可以使用XP，Server2003，Vista，Server2008，W7等多个盒子进行测试。测试应用程序使用标准（或管理员）帐户运行，在前台写入时从记事本中窃取输入焦点。

var
  Input: TInput;
begin
  ZeroMemory(@Input, SizeOf(Input));
  SendInput(1, Input, SizeOf(Input)); // don't send anyting actually to another app..
  SetForegroundWindow(Handle);

你可以进一步调整它f.i.如果需要，可以使用最小化的应用程序。

Answer 2

你不能可靠地做到这一点。 Windows XP有一个允许它的解决方法，但从那时起版本禁止它（见下面的注释）。这在SetForegroundWindow的MSDN文档的备注部分明确说明：

系统限制哪些进程可以设置前景窗口。仅当满足下列条件之一时，进程才能设置前台窗口：


该过程是前台过程。

该过程由前台进程启动。

该过程收到了最后一个输入事件。

没有前台进程。

正在调试前台进程。

未锁定前景（请参阅LockSetForegroundWindow）。

前台锁定超时已过期（请参阅SystemParametersInfo中的SPI_GETFOREGROUNDLOCKTIMEOUT）。

没有菜单处于活动状态。


当用户使用另一个窗口时，应用程序无法强制窗口到达前台。相反，Windows会闪烁窗口的任务栏按钮以通知用户。

请注意引用文档的最后一段，尤其是第一句。

的问题

这纯粹是个人使用，我希望它发生;它不会打扰任何东西。

是任何应用程序都可以尝试做同样的事情。 “纯粹个人使用”如何告诉您个人而不仅仅是任何申请？ :-)

注意：当我点击帮助工具按钮时，我已经尝试了所有我能想到的将IDE的文档显示在前台，但我所能得到的只是闪烁的任务栏按钮（我和用户想要的一样）这样做。）

Answer 3

我在我的一个应用程序中做了类似的事情，这个功能对我有用在xp / vista / w7中：

function ForceForegroundWindow(hwnd: THandle): Boolean;
const
  SPI_GETFOREGROUNDLOCKTIMEOUT = $2000;
  SPI_SETFOREGROUNDLOCKTIMEOUT = $2001;
var
  ForegroundThreadID: DWORD;
  ThisThreadID: DWORD;
  timeout: DWORD;
begin
  if IsIconic(hwnd) then ShowWindow(hwnd, SW_RESTORE);

  if GetForegroundWindow = hwnd then Result := True
  else
  begin
    // Windows 98/2000 doesn't want to foreground a window when some other
    // window has keyboard focus

    if ((Win32Platform = VER_PLATFORM_WIN32_NT) and (Win32MajorVersion > 4)) or
      ((Win32Platform = VER_PLATFORM_WIN32_WINDOWS) and
      ((Win32MajorVersion > 4) or ((Win32MajorVersion = 4) and
      (Win32MinorVersion > 0)))) then
    begin
      Result := False;
      ForegroundThreadID := GetWindowThreadProcessID(GetForegroundWindow, nil);
      ThisThreadID := GetWindowThreadPRocessId(hwnd, nil);
      if AttachThreadInput(ThisThreadID, ForegroundThreadID, True) then
      begin
        BringWindowToTop(hwnd); // IE 5.5 related hack
        SetForegroundWindow(hwnd);
        AttachThreadInput(ThisThreadID, ForegroundThreadID, False);
        Result := (GetForegroundWindow = hwnd);
      end;
      if not Result then
      begin
        // Code by Daniel P. Stasinski
        SystemParametersInfo(SPI_GETFOREGROUNDLOCKTIMEOUT, 0, @timeout, 0);
        SystemParametersInfo(SPI_SETFOREGROUNDLOCKTIMEOUT, 0, TObject(0),
          SPIF_SENDCHANGE);
        BringWindowToTop(hwnd); // IE 5.5 related hack
        SetForegroundWindow(hWnd);
        SystemParametersInfo(SPI_SETFOREGROUNDLOCKTIMEOUT, 0, TObject(timeout), SPIF_SENDCHANGE);
      end;
    end
    else
    begin
      BringWindowToTop(hwnd); // IE 5.5 related hack
      SetForegroundWindow(hwnd);
    end;

    Result := (GetForegroundWindow = hwnd);
  end;
end;

另一种解决方案不是窃取焦点，只是将窗口TOPMOST放在z缓冲区中：

procedure ForceForegroundNoActivate(hWnd : THandle);

begin
 if IsIconic(Application.Handle) then
  ShowWindow(Application.Handle, SW_SHOWNOACTIVATE);
 SetWindowPos(hWnd, HWND_TOPMOST, 0, 0, 0, 0, SWP_NOSIZE or SWP_NOACTIVATE or SWP_NOMOVE);
 SetWindowPos(hWnd, HWND_NOTOPMOST, 0, 0, 0, 0, SWP_NOSIZE or SWP_NOACTIVATE or SWP_NOMOVE);
end;

Answer 4

您可以编写一个可执行文件来解决该限制。例如，一个简单的（非可视）应用程序（基本上是一个控制台应用程序但没有{$ APPTYPE CONSOLE}），其唯一目的就是将您想要的窗口放在前面。

只要您需要执行前端操作，您的监控后台应用程序就会通过命令行调用（例如ShellExecute）调用帮助应用程序。由于这个应用程序正在成为前台进程，因此它可以将其他窗口置于前面（SetForeGroundWindow）。您可以使用FindWindow来获取目标窗口的句柄，或在启动帮助应用程序时传递适当的参数。

Answer 5

这甚至可以在Windows7 + 8操作系统中使用。唯一的要求是应用程序本身可以调用函数。使用外部应用程序来设置另一个进程的窗口是非常棘手的。

Application.Restore; // unminimize window, makes no harm always call it
SetWindowPos(self.Handle, HWND_NOTOPMOST,0,0,0,0, SWP_NOMOVE or SWP_NOSIZE);
SetWindowPos(self.Handle, HWND_TOPMOST,0,0,0,0, SWP_NOMOVE or SWP_NOSIZE);
SetWindowPos(self.Handle, HWND_NOTOPMOST,0,0,0,0, SWP_SHOWWINDOW or SWP_NOMOVE or SWP_NOSIZE);

编辑好的，我发现了一个问题。应用程序被带到前面，但焦点保留在原始应用程序中。使用这个答案来解决问题，这是一个非常复杂的方法，但是copypaste可以解决问题。在调用ForceForegroundWindow（wnd）之前，您可能必须调用Application.Restore来最小化窗口。 https://stackoverflow.com/a/5885318/185565

Answer 6

function WinActivate(const AWinTitle: string): boolean;
var
  _WindowHandle: HWND;
begin
  Result := false;
  _WindowHandle := FindWindow(nil, PWideChar(AWinTitle));
  if _WindowHandle <> 0 then
  begin
    if IsIconic(_WindowHandle) then
      Result := ShowWindow(_WindowHandle, SW_RESTORE)
    else
      Result := SetForegroundWindow(_WindowHandle);
  end;
end;

if WinActivate(self.Caption) then
  ShowMessage('This works for me in Windows 10');

Answer 7

假设没有其他StayOnTop应用程序正在运行，您可以暂时将表单FormStyle设置为fsStayOnTop，然后执行Application Restore和BringToFront，然后将formstyle更改回原来的样式。

tmpFormStyle := Application.MainForm.FormStyle;
Application.MainForm.FormStyle := fsStayOnTop;
Application.Restore; // optional
Application.BringToFront;
Application.MainForm.FormStyle := tmpFormStyle;

同样，这只有在没有其他stayontop应用程序的情况下才有效。

Answer 8

Form.bringtofront; ？

应该有效。如果你把它放在计时器中，它将保持在前面。

如何将我的应用程序带到前面？

8 个答案: