将列表分组为Haskell中的n个元素的列表

Question

库中的列表是否有一个操作来生成n个元素的组？例如：n = 3

groupInto 3 [1,2,3,4,5,6,7,8,9] = [[1,2,3],[4,5,6],[7,8,9]]

如果没有，我该怎么做？

Answer 1

快速搜索Hoogle表明没有这样的功能。另一方面，有人回复称split包中有一个名为chunksOf。

但是，您可以自己动手

group :: Int -> [a] -> [[a]]
group _ [] = []
group n l
  | n > 0 = (take n l) : (group n (drop n l))
  | otherwise = error "Negative or zero n"

当然，可以删除一些括号，我留在这里是为了理解代码的作用：

基本情况很简单：每当列表为空时，只需返回空列表。

如果n为正，则首先进行递归案例测试。如果n为0或更低，我们将进入无限循环，我们不希望如此。然后，我们使用take和drop将列表拆分为两部分：take返回第一个n元素，而drop返回其他元素。然后，我们将第一个n元素添加到通过将我们的函数应用于原始列表中的其他元素而获得的列表中。

Answer 2

此功能以及其他类似功能可在流行的split包中找到。

> import Data.List.Split
> chunksOf 3 [1,2,3,4,5,6,7,8,9]
[[1,2,3],[4,5,6],[7,8,9]]

Answer 3

Mihai指出，你可以自己写一个。但我会使用splitAt函数，因为它不需要输入列表上的两次传递，就像下拉组合那样：

chunks :: Int -> [a] -> [[a]]
chunks _ [] = []
chunks n xs =
    let (ys, zs) = splitAt n xs
    in  ys : chunks n zs

这是一种常见模式 - 通过重复迭代从种子值（在本例中是您的输入列表）生成列表。此模式在unfoldr函数中捕获。我们可以将它与splitAt的略微修改版本一起使用（感谢 Will Ness 以获得更简洁的版本）：

chunks n = takeWhile (not.null) . unfoldr (Just . splitAt n)

也就是说，我们生成n个元素的块，同时我们使用unfoldr将输入列表缩短n，然后生成这些块直到我们得到空列表 - 此时初始输入被完全消耗。

当然，正如其他人指出的那样，您应该使用split模块中已有的功能。但是，习惯于使用标准Haskell库中的列表处理函数总是好的。

Answer 4

这被称为“chunk”，是最常提到的列表操作之一，不在base中。包split提供了这样的操作，复制并粘贴了haddock文档：

 > chunksOf 3 ['a'..'z']
 ["abc","def","ghi","jkl","mno","pqr","stu","vwx","yz"]

此外，根据我的意愿，hoogle只搜索一小组图书馆（GHC或HP提供的图书馆），但您可以使用+PKG_NAME明确地向搜索添加资讯报告 - 与Int -> [a] -> [[a]] +split一起使用得到你想要的。有些人因此而使用Hayoo。