Question

我是xslt的新手。我有一个像

这样的xml文件

<EmpCollection>
<Emp>
<Name>Sai</Name>
<Sal>7000</Sal>
</Emp>
<Emp>
<Name>Nari</Name>
<Sal>7400</Sal>
</Emp>
<Emp>
<Name>Hari</Name>
<Sal>9000</Sal>
</Emp>
<Emp>
<Name>Suri</Name>
<Sal>8900</Sal>
</Emp>
</EmpCollection>

现在我想在不使用sum（）函数的情况下添加工资总和。我想以清晰的方式学习xslt： - ）

Answer 1

<强>予。可能是最简单的解决方案之一：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="Sal">
  <xsl:param name="pSum" select="0"/>
     <xsl:apply-templates select="following::Sal[1]">
       <xsl:with-param name="pSum" select="$pSum + ."/>
     </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="Sal[not(following::Sal)]">
  <xsl:param name="pSum" select="0"/>
  <xsl:value-of select="$pSum + ."/>
 </xsl:template>

 <xsl:template match="/">
  <xsl:apply-templates select="descendant::Sal[1]"/>
 </xsl:template>
</xsl:stylesheet>

在提供的XML文档上应用此转换时：

<EmpCollection>
    <Emp>
        <Name>Sai</Name>
        <Sal>7000</Sal>
    </Emp>
    <Emp>
        <Name>Nari</Name>
        <Sal>7400</Sal>
    </Emp>
    <Emp>
        <Name>Hari</Name>
        <Sal>9000</Sal>
    </Emp>
    <Emp>
        <Name>Suri</Name>
        <Sal>8900</Sal>
    </Emp>
</EmpCollection>

产生了想要的正确结果：

<强> II。更通用的解决方案是使用FXSL 2.x f:foldl()函数，如下所示：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/" exclude-result-prefixes="f">
   <xsl:import href="../f/func-foldl.xsl"/>
   <xsl:import href="../f/func-Operators.xsl"/>

   <xsl:output  encoding="UTF-8" omit-xml-declaration="yes"/>

    <xsl:template match="/">
      <xsl:value-of select="f:foldl(f:add(), 0, /*/*/Sal)"/>
    </xsl:template>
</xsl:stylesheet>

当在同一个XML文档（上面）上应用此XSLT 2.0转换时，会产生相同的正确和想要的结果：

您可以将任何双参数函数作为参数传递给f:foldl()，并生成不同问题的解决方案。

例如，传递f:mult()而不是f:add()（并将“零”参数更改为1）会产生薪水的乘积：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/" exclude-result-prefixes="f">
   <xsl:import href="../f/func-foldl.xsl"/>
   <xsl:import href="../f/func-Operators.xsl"/>

   <xsl:output  encoding="UTF-8" omit-xml-declaration="yes"/>

    <xsl:template match="/">
      <xsl:value-of select="f:foldl(f:mult(), 1, /*/*/Sal)"/>
    </xsl:template>
</xsl:stylesheet>

将此转换应用于同一XML文档的结果现在是所有Sal元素的产物：

4.14918E15

<强> III。在XSLT 3.0（XPath 3.0）中，可以使用标准fold-left()或fold-right()函数，其方式与上一个解决方案完全相同。

Answer 2

可能有更优雅的方式（我猜sum() :)但以下作品由'folding' siblings with addition完成。终止条件是最后一个兄弟（即没有后续节点）

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="1.0">
    <xsl:output method="xml" omit-xml-declaration="yes"/>

    <xsl:template match="/EmpCollection">
        <result>Result Is : <xsl:apply-templates select="Emp[1]"/>
        </result>
    </xsl:template>

    <xsl:template match="Emp[following-sibling::Emp]">
        <xsl:variable name="salThis">
            <xsl:value-of select="Sal"/>
        </xsl:variable>
        <xsl:variable name="salOthers">
            <xsl:apply-templates select="following-sibling::Emp[position()=1]"/>
        </xsl:variable>
        <xsl:value-of select="$salThis + $salOthers"/>
    </xsl:template>

    <!--Termination - the last employee just returns its salary value-->
    <xsl:template match="Emp[not(following-sibling::Emp)]">
        <xsl:value-of select="Sal"/>
    </xsl:template>
</xsl:stylesheet>

给出结果：

<result>Result Is : 32300</result>

修改

再次阅读你的问题后，我想这不是代码高尔夫问题？以下是使用硬编码元素名称执行此操作的更简单方法，该方法指示处理器将命名员工的工资加在一起：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> <xsl:output method="xml" omit-xml-declaration="yes"/> <xsl:template match="/EmpCollection"> <result> Result Is : <xsl:value-of select="Emp[Name='Sai']/Sal + Emp[Name='Nari']/Sal + Emp[Name='Hari']/Sal + Emp[Name='Suri']/Sal"/> </result> </xsl:template> </xsl:stylesheet>

然后应该很容易理解sum()正在做什么：

<xsl:template match="/EmpCollection"> <result> Result Is : <xsl:value-of select="sum(Emp/Sal)"/> </result> </xsl:template>

修改

简单就是：

<xsl:template match="/EmpCollection"> <result> <xsl:text>Count Is : </xsl:text> <xsl:value-of select="count(Emp)"/> </result> </xsl:template>

不使用count()执行此操作并非如此简单。请注意，xsl:variable一旦分配（不可变），就无法更改。所以以下内容根本不起作用。

<xsl:template match="/EmpCollection"> <xsl:variable name="count" select="0" /> <xsl:for-each select="Emp">  <xsl:variable name="count" select="$count + 1"></xsl:variable> </xsl:for-each> <result> Result Is : <xsl:value-of select="$count"/> </result> </xsl:template>

因此，您可以“循环”所有节点，然后使用position()确定这是否是序列中的最后一个节点。（请注意，我们已使用for-each，但实际上最好使用use apply-template）

<xsl:template match="/EmpCollection"> <result> <xsl:text>Count Is : </xsl:text> <xsl:for-each select="Emp"> <xsl:if test="position() = last()"> <xsl:number value="position()" format="1" /> </xsl:if> </xsl:for-each> </result> </xsl:template>

:(

计算没有sum函数的数组元素之和

2 个答案: