Question

我正在尝试创建一个以init cap形式存储输入字符串（TypeInput）值的变量。这个新变量将在我的样式表中的不同位置使用。我创建了一个模板，我调用它来将输入字符串转换为init cap表单。但是，当我运行样式表时，生成的变量TypeInputInitCap在调试器中显示为NodeSet（1），并且不在输出中输出文本。有什么想法吗？见下面的示例。

<xsl:variable name="TypeInputInitCap">
    <xsl:call-template name="ConvertToInitCapString">
        <xsl:with-param name="str" select="$TypeInput"></xsl:with-param>
    </xsl:call-template>    
</xsl:variable>

<xsl:template name="ConvertToInitCapString">
    <xsl:param name="str"></xsl:param>        
    <!-- Extract each component of the name delimited by . -->
    <xsl:variable name="TokenNodeSet">
        <xsl:for-each select="tokenize($str, '.')">
            <!-- Init cap each component -->
            <xsl:value-of select="concat(upper-case(substring(.,1,1)), lower-case(substring(.,2)))"></xsl:value-of>
        </xsl:for-each>
    </xsl:variable>
    <xsl:for-each select="$TokenNodeSet">
        <xsl:value-of select="."></xsl:value-of>
        <xsl:if test="not(last())">
            <xsl:text>.</xsl:text>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

Answer 1

我认为问题是$TokenNodeSet变量只包含一个字符串，因此第二个for-each只循环一次。

这样做呢：

<xsl:template name="ConvertToInitCapString"> 
  <xsl:param name="str"></xsl:param>         
  <xsl:for-each select="tokenize($str, '\.')"> 
    <xsl:value-of select="concat(upper-case(substring(.,1,1)), lower-case(substring(.,2)))"/> 
    <xsl:if test="not(last())"> 
        <xsl:text>.</xsl:text> 
    </xsl:if> 
  </xsl:for-each>

修改

修正了LarsH在评论
中建议的tokenize()以上呼叫

Answer 2

我会替换

<xsl:variable name="TokenNodeSet">
    <xsl:for-each select="tokenize($str, '.')">
        <!-- Init cap each component -->
        <xsl:value-of select="concat(upper-case(substring(.,1,1)), lower-case(substring(.,2)))"></xsl:value-of>
    </xsl:for-each>
</xsl:variable>

与

<xsl:variable name="TokenNodeSet" select="for $token in tokenize($str, '\.') return concat(upper-case(substring($token,1,1)), lower-case(substring($token,2)))" />

或更好的

<xsl:variable name="TokenNodeSet" as="xs:string*" select="for $token in tokenize($str, '\.') return concat(upper-case(substring($token,1,1)), lower-case(substring($token,2)))" />

或最后因为它是XSLT 2.0，其中没有节点集我会将变量重命名为例如。

<xsl:variable name="TokenSequence" as="xs:string*" select="for $token in tokenize($str, '\.') return concat(upper-case(substring($token,1,1)), lower-case(substring($token,2)))" />

Answer 3

感谢大家的帮助。我的模板中的第二部分没有必要，所以我现在正在使用这个版本，它有效。它重新添加'。'令牌之间的字符。（我没有使用这个帖子中建议的短版本，因为如果连接，我最终会得到一个额外的点。）：

<xsl:template name="ConvertToInitCapString">
    <xsl:param name="str" select="."></xsl:param>        
    <!-- Extract each component of the name delimited by . -->
    <xsl:for-each select="tokenize($str, '\.')">
        <!-- Init cap each component -->
        <xsl:value-of select="concat(upper-case(substring(.,1,1)), lower-case(substring(.,2)))"></xsl:value-of>                
        <xsl:if test="position() != last()">
            <xsl:value-of select="'.'"></xsl:value-of>
        </xsl:if>
    </xsl:for-each>                              
</xsl:template>

XSLT标记化节点集

3 个答案: