Question

我在VB.NET中制作一个简单的图像编辑器，其中一个功能是亮度/曝光。

这就是我的做法：

For i = 0 To img.Width - 1
    For j = 0 To img.Height - 1
        Dim s As Color = img.GetPixel(i, j)

        Dim r As Integer = s.R * 2
        Dim g As Integer = s.G * 2
        Dim b As Integer = s.B * 2
        If s.R * 2 > 255 Then
            r = 255
        End If

        If s.G * 2 > 255 Then
            g = 255
        End If
        If s.B * 2 > 255 Then
            b = 255
        End If
        Dim x As Color = Color.FromArgb(255, r, g, b)
        img.SetPixel(i, j, x)

    Next
Next

其中2是亮度，使亮度提高两倍。

唯一的问题是这似乎不能很好地工作，因为它做到了，但需要大约30秒！我究竟做错了什么？有没有更好的方法来实现它？

由于

Answer 1

您可以使用ColorMatrix和ImageAttributes更快地完成它。方法如下：

Imports System.Drawing.Imaging

Public Class Form1

Dim g As Graphics
Dim img As Image
Dim r As Rectangle

Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
  ' load photo file into picture box and initialize graphics
  img = Image.FromFile("c:\tmp.jpg")
  PictureBox1.Image = New Bitmap(PictureBox1.Width, PictureBox1.Height, PixelFormat.Format32bppArgb)
  g = Graphics.FromImage(PictureBox1.Image)
  r = New Rectangle(0, 0, PictureBox1.Width, PictureBox1.Height)
  g.DrawImage(img, r)
End Sub

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
  Call setBrightness(0.2)
End Sub

Sub setBrightness(ByVal Brightness As Single)
  ' Brightness should be -1 (black) to 0 (neutral) to 1 (white)

  Dim colorMatrixVal As Single()() = { _
     New Single() {1, 0, 0, 0, 0}, _
     New Single() {0, 1, 0, 0, 0}, _
     New Single() {0, 0, 1, 0, 0}, _
     New Single() {0, 0, 0, 1, 0}, _
     New Single() {Brightness, Brightness, Brightness, 0, 1}}

  Dim colorMatrix As New ColorMatrix(colorMatrixVal)
  Dim ia As New ImageAttributes

  ia.SetColorMatrix(colorMatrix, ColorMatrixFlag.Default, ColorAdjustType.Bitmap)

  g.DrawImage(img, r, 0, 0, img.Width, img.Height, GraphicsUnit.Pixel, ia)
  PictureBox1.Refresh()
End Sub

End Class

Answer 2

使用以下示例，将一个改变亮度/对比度和图像其他特征的项目放在一起应该非常容易。

这是一个使用ColorMatrix来更改图像的示例，它应该更快：

http://www.developerfusion.com/forum/thread/35125/

以下是同时进行亮度和对比度的示例：

http://www.codeproject.com/KB/graphics/multiple_color_matrices.aspx

使用ColorMatrix的另一个例子：

http://www.codeproject.com/KB/GDI-plus/colormatrix.aspx

并参考ColorMatrix：

http://msdn.microsoft.com/en-us/library/ms534063%28VS.85%29.aspx

vb .net的亮度/曝光功能

2 个答案: