vbs如何从命令行命令获取结果

Question

我想使用Windows脚本（.vbs）从命令行（cmd.exe）获取简单命令的结果。这是怎么做到的？我无法找到一个好的/简单的例子或解释。您可以使用“日期”或“时间”命令来提供示例。 如：

P.S。我能够编写打开cmd.exe并发送命令的脚本代码。

谢谢！

Answer 1

如有疑问，请阅读documentation。你可能想要这样的东西：

Set p = CreateObject("WScript.Shell").Exec("%COMSPEC% /c date /t")
Do While p.Status = 0
  WScript.Sleep 100
Loop
WScript.Echo p.StdOut.ReadAll

编辑：使用Exec()时，您通过.StdIn描述符传递输入，而不是通过SendKeys()（这是一种相当不可靠的传递输入方式）

%COMSPEC%是一个系统环境变量，其cmd.exe的完整路径和/c选项使cmd.exe退出命令后的date /t完成了。

如果该命令指示带有退出代码的成功/失败，您可以在命令完成后检查ExitCode属性。

If p.Status <> 0 Then WScript.Echo p.ExitCode

Edit2：您是否可以构建命令行来执行特定任务而无需用户交互，而不是以交互方式使用atprogram？使用非交互式命令行，这样的事情可能会起作用：

prompt = "C:\>"
atprogram_cmdline_1 = "atprogram.exe ..."
atprogram_cmdline_2 = "atprogram.exe ..."
'...

Function ReadOutput(p)
  text = ""
  Do Until Right(text, Len(prompt)) = prompt
    text = text & p.StdOut.Read(1)
  Loop
  ReadOutput = text
End Function

Set cmd = CreateObject("WScript.Shell").Exec("%COMSPEC% /k")
ReadOutput cmd  ' skip over first prompt

cmd.StdIn.WriteLine(atprogram_cmdline_1)
WScript.Echo ReadOutput(cmd)
cmd.StdIn.WriteLine(atprogram_cmdline_2)
WScript.Echo ReadOutput(cmd)
'...

cmd.Terminate  ' exit CMD.EXE

%COMSPEC% /k在不运行命令的情况下生成命令提示符。 /k阻止它关闭。由于它未自动关闭，因此您无法在此处使用While p.Status = 0循环。如果命令需要一些时间才能完成，则需要WScript.Sleep几秒钟。

通过cmd.StdIn.WriteLine，您可以在CMD实例中运行命令行。函数ReadOutput()从StdOut读取输出，直到出现下一个提示。您需要查找提示，因为读取操作是阻塞的，因此您不能简单地说“读取所有已打印的内容”。

完成后，您通过CMD.EXE退出cmd.Terminate。