Question

我正在写一个prolog程序，它将检查两个数学表达式是否实际相同。例如，如果我的数学表达式目标是：（a + b）+ c，那么以下任何表达式都被认为是相同的：

（A + B）+ C

A +（B + C）

（B + A）+ C

（C + A）+ B

A +（C + B）

C +（A + B）

和其他组合

当然，我不希望检查可能答案的组合，因为表达式可能比这更复杂。

目前，这是我的方法：例如，如果我想检查a + b * c是否与另一个表达式（如c * b + a）相同，那么我将两个表达式递归地存储为二进制表达式，我应该创建一个规则，如ValueOf，它将给出我是第一个表达式和第二个表达式的“值”。然后我只检查两个表达式的“值”是否相同，然后我可以说两个表达式都是相同的。问题是，因为表达式的内容不是数字，而是标识符，我不能使用prolog“is”关键字来获取值。

有什么建议吗？

非常感谢

% represent a + b * c
binExprID(binEx1).
hasLeftArg(binEx1, a).
hasRightArg(binEx1, binEx2).
hasOperator(binEx1, +).

binExprID(binEx2).
hasLeftArg(binEx2, b).
hasRightArg(binEx2, c).
hasOperator(binEx2, *).

% represent c * b + a
binExprID(binEx3).
hasLeftArg(binEx3, c).
hasRightArg(binEx3, b).
hasOperator(binEx3, *).

binExprID(binEx4).
hasLeftArg(binEx4, binEx3).
hasRightArg(binEx4, a).
hasOperator(binEx4, +).

goal:- valueOf(binEx1, V),
       valueOf(binEx4, V).

Answer 1

数学表达式可能非常复杂，我认为你指的是算术。正常形式（我希望我的措辞是合适的）是“单项式的总和”。

无论如何，一般来说解决这个问题并不容易，而且你的请求中存在歧义：2个表达式在语法上可能不同（即它们的语法树不同）但仍具有相同的值。显然这是由于操作使值保持不变，如加/减0。

根据您的描述，我认为您对'评估'身份感兴趣。然后你可以在比较相等之前规范化两个表达式。

为了评估句法身份，我会删除所有括号，“分配”因子而不是加数。该表达式成为乘法项的列表。基本上，我们得到一个列表列表，可以在不改变“值”的情况下进行排序。

表达式展平后，必须累加所有乘法常数。

简化示例：

a+(b+c)*5将为[[1,a],[b,5],[c,5]]而a+5*(c+b)将为[[1,a],[5,c],[5,b]]

经过一些改进后，

编辑，这是非常必要的规范化程序：

:- [library(apply)].

arith_equivalence(E1, E2) :-
    normalize(E1, N),
    normalize(E2, N).

normalize(E, N) :-
    distribute(E, D),
    sortex(D, N).

distribute(A, [[1, A]]) :- atom(A).
distribute(N, [[1, N]]) :- number(N).
distribute(X * Y, L) :-
    distribute(X, Xn),
    distribute(Y, Yn),
    % distribute over factors
    findall(Mono, (member(Xm, Xn), member(Ym, Yn), append(Xm, Ym, Mono)), L).
distribute(X + Y, L) :-
    distribute(X, Xn),
    distribute(Y, Yn),
    append(Xn, Yn, L).

sortex(L, R) :-
    maplist(msort, L, T),
    maplist(accum, T, A),
    sumeqfac(A, Z),
    exclude(zero, Z, S),
    msort(S, R).

accum(T2, [Total|Symbols]) :-
    include(number, T2, Numbers),
    foldl(mul, Numbers, 1, Total),
    exclude(number, T2, Symbols).

sumeqfac([[N|F]|Fs], S) :-
    select([M|F], Fs, Rs),
    X is N+M,
    !, sumeqfac([[X|F]|Rs], S).
sumeqfac([F|Fs], [F|Rs]) :-
    sumeqfac(Fs, Rs).
sumeqfac([], []).

zero([0|_]).
mul(X, Y, Z) :- Z is X * Y.

一些测试：

?- arith_equivalence(a+(b+c), (a+c)+b).
true .

?- arith_equivalence(a+b*c+0*77, c*b+a*1).
true .

?- arith_equivalence(a+a+a, a*3).
true .

我使用了一些内置的SWI-Prolog，例如include / 3，exclude / 3，foldl / 5和msort / 2，以避免重复丢失。

这些是基本的list manipulation内置函数，如果您的系统没有它们，则可以轻松实现。

修改

foldl / 4，如SWI-Prolog apply.pl中所定义：

:- meta_predicate foldl(3, +, +, -). foldl(Goal, List, V0, V) :- foldl_(List, Goal, V0, V). foldl_([], _, V, V). foldl_([H|T], Goal, V0, V) :- call(Goal, H, V0, V1), foldl_(T, Goal, V1, V).

处理部门

分部引入了一些复杂性，但这应该是预料之中的。毕竟，它引入了一个完整的类数字：理性。

以下是修改后的谓词，但我认为代码需要更多调试。所以我也提到了这个微重写系统可以解决的“单元测试”。另请注意，我没有自己介绍否定。我希望你能做出任何必要的修改。

/* File: arith_equivalence.pl Author: Carlo,,, Created: Oct 3 2012 Purpose: answer to http://stackoverflow.com/q/12665359/874024 How to check if two math expressions are the same? I warned that generalizing could be a though task :) See the edit. */ :- module(arith_equivalence, [arith_equivalence/2, normalize/2, distribute/2, sortex/2 ]). :- [library(apply)]. arith_equivalence(E1, E2) :- normalize(E1, N), normalize(E2, N), !. normalize(E, N) :- distribute(E, D), sortex(D, N). distribute(A, [[1, A]]) :- atom(A). distribute(N, [[N]]) :- number(N). distribute(X * Y, L) :- distribute(X, Xn), distribute(Y, Yn), % distribute over factors findall(Mono, (member(Xm, Xn), member(Ym, Yn), append(Xm, Ym, Mono)), L). distribute(X / Y, L) :- normalize(X, Xn), normalize(Y, Yn), divide(Xn, Yn, L). distribute(X + Y, L) :- distribute(X, Xn), distribute(Y, Yn), append(Xn, Yn, L). sortex(L, R) :- maplist(dsort, L, T), maplist(accum, T, A), sumeqfac(A, Z), exclude(zero, Z, S), msort(S, R). dsort(L, S) :- is_list(L) -> msort(L, S) ; L = S. divide([], _, []). divide([N|Nr], D, [R|Rs]) :- ( N = [Nn|Ns], D = [[Dn|Ds]] -> Q is Nn/Dn, % denominator is monomial remove_common(Ns, Ds, Ar, Br), ( Br = [] -> R = [Q|Ar] ; R = [Q|Ar]/[1|Br] ) ; R = [N/D] % no simplification available ), divide(Nr, D, Rs). remove_common(As, [], As, []) :- !. remove_common([], Bs, [], Bs). remove_common([A|As], Bs, Ar, Br) :- select(A, Bs, Bt), !, remove_common(As, Bt, Ar, Br). remove_common([A|As], Bs, [A|Ar], Br) :- remove_common(As, Bs, Ar, Br). accum(T, [Total|Symbols]) :- partition(number, T, Numbers, Symbols), foldl(mul, Numbers, 1, Total), !. accum(T, T). sumeqfac([[N|F]|Fs], S) :- select([M|F], Fs, Rs), X is N+M, !, sumeqfac([[X|F]|Rs], S). sumeqfac([F|Fs], [F|Rs]) :- sumeqfac(Fs, Rs). sumeqfac([], []). zero([0|_]). mul(X, Y, Z) :- Z is X * Y. :- begin_tests(arith_equivalence). test(1) :- arith_equivalence(a+(b+c), (a+c)+b). test(2) :- arith_equivalence(a+b*c+0*77, c*b+a*1). test(3) :- arith_equivalence(a+a+a, a*3). test(4) :- arith_equivalence((1+1)/x, 2/x). test(5) :- arith_equivalence(1/x+1, (1+x)/x). test(6) :- arith_equivalence((x+a)/(x*x), 1/x + a/(x*x)). :- end_tests(arith_equivalence).

运行单元测试：

?- run_tests(arith_equivalence). % PL-Unit: arith_equivalence ...... done % All 6 tests passed true.

序言。如何检查两个数学表达式是否相同

1 个答案: