Question

此功能：

GOOGLEFINANCE(("CURRENCY:EURAUD"))

在Google表格中运作良好，我在网页上搜索了一些关于此功能以及如何使用的文档，我最接近的就是这个

http://www.google.com/finance?q=EURAUD

有谁知道如何使用这个？或者在哪里可以找到有关此功能的文档？

Answer 1

您要找的内容的具体说明如下： https://support.google.com/docs/answer/3093281

请记住，您的Google Spreadsheets公式可能会使用分号（;）而不是逗号（，），具体取决于区域设置。

一旦做出替换，一些例子将如下所示：

=GoogleFinance("CURRENCY:USDEUR")
=INDEX(GoogleFinance("USDEUR","price",today()-30,TODAY()),2,2)
=SPARKLINE(GoogleFinance("USDEUR","price",today()-30,today()))

Answer 2

2016年1月1日欧元兑挪威克朗汇率：

=INDEX(GOOGLEFINANCE("CURRENCY:EURNOK"; "close"; DATE(2016;1;1)); 2; 2)

使用INDEX()函数是因为GOOGLEFINANCE()函数在用这些参数调用时实际打印出4个单独的单元格（2x2），结果只有一个单元格。

Answer 3

你走了：

https://support.google.com/docs/answer/3093281

这是Google提供的所有文档。

Answer 4

请注意，新版Google表格中的GoogleFinance()功能无法100％正常运作。例如，使用公式USD从GBP转换为GoogleFinance("CURRENCY:USDGBP")会在旧版本中提供0.603974，但在新版本中只会提供0.6。看起来有一个舍入错误。

Answer 5

=INDEX(GoogleFinance("CURRENCY:" & "EUR" & "USD", "price", A2), 2, 2)

其中A2是日期格式为日期的单元格。

将“EUR”和“USD”替换为您的货币对。

Answer 6

某些货币对在某些天内没有历史数据。

比较=GOOGLEFINANCE("CURRENCY:EURNOK", "close", DATE(2016,1,1), DATE(2016,1,12)：

Date                Close
1/1/2016 23:58:00   9.6248922
1/2/2016 23:58:00   9.632922114
1/3/2016 23:58:00   9.579957264
1/4/2016 23:58:00   9.609146435
1/5/2016 23:58:00   9.573877808
1/6/2016 23:58:00   9.639368875
1/7/2016 23:58:00   9.707103569
1/8/2016 23:58:00   9.673324479
1/9/2016 23:58:00   9.702379872
1/10/2016 23:58:00  9.702721875
1/11/2016 23:58:00  9.705679083

和=GOOGLEFINANCE("CURRENCY:EURRUB", "close", DATE(2016,1,1), DATE(2016,1,12)：

Date                Close
1/1/2016 23:58:00   79.44402768
1/4/2016 23:58:00   79.14048175
1/5/2016 23:58:00   80.0452446
1/6/2016 23:58:00   80.3761125
1/7/2016 23:58:00   81.70830185
1/8/2016 23:58:00   81.70680013
1/11/2016 23:58:00  82.50853122

所以=INDEX(GOOGLEFINANCE("CURRENCY:EURRUB", "close", DATE(2016,1,1)), 2, 2)给出了

79.44402768

但是=INDEX(GOOGLEFINANCE("CURRENCY:EURRUB", "close", DATE(2016,1,2)), 2, 2)给出了

#N/A

因此，当使用周末/节假日没有汇率的货币对时，以下公式可用于获取下一个工作日的汇率：

=INDEX(GOOGLEFINANCE("CURRENCY:EURRUB", "close", DATE(2016,1,2), 4), 2, 2)

Answer 7

语法为：

= GOOGLEFINANCE（自动收报机，[属性]，[start_date]，[num_days | end_date]，[interval]）

Sample usage：

=GOOGLEFINANCE("GOOG", "price", DATE(2014,1,1), DATE(2014,12,31), "DAILY")
=GOOGLEFINANCE("GOOG","price",TODAY()-30,TODAY())
=GOOGLEFINANCE(A2,A3)
=117.80*Index(GOOGLEFINANCE("CURRENCY:EURGBP", "close", DATE(2014,1,1)), 2, 2)

例如，如果您想在特定日期转换费率，这里有一些更高级的示例：

=IF($C2 = "GBP", "", Index(GoogleFinance(CONCATENATE("CURRENCY:", C2, "GBP"), "close", DATE(year($A2), month($A2), day($A2)), DATE(year($A2), month($A2), day($A2)+1), "DAILY"), 2))

其中$A2是您的日期（例如01/01/2015），C2是您的货币（例如EUR）。

在Docs editors Help at Google查看更多示例。

Answer 8

您必须在公式框中使用等号

=GOOGLEFINANCE("GOOG", "price", DATE(2014,1,1), DATE(2014,12,31), "DAILY")

如何使用GOOGLEFINANCE（（“CURRENCY：EURAUD”））函数

8 个答案: