Question

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
    xmlns:t1="http://mynamespace/A" xmlns:top="http://mynamespace/B" 
    xmlns:max="http://mynamespace/C"><soapenv:Body>
  <t1:Creditcard>
     <top:AutoPayenroll>
        <top:CustomerId>
           <max:CustName>Taylor</max:CustName>
           <max:CustID>1234</max:CustID>
        </top:CustomerId>
     </top:AutoPayenroll>
  </t1:CreditCard></soapenv:Body></soapenv:Envelope>

需要将CustID更改为我所做的加密。但不知道如何插入

使用此XSL：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
  xmlns:t1="http://mynamespace/A" xmlns:top="http://mynamespace/B"
  xmlns:max="http://mynamespace/C" version="1.0">
  <xsl:output method="xml"/><xsl:template match="/"> 
<xsl:apply-templates/>   </xsl:template>  <xsl:template match="//*[local-name()='CustID']"> 
<xsl:variable name="cleartxt" select="./text()"/>  
<!--got this encrypted data from my internal code-->  
<xsl:variable name="encdata" select="'jksdguasidgeiruh'"/>  
<xsl:element name="//*[local-name()='Pswd']"> 
  <xsl:value-of select="$encdata"/> 
</xsl:element>   </xsl:template>   <xsl:template match="*"> 
<xsl:copy> <xsl:copy-of select="@*"/>  
  <xsl:apply-templates/> 
</xsl:copy>   </xsl:template> </xsl:stylesheet>

回复应如下：

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:t1="http://mynamespace/A" xmlns:top="http://mynamespace/B" xmlns:max="http://mynamespace/C"><soapenv:Body>
  <t1:Creditcard>
     <top:AutoPayenroll>
        <top:CustomerId>
           <max:CustName>Taylor</max:CustName>
       <max:CustID>jksdguasidgeiruh</max:CustID>
        </top:CustomerId>
     </top:AutoPayenroll>
  </t1:CreditCard></soapenv:Body></soapenv:Envelope>

Answer 1

您的示例XSL和所需的输出有点不一致，但无论如何。

你有没有试过像：

<max:Pswd><xsl:value-of select="$encdata"/></max:Pswd>

换句话说，如果仅对所需输出进行编码就不一定需要使用<xsl:element/>。

Answer 2

由于max命名空间在想要的结果中是相同的（不是不同的），您只需要执行这个简短的转换：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:max="http://mynamespace/C">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pEncrypted" select="'jksdguasidgeiruh'"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="max:CustID/text()">
  <xsl:value-of select="$pEncrypted"/>
 </xsl:template>
</xsl:stylesheet>

当对提供的XML文档应用此转换时（已更正为格式正确！）：

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
xmlns:t1="http://mynamespace/A"
xmlns:top="http://mynamespace/B"
xmlns:max="http://mynamespace/C">
    <soapenv:Body>
        <t1:Creditcard>
            <top:AutoPayenroll>
                <top:CustomerId>
                    <max:CustName>Taylor</max:CustName>
                    <max:CustID>1234</max:CustID>
                </top:CustomerId>
            </top:AutoPayenroll>
        </t1:Creditcard>
    </soapenv:Body>
</soapenv:Envelope>

产生了想要的正确结果：

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
 xmlns:t1="http://mynamespace/A"
 xmlns:top="http://mynamespace/B"
 xmlns:max="http://mynamespace/C">
   <soapenv:Body>
      <t1:Creditcard>
         <top:AutoPayenroll>
            <top:CustomerId>
               <max:CustName>Taylor</max:CustName>
               <max:CustID>jksdguasidgeiruh</max:CustID>
            </top:CustomerId>
         </top:AutoPayenroll>
      </t1:Creditcard>
   </soapenv:Body>
</soapenv:Envelope>

<强>解释：

正确使用和覆盖 identity rule/template 。

<强>更新：

OP在评论中指出命名空间在每个响应上可能不同，并且事先不知道。

这是相同的解决方案，稍作修改以适应此规范的更改;

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pEncrypted" select="'jksdguasidgeiruh'"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="*[local-name()='CustID']/text()">
  <xsl:value-of select="$pEncrypted"/>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于同一XML文档（上图）时，会生成相同的正确所需结果：

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:t1="http://mynamespace/A" xmlns:top="http://mynamespace/B" xmlns:max="http://mynamespace/C">
   <soapenv:Body>
      <t1:Creditcard>
         <top:AutoPayenroll>
            <top:CustomerId>
               <max:CustName>Taylor</max:CustName>
               <max:CustID>jksdguasidgeiruh</max:CustID>
            </top:CustomerId>
         </top:AutoPayenroll>
      </t1:Creditcard>
   </soapenv:Body>
</soapenv:Envelope>

或者更安全，（OP在另一条评论中声明，名称空间-uri是相同的，只有前缀发生变化）：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pEncrypted" select="'jksdguasidgeiruh'"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match=
 "*[local-name()='CustID' and namespace-uri()='http://mynamespace/C']/text()">
  <xsl:value-of select="$pEncrypted"/>
 </xsl:template>
</xsl:stylesheet>

Answer 3

您无法使用xpath来定义元素名称。以下内容会将CustId替换为Pswd命名空间中的max=http://mynamespace/C，并使用身份模板复制其他内容：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:msxsl="urn:schemas-microsoft-com:xslt"
                xmlns:max="http://mynamespace/C"
                >
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <!--Replace CustID with Pswd-->
    <xsl:template match="*[local-name()='CustID']">
        <xsl:variable name="cleartxt" select="./text()"/>
        <!--got this encrypted data from my internal code-->
        <xsl:variable name="encdata" select="'jksdguasidgeiruh'"/>
        <xsl:element name="max:Pswd">
            <xsl:value-of select="$encdata"/>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

使用xsl将相同的命名空间添加到xml

3 个答案: