Question

我有4个批处理文件。我想同时运行one.bat和two.bat。完成这两个批处理文件后，three.bat和four.bat应该同时运行，并行运行。我试过很多方法但是mot工作正常。

任何人都可以帮助我吗？

Answer 1

使用我为Parallel execution of shell processes提供的解决方案的简化版本可以轻松完成此操作。有关文件锁定如何工作的说明，请参阅该解决方案。

@echo off
setlocal
set "lock=%temp%\wait%random%.lock"

:: Launch one and two asynchronously, with stream 9 redirected to a lock file.
:: The lock file will remain locked until the script ends.
start "" cmd /c 9>"%lock%1" one.bat
start "" cmd /c 9>"%lock%2" two.bat

:Wait for both scripts to finish (wait until lock files are no longer locked)
1>nul 2>nul ping /n 2 ::1
for %%N in (1 2) do (
  ( rem
  ) 9>"%lock%%%N" || goto :Wait
) 2>nul

::delete the lock files
del "%lock%*"

:: Launch three and four asynchronously
start "" cmd /c three.bat
start "" cmd /c four.bat

Answer 2

我有同样的困境。这是我解决这个问题的方式。我使用Tasklist命令来监视进程是否仍在运行：

:Loop
tasklist /fi "IMAGENAME eq <AAA>" /fi "Windowtitle eq <BBB>"|findstr /i /C:"<CCC>" >nul && (
timeout /t 3
GOTO :Loop
)
echo one.bat has stopped
pause

你需要调整

<AAA>, <BBB>, <CCC>

脚本中的值，以便正确过滤您的流程。

希望有所帮助。

Answer 3

创建一个启动one.bat和two.bat的master.bat文件。当one.bat和two.bat正确结束时，它们回显到已完成的文件

if errorlevel 0 echo ok>c:\temp\OKONE
if errorlevel 0 echo ok>c:\temp\OKTWO

然后master.bat等待两个文件的存在

del c:\temp\OKONE
del c:\temp\OKTWO
start one.bat
start two.bat
:waitloop
if not exist c:\temp\OKONE (
    sleep 5
    goto waitloop
    )
if not exist c:\temp\OKTWO (
    sleep 5
    goto waitloop
    )
start three.bat
start four.bat

另一种方法是尝试使用/ WAIT标志

start /WAIT one.bat
start /WAIT two.bat

但您无法控制错误。

这是一些参考资料

http://malektips.com/xp_dos_0002.html

http://ss64.com/nt/sleep.html

http://ss64.com/nt/start.html

Answer 4

只需添加另一种方法，也许是最短的方法。

(one.cmd | two.cmd) && (three.cmd | four.cmd)

概念真的很简单。从1和2并行开始，一旦完成，errorlevel 0运行3和4。

等待并行批处理脚本

4 个答案: