Question

我有字符串

'TEST1, TEST2, TEST3'

我想要

'TEST1,TEST2,TEST3'

在powerbuilder中是一个像replace，substr之类的函数吗？

Answer 1

当然有（你可以很容易地在帮助中找到它）但是它不是很有帮助。

它的原型是Replace ( string1, start, n, string2 )，因此在调用之前你需要知道要替换的字符串的位置。

有一个常见的包装器，包括在pos() / replace()上循环，直到没有任何东西可以替换。以下是全局函数的源代码：

global type replaceall from function_object
end type

forward prototypes
global function string replaceall (string as_source, string as_pattern, string as_replace)
end prototypes

global function string replaceall (string as_source, string as_pattern, string as_replace);//replace all occurences of as_pattern in as_source by as_replace 

string ls_target
long i, j

ls_target=""
i = 1
j = 1
do
    i = pos( as_source, as_pattern, j )
    if i>0 then
        ls_target += mid( as_source, j, i - j )
        ls_target += as_replace
        j = i + len( as_pattern )
    else
        ls_target += mid( as_source, j )
    end if
loop while i>0

return ls_target

end function

请注意PB中的字符串函数（搜索和连接）效率不高，另一种解决方案可能是使用PbniRegex扩展提供的FastReplaceall()全局函数。它是从9到12版本的PB classic的c ++编译插件。

Answer 2

一种方法是使用数据库，因为您可能有一个活动连接。

string ls_stringwithspaces = "String String String     String"
string ls_stringwithnospace = ""
string ls_sql = "SELECT  replace('" + ls_stringwithspaces + "', ' ', '')"

DECLARE db DYNAMIC CURSOR FOR SQLSA;
PREPARE SQLSA FROM :ls_sql USING SQLCA;

OPEN DYNAMIC db;
IF SQLCA.SQLCode > 0 THEN
       // erro handling
END IF
FETCH  db INTO :ls_stringwithnospace;
CLOSE db;

MessageBox("", ls_stringwithnospace)

Answer 3

我这样做：

  long space, ll_a
     FOR ll_a = 1 to len(ls_string)
            space = pos(ls_string, " ")
            IF space > 0 THEN
            ls_string= Replace(ls_string, space, 1, "")
            END IF
     NEXT

从空间powerbuilder清除字符串

3 个答案: