Question

我有以下程序：

rename proc _proc
_proc proc {name args body} {
    global pass_log_trace

    set g_log_trace "0"
    if {[info exists pass_log_trace]} {
        set g_log_trace $pass_log_trace
    }

    # simple check if we have double declaration of the same procedure
    if {[info procs $name] != ""} {
        puts "\nERROR: redeclaration of procedure: $name"
    }

    _proc $name $args $body

    if {$g_log_trace != 0} {
        trace add execution $name enter trace_report_enter
        trace add execution $name leave trace_report_leave
    }
}

此过程的目的主要是向代码中的所有过程添加入口和出口点跟踪器。但是，由于某种原因，它还会删除命名空间作用域。例如，像这样的代码：

namespace eval bob {
    namespace eval joe {
        proc proc1 {} {}
    }
    proc proc2 {} {
        puts "proc2"
    }
}

puts "Namespace calling [info procs ::bob\::*]"

不会在bob命名空间中创建过程，而是在全局命名空间中创建过程。致电namespace current始终会返回::。

有什么想法吗？

Answer 1

当您致电_proc时，请使用uplevel和namespace current的组合来添加调用上下文的命名空间：

set ns [uplevel 1 {namespace current}]
_proc ${ns}::$name $args $body

这里uplevel 1说，“在调用者的上下文中运行这段代码”，正如您所知，“namespace current”给出了调用它的名称空间的完全限定名称。

proc关键字的Tcl重命名在名称空间中不能很好地工作

1 个答案: