Question

说实话，这是我的第一个XML项目，但我终于厌倦了自己查找答案。我正在尝试创建一个地址簿，将联系人数据保存在XML文件中，并从转换后的XSLT样式表中提取，以生成一个简单的表。这是我的文件的副本，将非常感谢帮助。感谢。

XML：

<?xml version="1.0" encoding="ISO-8859-1"?>
<?xml-stylesheet type="text/xsl" href="contactdata.xsl"?>

<!DOCTYPE addressbook [
<!ELEMENT addressbook (contact)>
<!ELEMENT contact (fname,lname,mi,staddress,city,state,zip,phone,email,twitter)>
<!ELEMENT fname (#PCDATA)>
<!ELEMENT lname (#PCDATA)>
<!ELEMENT mi (#PCDATA)>
<!ELEMENT staddress (#PCDATA)>
<!ELEMENT city (#PCDATA)>
<!ELEMENT state (#PCDATA)>
<!ELEMENT zip (#PCDATA)>
<!ELEMENT phone (#PCDATA)>
<!ELEMENT email (#PCDATA)>
<!ELEMENT twitter (#PCDATA)>
]>

<addressbook>
<contact>
<fname>Peyton</fname>
<lname>Manning</lname>
<mi>Z</mi>
<staddress>123 Go Vols</staddress>
<city>Denver</city>
<state>CO</state>
<zip>12345</zip>
<phone>1-800-youwish</phone>
<email>pmanning@broncos.com</email>
<twitter>peyton_manning</twitter>
</contact>

<contact>
<fname>Eric</fname>
<lname>Berry</lname>
<mi>P</mi>
<staddress>123 Arrowhead Stadium</staddress>
<city>Kansas City</city>
<state>MO</state>
<zip>34567</zip>
<phone>816-213-4452</phone>
<email>eberry@chiefs.com</email>
<twitter>eric_berry</twitter>
</contact>
</addressbook>

和我的XSLT：

<?xml version="1.0" encoding="ISO-8859-1"?>
<?xml-stylesheet type="text/css" href="sitetemplate.css"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/">
<html>
<body>
<table>
<tr>
<th>First Name</th>
<th>Last Name</th>
<th>Middle Initial</th>
<th>Street Address</th>
<th>City</th>
<th>State</th>
<th>Zip</th>
<th>Phone</th>
<th>Email</th>
<th>Twitter</th>
</tr>
<xsl:for-each select="addressbook/contact">
    <tr>
      <td><xsl:value-of select="fname"/></td>
      <td><xsl:value-of select="lname"/></td>
      <td><xsl:value-of select="mi"/></td>
      <td><xsl:value-of select="staddress"/></td>
      <td><xsl:value-of select="city"/></td>
      <td><xsl:value-of select="state"/></td>
      <td><xsl:value-of select="zip"/></td>
      <td><xsl:value-of select="phone"/></td>
      <td><xsl:value-of select="email"/></td>
      <td><xsl:value-of select="twitter"/></td>

      </tr>
      </xsl:for-each>
</table>
</body>
</html>
</xsl:template>
</xsl:stylesheet>

另外我想提一下，现在代码是如何编写的，我的第一行是生成的，但我的表只是在之后停止了。

Answer 1

我想提一下，关于代码是如何编写的，我的产生了第一行，但我的表后来就停止了

没有。提供的转换工作正常，并为每个tr元素生成一个contact - 按预期

然而，想要的转换可以用更短的方式表达：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
    <html>
        <body>
            <table>
                <tr>
                    <th>First Name</th>
                    <th>Last Name</th>
                    <th>Middle Initial</th>
                    <th>Street Address</th>
                    <th>City</th>
                    <th>State</th>
                    <th>Zip</th>
                    <th>Phone</th>
                    <th>Email</th>
                    <th>Twitter</th>
                </tr>
                <xsl:apply-templates/>
            </table>
        </body>
    </html>
 </xsl:template>

 <xsl:template match="contact">
  <tr><xsl:apply-templates/></tr>
 </xsl:template>

 <xsl:template match="contact/*">
  <td><xsl:value-of select="."/></td>
 </xsl:template>
</xsl:stylesheet>

在提供的XML文档上应用此转换时：

<addressbook>
    <contact>
        <fname>Peyton</fname>
        <lname>Manning</lname>
        <mi>Z</mi>
        <staddress>123 Go Vols</staddress>
        <city>Denver</city>
        <state>CO</state>
        <zip>12345</zip>
        <phone>1-800-youwish</phone>
        <email>pmanning@broncos.com</email>
        <twitter>peyton_manning</twitter>
    </contact>
    <contact>
        <fname>Eric</fname>
        <lname>Berry</lname>
        <mi>P</mi>
        <staddress>123 Arrowhead Stadium</staddress>
        <city>Kansas City</city>
        <state>MO</state>
        <zip>34567</zip>
        <phone>816-213-4452</phone>
        <email>eberry@chiefs.com</email>
        <twitter>eric_berry</twitter>
    </contact>
</addressbook>

产生了想要的正确结果：

<html>
   <body>
      <table>
         <tr>
            <th>First Name</th>
            <th>Last Name</th>
            <th>Middle Initial</th>
            <th>Street Address</th>
            <th>City</th>
            <th>State</th>
            <th>Zip</th>
            <th>Phone</th>
            <th>Email</th>
            <th>Twitter</th>
         </tr>
         <tr>
            <td>Peyton</td>
            <td>Manning</td>
            <td>Z</td>
            <td>123 Go Vols</td>
            <td>Denver</td>
            <td>CO</td>
            <td>12345</td>
            <td>1-800-youwish</td>
            <td>pmanning@broncos.com</td>
            <td>peyton_manning</td>
         </tr>
         <tr>
            <td>Eric</td>
            <td>Berry</td>
            <td>P</td>
            <td>123 Arrowhead Stadium</td>
            <td>Kansas City</td>
            <td>MO</td>
            <td>34567</td>
            <td>816-213-4452</td>
            <td>eberry@chiefs.com</td>
            <td>eric_berry</td>
         </tr>
      </table>
   </body>
</html>

<强>解释：

正确使用模板，模式匹配和XSLT处理模型。

Answer 2

你的样式表适用于我。

在xsl中使用递归模板匹配而不是<xsl:for-each>时，可以轻松地执行此操作。在这种情况下，它非常简单。

使用该样式，您的模板将更改为：

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/">
<html>
  <body>
    <xsl:apply-templates/>
  </body>
</html>
</xsl:template>

<xsl:template match="addressbook">
  <table>
    <tr>
      <th>First Name</th>
      <th>Last Name</th>
      <th>Middle Initial</th>
      <th>Street Address</th>
      <th>City</th>
      <th>State</th>
      <th>Zip</th>
      <th>Phone</th>
      <th>Email</th>
      <th>Twitter</th>
    </tr>
    <xsl:apply-templates/>
  </table>
</xsl:template>


<xsl:template match="contact">
    <tr>
      <td><xsl:value-of select="fname"/></td>
      <td><xsl:value-of select="lname"/></td>
      <td><xsl:value-of select="mi"/></td>
      <td><xsl:value-of select="staddress"/></td>
      <td><xsl:value-of select="city"/></td>
      <td><xsl:value-of select="state"/></td>
      <td><xsl:value-of select="zip"/></td>
      <td><xsl:value-of select="phone"/></td>
      <td><xsl:value-of select="email"/></td>
      <td><xsl:value-of select="twitter"/></td>
    </tr>
</xsl:template>

</xsl:stylesheet>

对于一个简单的表当然可行。但是值得学习这种风格，因为对于更复杂的结构来说它会更好。

为什么我的XSLT样式表没有从表格的XML文件中提取值？

2 个答案: