Question

我有两个SAS数据集。第一个相对较小，包含唯一日期和相应的ID：

date   dateID
1jan90     10
2jan90     15
3jan90     20
...

第二个数据集非常大，有两个日期变量：

dt1     dt2
1jan90  2jan90
3jan90  1jan90
...

我需要将dt1和dt2都匹配到dateID，因此输出结果为：

id1  id2
10   15
20   10

效率在这里非常重要。我知道如何使用哈希对象进行一次匹配，因此我可以执行一个数据步骤来执行dt1的匹配，然后执行dt2的另一个步骤，但我想同时执行这两项操作一个数据步骤。怎么办呢？

以下是我仅针对dt1进行匹配的方式：

data tbl3;
 if 0 then set tbl1 tbl2;

 if _n_=1 then do;
  declare hash dts(dataset:'work.tbl2');
  dts.DefineKey('date');
  dts.DefineData('dateid');
  dts.DefineDone();
 end;

 set tbl1;
 if dts.find(key:date)=0 then output;
 run;

Answer 1

根据哈希表的大小，格式可能会有效...

data fmt ;
retain fmtname 'DTID' type 'N' ;
set tbl1 ;
start = date ;
label = dateid ;
run ;
proc format cntlin=fmt ; run ;

data tbl3 ;
  set tbl2 ;
  id1 = put(dt1,DTID.) ;
  id2 = put(dt2,DTID.) ;
run ;

根据以下评论编辑版本......

data fmt ;
retain fmtname 'DTID' type 'I' ;
set tbl1 end=eof ;
start = date ;
label = dateid ;
output ;
if eof then do ;
  hlo = 'O' ;
  label = . ;
  output ;
end ;
run ;
proc format cntlin=fmt ; run ;

data tbl3 ;
  set tbl2 ;
  id1 = input(dt1,DTID.) ;
  id2 = input(dt2,DTID.) ;
run ;

Answer 2

我现在没有SAS在我面前测试它，但代码看起来像这样：

 data tbl3;
   if 0 then set tbl1 tbl2;

   if _n_=1 then do;
     declare hash dts(dataset:'work.tbl2');
     dts.DefineKey('date');
     dts.DefineData('dateid');
     dts.DefineDone();
   end;

   set tbl1;

   date = dt1;
   if dts.find()=0 then do;
     id1 = dateId;
   end;

   date = dt2;
   if dts.find()=0 then do;
     id2 = dateId;
   end;

   if dt1 or dt2 then do output; * KEEP ONLY RECORDS THAT MATCHED AT LEAST ONE;

   drop date dateId;
 run;

Answer 3

我同意格式解决方案，但是如果你想做散列解决方案，那么它就是这样。这里最基本的是你将键定义为你匹配的变量，而不是散列本身。

data tbl2;
informat date DATE7.;
input date   dateID;
datalines;
01jan90     10
02jan90     15
03jan90     20
;;;;
run;

data tbl1;
informat dt1 dt2 DATE7.;
input dt1     dt2;
datalines;
01jan90  02jan90
03jan90  01jan90
;;;;
run;
data tbl3;
 if 0 then set tbl1 tbl2;

 if _n_=1 then do;
  declare hash dts(dataset:'work.tbl2');
  dts.DefineKey('date');
  dts.DefineData('dateid');
  dts.DefineDone();
 end;

 set tbl1;
 rc1 = dts.find(key:dt1);
 if rc1=0 then id1=dateID;
 rc2 = dts.find(key:dt2);
 if rc2=0 then id2=dateID;
 if rc1=0 and rc2=0 then output;
 run;

SAS中的多个哈希对象

3 个答案: