Question

嘿我正在运行以下脚本：

using terms from application "Messages"
    on message received this_message from this_buddy for this_chat
        display dialog "test"
    end message received
end using terms from

但是当我收到消息时，我每次都会收到以下错误：

Event: Message Received in Active Chat
File: registerToReceiveMessages.applescript
Error: Error -1708

我无法在互联网上找到任何错误。它似乎适用于除活动聊天之外的每个聊天。有什么想法吗？

此外，我正在尝试为“收到的已发送消息”添加事件，但每次我编译applescript时都会将其替换为“收到远程屏幕共享邀请”

Answer 1

每当您选择不处理指定事件的AppleScript时，您将收到错误-1708 。

例如，如果您的脚本仅实现了on message sent，但是每次接收消息时都将此脚本设置为运行，则会收到错误-1708。这是因为您的脚本只知道如何处理传出消息，而不是传入消息，因此，错误-1708。

现在这里有一些有趣的事情......

如果您尝试将默认脚本Mix Message Case.applescript用于事件Message Received，Message Received in Active Chat和Message Sent。第一个和最后一个工作正常，但您将在活动聊天事件中收到-1708错误。我们可以推断这意味着脚本不处理事件Message Received in Active Chat。因此，即便是Apple也无法立即处理此事件。

OS X Mavericks更新：

此更新修复了前面提到的错误。如果您选择Apple的示例脚本 Speak Events.applescript ，您会注意到它可以完美地处理收到活动聊天室的消息。如果检查代码，您会注意到它正在使用on active chat message received方法。我们现在可以在脚本中使用它。由于我不再安装旧版本，因此我无法测试此版本的相同方法是否有效。

以下是Speak Events.applescript的代码：

on active chat message received with eventDescription
    say eventDescription
end active chat message received

另请注意，您不再指定要针对特定事件运行的单个脚本。而是为Messages事件指定单个脚本处理程序。这意味着您必须实现所有事件以避免获得-1708方法。请注意，在示例脚本中，Apple甚至有评论# The following are unused but need to be defined to avoid an error。这是一个模板，可以用作脚本的起点：

using terms from application "Messages"
    # The following are unused but need to be defined to avoid an error

    on message sent theMessage with eventDescription
    end message sent

    on message received theMessage with eventDescription
    end message received

    on chat room message received with eventDescription
    end chat room message received

    on active chat message received with eventDescription
    end active chat message received

    on addressed message received theMessage from theBuddy for theChat with eventDescription
    end addressed message received

    on received text invitation with eventDescription
    end received text invitation

    on received audio invitation theText from theBuddy for theChat with eventDescription
    end received audio invitation

    on received video invitation theText from theBuddy for theChat with eventDescription
    end received video invitation

    on received local screen sharing invitation from theBuddy for theChat with eventDescription
    end received local screen sharing invitation

    on buddy authorization requested with eventDescription
    end buddy authorization requested

    on addressed chat room message received with eventDescription
    end addressed chat room message received

    on received remote screen sharing invitation with eventDescription
    end received remote screen sharing invitation

    on login finished with eventDescription
    end login finished

    on logout finished with eventDescription
    end logout finished

    on buddy became available with eventDescription
    end buddy became available

    on buddy became unavailable with eventDescription
    end buddy became unavailable

    on received file transfer invitation theFileTransfer with eventDescription
    end received file transfer invitation

    on av chat started with eventDescription
    end av chat started

    on av chat ended with eventDescription
    end av chat ended

    on completed file transfer with eventDescription
    end completed file transfer

end using terms from

如果您从这个脚本开始并只实现您需要的方法（保持其余部分完好无损），那么您应该避免所有-1708错误。

Answer 2

我看起来像message received事件处理程序只有在 Messages 中感觉它时才有效。我有一个略有不同的脚本相同的问题。在另一个网站上找到另一个示例后，将其复制粘贴到一个新的AppleScript编辑器窗口中并将其保存到通过Messages复制到~/Library/Scripts/Messages的AppleScript文件中，它开始工作。

您的脚本似乎没有问题。如果我用代码替换当前脚本并保存脚本，它会按预期工作，显示包含文本test的对话框。

将脚本设置为运行到None并返回到您在“消息设置”中创建的脚本也可能就足够了。

试图从os x消息w / applescript接收消息

2 个答案: