Question

我已经编写了这段代码，将一堆.xlsx工作簿批量转换为.xls（我有很多最终用户使用2003）。它完成了这项工作，但速度很慢，我在20个工作簿上测试了这个，每个工作簿大小只有30 kb，在本地执行需要9.78秒。通过我的sharepoint服务器这需要262秒，但我相信sharepoint的速度非常慢，这是一个不同的问题。

代码

Option Explicit
Sub Convert_to972003()
    Dim orgwb As Workbook
    Dim mypath As String, strfilename As String
    Dim nname As String

    '--> Error Handling
    On Error GoTo WhatHappened

    '--> Disable Alerts
    With Application
        .DisplayAlerts = False
        .ScreenUpdating = False
    End With

    '--> Specify location of workbooks
    mypath = "C:\xxx"
    strfilename = Dir(mypath & "\*.xlsx", vbNormal)

    '--> Check the specified folder contains files
    If Len(strfilename) = 0 Then Exit Sub

    '--> Start Loop, end when last file reached
    Do Until strfilename = ""

    '--> Open a workbook
        Set orgwb = Application.Workbooks.Open _
        (mypath & "\" & strfilename)

        '--> Create new Filename, Save in new File Format and Close
        nname = Replace(strfilename, ".xlsx", ".xls")
        orgwb.SaveAs mypath & "\" & nname, FileFormat:=xlExcel8
        orgwb.Close
        strfilename = Dir()
    Loop

    '--> Enable Alerts
    With Application
        .DisplayAlerts = True
        .ScreenUpdating = True
    End With

Exit Sub

WhatHappened: MsgBox Err.Description

End Sub

问题

转换文件格式比循环文件夹/打开/保存/关闭有更快的方法吗？

Answer 1

如果这仍然相关。当我遇到类似的问题时，我最终得到了几乎相同的代码，但帮助我加快一点的是禁用Application.EnableEvents，即：

Application.EnableEvents = False
...
Application.EnableEvents = True

在适当的部分。如果您有任何其他加载项或宏由各种Excel事件（如打开或关闭工作簿等）触发，这将特别有用。

执行时间较慢批量.xlsx到.xls转换

1 个答案: