Question

我有一个xsl：模板，它将一个额外的节点插入到我的原始XML中。

然后，我想使用以下模板来引用该新节点来提供帮助在继续解析源文件。

我当前的方法（第二个模板）没有“看到”第一个模板中新插入的节点。我该如何处理？

非常感谢。

以下示例极为简化，以表达我想要实现的目标。

启动XML：

<master> 
 <node>
  <node1>hi</node1>
  <node2>bye</node2>
 </node>
</master>

第一个模板：

<xsl:template match="master/node">
  <node>
  <xsl:apply-templates/>
  <node3>greetings</node3>
  </node>
</xsl:template>

结果XML 1：

<master> 
 <node>
  <node1>hi</node1>
  <node2>bye</node2>
  <node3>greetings<node3>
 </node>
</master>

第二个模板：

<xsl:template match="master/node[node3='greetings']">
  <node>
   <newnode><xsl:value-of select="./node3"/>
  </node>
</xsl:template>

预期结果：

<master> 
 <node>
  <newnode>greetings</newnode>
 </node>
</master>

XSL：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="no" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="@*|node()">
  <xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
  </xsl:copy>
</xsl:template>

        <!-- first template -->
<xsl:template match="master/node">
  <node>
  <xsl:apply-templates/>
  <node3>greetings</node3>
  </node>
</xsl:template>

        <!-- second template -->
<xsl:template match="master/node[node3='greetings']">
  <node>
   <newnode><xsl:value-of select="./node3"/></newnode>
  </node>
</xsl:template>

Answer 1

在没有扩展的XSLT 1.0中，只有输入文档中的节点可以与模板匹配。要将模板应用于中间结果，可以使用nodeset扩展（由XSLT 1.0实现广泛实现），该扩展允许将模板应用于结果树片段。或者你可以转到XSLT 2.0。

有关nodeset扩展的详细信息，请参阅Dimitre Novatchev's answer to a related question。

Answer 2

Michael Sperberg-McQueen已经给出了如何在XSLT 1.0中处理RTF（结果树片段）的精确解释。

以下是使用EXSLT node-set()扩展函数的完整解决方案的示例：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="/">
  <xsl:variable name="vrtfPass1">
   <xsl:apply-templates/>
  </xsl:variable>
  <xsl:apply-templates select="ext:node-set($vrtfPass1)/*"/>
 </xsl:template>

 <xsl:template match="master/node">
  <node>
   <xsl:apply-templates/>
   <node3>greetings</node3>
  </node>
 </xsl:template>

 <xsl:template match="master/node[node3='greetings']" priority="2">
  <node>
   <newnode><xsl:value-of select="./node3"/></newnode>
  </node>
 </xsl:template>
</xsl:stylesheet>

将此转换应用于提供的XML文档时：

<master>
 <node>
  <node1>hi</node1>
  <node2>bye</node2>
 </node>
</master>

产生了想要的正确结果：

<master>
   <node>
      <newnode>greetings</newnode>
   </node>
</master>

请注意最好以这种方式组织多次传递处理，所有在Pass-N中运行的模板都处于与在任何其他传递中运行的所有模板不同的模式数。这是为了避免在Pass-N和Pass-M中意外选择执行相同模板时出错。

使用模式上述解决方案：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

  <xsl:template match="node()|@*" mode="pass2">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*" mode="pass2"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="/">
  <xsl:variable name="vrtfPass1">
   <xsl:apply-templates/>
  </xsl:variable>
  <xsl:apply-templates mode="pass2"
  select="ext:node-set($vrtfPass1)/*"/>
 </xsl:template>

 <xsl:template match="master/node">
  <node>
   <xsl:apply-templates/>
   <node3>greetings</node3>
  </node>
 </xsl:template>

 <xsl:template mode="pass2" match="master/node[node3='greetings']"
      priority="2">
  <node>
   <newnode><xsl:value-of select="./node3"/></newnode>
  </node>
 </xsl:template>
</xsl:stylesheet>

Answer 3

在XSLT 2.0中，您只需捕获变量中第一个模板的输出，并且变量的值是一个新的XML文档，可以像源文档一样进行处理。

在XSLT 1.0中，当您在变量中捕获模板的输出时，它不是第一类文档，而是“结果树片段”，只能以非常有限的方式处理。 exslt：node-set（）扩展将它从“结果树片段”转换为第一类文档，然后可以正常处理。

我希望这有助于总结其他人提供的非常详细的信息（虽然我觉得这些天我们应该假设人们使用的是XSLT 2.0，除非他们另有说明。）

xslt - 引用上一个模板的输出结果

3 个答案: