Question

我有一个sql文件 test.sql 用于运行一些SQL（创建对象/更新/删除/插入），看起来像这样

    CREATE TABLE test_dbi1 (
    test_dbi_intr_no    NUMBER(15)
  , test_dbi_name       VARCHAR2(100);

UPDATE mytable 
SET col1=1;

    CREATE TABLE test_dbi2 (
    test_dbi_intr_no    NUMBER(15)
  , test_dbi_name       VARCHAR2(100);

通常，我只使用SQLPLUS（在Perl中）使用此命令执行此test.sql： @ TEST.SQL

有没有办法在Perl中使用DBI做同样的事情？到目前为止，我发现DBI一次只能执行一个语句，而没有“;”最后。

Answer 1

数据库控制一次可以执行的语句数。我不记得Oracle是否允许每个prepare多个语句（MySQL确实如此）。试试这个：

my $dbh = DBI->connect(
    "dbi:Oracle:dbname",
    "username",
    "password",
    {
        ChopBlanks       => 1,
        AutoCommit       => 1,
        RaiseError       => 1,
        PrintError       => 1,
        FetchHashKeyName => 'NAME_lc',
    }
);
$dbh->do("
    CREATE TABLE test_dbi1 (
        test_dbi_intr_no    NUMBER(15),
        test_dbi_name       VARCHAR2(100)
    );

    UPDATE mytable 
        SET col1=1;

    CREATE TABLE test_dbi2 (
        test_dbi_intr_no    NUMBER(15),
        test_dbi_name       VARCHAR2(100)
    );
");

$dbh->disconnect;

当然，如果你破坏语句，你会得到更好的错误处理。您可以使用简单的解析器将字符串分解为单个语句：

#!/usr/bin/perl

use strict;
use warnings;

my $sql = "
    CREATE TABLE test_dbi1 (
        test_dbi_intr_no    NUMBER(15),
        test_dbi_name       VARCHAR2(100)
    );

    UPDATE mytable
        SET col1=';yes;'
        WHERE col2=1;

    UPDATE mytable
        SET col1='Don\\'t use ;s and \\'s together, it is a pain'
        WHERE col2=1;


    CREATE TABLE test_dbi2 (
        test_dbi_intr_no    NUMBER(15),
        test_dbi_name       VARCHAR2(100)
    );
";

my @statements = ("");
#split the string into interesting pieces (i.e. tokens):
#   ' delimits strings
#   \ pass on the next character if inside a string
#   ; delimits statements unless it is in a string
#   and anything else
# NOTE: the grep { ord } is to get rid of the nul
# characters the split seems to be adding
my @tokens     = grep { ord } split /([\\';])/, $sql; 
# NOTE: this ' fixes the stupid SO syntax highlighter
#this is true if we are in a string and should ignore ; 
my $in_string  = 0;
my $escape     = 0;
#while there are still tokens to process
while (@tokens) {
    #grab the next token
    my $token = shift @tokens;
    #if we are in a string
    if ($in_string) {
        #add the token to the last statement
        $statements[-1] .= $token;
        #setup the escape if the token is \
        if ($token eq "\\") {
                $escape = 1;
                next;
        }
        #turn off $in_string if the token is ' and it isn't escaped
        $in_string = 0 if not $escape and $token eq "'";
        $escape = 0; #turn off escape if it was on
        #loop again to get the next token

        next;
    }
    #if the token is ; and we aren't in a string
    if ($token eq ';') {
        #create a new statement
        push @statements, "";
        #loop again to get the next token
        next;
    }
    #add the token to the last statement
    $statements[-1] .= $token;
    #if the token is ' then turn on $in_string
    $in_string = 1 if $token eq "'";
}
#only keep statements that are not blank
@statements = grep { /\S/ } @statements;

for my $i (0 .. $#statements) {
    print "statement $i:\n$statements[$i]\n\n";
}

Answer 2

请看一下这个新的CPAN模块：DBIx::MultiStatementDo

正是为此而构思出来。

Answer 3

Oracle可以使用匿名PL / SQL块在一个prepare中运行多个SQL语句。

例如

$dbh->do("
    BEGIN
      UPDATE table_1 SET col_a = col_a -1;
      DELETE FROM table_2 where id in (select id from table_1 where col_a = 0);
    END;
");

DDL（创建或删除对象）更复杂，主要是因为它是你不应该在ad-hoc基础上做的事情。

Answer 4

您可以在Perl中添加另一层逻辑，它解析SQL脚本，将其拆分为语句并使用上述技术逐个执行

   --sql file
   -- [statement1]
   SQLCODE...

   -- [statement2]
   SQLCODE...

#Gets queries from file.
sub sql_q {
     my ($self) = @_;
     return $self->{sql_q} if $self->{sql_q};
     my $file = $self->{sql_queries_file};

     $self->{sql_q} || do {
         -e $file || croak( 'Queries file ' . $file . ' can not be found.' );
         my $fh = IO::File->new("< $file");
         my @lines;
         ( $fh->binmode and @lines = $fh->getlines and $fh->close ) or croak $!;

         my ($key);
         foreach ( 0 .. @lines - 1 ) {
             next if ( $lines[$_] =~ /^;/ );
             if ( $lines[$_] =~ /^--\s*?\[(\w+)\]/ ) {
                 $key = $1;
             }
             $self->{sql_q}{$key} .= $lines[$_] if $key;
         }
     };
     return $self->{sql_q};
 }
 #then in your script
 #foreach statement something like
 $dbh->prepare($sql_obj->{sql_q}->{statement_name})->execute(@bindvars);

Perl DBI - 运行带有多个语句的SQL脚本

4 个答案: