Question

可能重复：
How to strip out a url variable

我有网址http://localhost/abc/detail.cfm?iId=1711471&countrysearch=3693&itemnumbersearch=&keywordsearch=&purl=%2FIGPCI%2Fthumbs%2Ecfm%3Fcountrysearch%3D3693%26itemnumbersearch%3D%26keywordsearch%3D%26x%3D78%26y%3D10&productid=1111&recordindex=1 我想在每次需要准备新的带有productid和recordindex值的新URL时，点击名为“next”的链接搜索产品详细信息。例如，我有四个关于countryid =“3693”的产品，

productid productname 
1           p1
2           p2
3           p3
4           p4

当下次点击新网址时，使用productid = 1和recordindex = 1，再次点击，然后点击URL为productid = 2并记录id = 2，依此类推。

获取URL我使用了以下代码：

 <cfset currentURL = "#CGI.SERVER_NAME#" & "#CGI.PATH_INFO#" & "#CGI.query_string#">

给我当前的网址

然后我用以下代码准备新网址：

<cfif queryString.recordset gt 0> <cfset recordindex=#recordindex#+1> <cfset newUrl=currentURL & '&productid=#queryString.poductid[recordindex]#&recordindex=#recordindex#' </cfif>

使用此代码，每次使用旧代码追加url值。像：

http://localhost/abc/detail.cfm?iId=1711471&countrysearch=3693&itemnumbersearch=&keywordsearch=&purl=%2FIGPCI%2Fthumbs%2Ecfm%3Fcountrysearch%3D3693%26itemnumbersearch%3D%26keywordsearch%3D%26x%3D78%26y%3D10&productid=1111&recordindex=1&productid=2&recordindex=2

我的问题如何在旧的URL中删除旧的＆amp; productid = 1111＆amp; recordindex = 1 。尝试使用替换函数但是在字符串匹配时替换它，在我的情况下每次产品和记录索引值是change.how使用正则表达式删除旧字符串。请帮助我。

由于

Answer 1

你不需要正则表达式。实际上，有人已经为此构建了一个UDF。

QueryStringDeleteVar

示例：

<cfset currentURL = CGI.SERVER_NAME & CGI.PATH_INFO & queryStringDeleteVar("productid,recordindex")>

UDF代码：

<cfscript>
/**
 * Deletes a var from a query string.
 * Idea for multiple args from Michael Stephenson (michael.stephenson@adtran.com)
 * 
 * @param variable      A variable, or a list of variables, to delete from the query string. 
 * @param qs      Query string to modify. Defaults to CGI.QUERY_STRING. 
 * @return Returns a string. 
 * @author Nathan Dintenfass (michael.stephenson@adtran.comnathan@changemedia.com) 
 * @version 1.1, February 24, 2002 
 */
function queryStringDeleteVar(variable){
    //var to hold the final string
    var string = "";
    //vars for use in the loop, so we don't have to evaluate lists and arrays more than once
    var ii = 1;
    var thisVar = "";
    var thisIndex = "";
    var array = "";
    //if there is a second argument, use that as the query string, otherwise default to cgi.query_string
    var qs = cgi.query_string;
    if(arrayLen(arguments) GT 1)
        qs = arguments[2];
    //put the query string into an array for easier looping
    array = listToArray(qs,"&");        
    //now, loop over the array and rebuild the string
    for(ii = 1; ii lte arrayLen(array); ii = ii + 1){
        thisIndex = array[ii];
        thisVar = listFirst(thisIndex,"=");
        //if this is the var, edit it to the value, otherwise, just append
        if(not listFind(variable,thisVar))
            string = listAppend(string,thisIndex,"&");
    }
    //return the string
    return string;
}
</cfscript>

虽然，由于您希望替换网址参数值，QueryStringChangeVar可能更符合您的要求。

<cfscript>
/**
 * Changes a var in a query string.
 * 
 * @param name      The name of the name/value pair you want to modify. (Required)
 * @param value      The new value for the name/value pair you want to modify. (Required)
 * @param qs      Query string to modify. Defaults to CGI.QUERY_STRING. (Optional)
 * @return Returns a string. 
 * @author Nathan Dintenfass (nathan@changemedia.com) 
 * @version 2, September 5, 2002 
 */
function QueryStringChangeVar(variable,value){
    //var to hold the final string
    var string = "";
    //vars for use in the loop, so we don't have to evaluate lists and arrays more than once
    var ii = 1;
    var thisVar = "";
    var thisIndex = "";
    var array = "";
    var changedIt = 0;
    //if there is a third argument, use that as the query string, otherwise default to cgi.query_string
    var qs = cgi.query_string;
    if(arrayLen(arguments) GT 2)
        qs = arguments[3];

    //put the query string into an array for easier looping
    array = listToArray(qs,"&");
    //now, loop over the array and rebuild the string
    for(ii = 1; ii lte arrayLen(array); ii = ii + 1){
        thisIndex = array[ii];
        thisVar = listFirst(thisIndex,"=");
        //if this is the var, edit it to the value, otherwise, just append
        if(thisVar is variable){
            string = listAppend(string,thisVar & "=" & value,"&");
            changedIt = 1;
        }
        else{
            string = listAppend(string,thisIndex,"&");
        }
    }
    //if it was not changed, add it!
    if(NOT changedIt)
        string = listAppend(string,variable & "=" & value,"&");
    //return the string
    return string;
}
</cfscript>

如何从URL中删除字符串？

1 个答案: