Question

我正在编写一个VB脚本来更新网络上的一些文件。在开始之前，我想知道是否有任何文件被锁定。我想在之前实际做任何更新。

我知道如果在我尝试替换文件时文件被锁定，我可以处理错误，但我真的想知道在开始更新任何文件之前是否有任何文件被锁定。

有没有办法看到使用VBS锁定文件（除了尝试替换它）？

Answer 1

此功能确定是否可以在“写入”模式下访问感兴趣的文件。这与确定文件是否被进程锁定不完全相同。不过，您可能会发现它适用于您的情况。（至少在出现更好的情况之前。）

此函数将指示当另一个进程锁定文件时无法进行“写入”访问。但是，它无法将该条件与阻止“写入”访问的其他条件区分开来。例如，如果文件的只读位设置或具有限制性NTFS权限，则也无法进行“写入”访问。当进行“写入”访问尝试时，所有这些条件都将导致“权限被拒绝”。

另请注意，如果某个文件被另一个进程锁定，则此函数返回的答案仅在执行该函数时才可靠。因此，并发性问题是可能的。

如果发现以下任何条件，则抛出异常：'找不到文件'，'找不到路径'或'非法文件名'（'错误的文件名或号码'）。

Function IsWriteAccessible(sFilePath)
    ' Strategy: Attempt to open the specified file in 'append' mode.
    ' Does not appear to change the 'modified' date on the file.
    ' Works with binary files as well as text files.

    ' Only 'ForAppending' is needed here. Define these constants
    ' outside of this function if you need them elsewhere in
    ' your source file.
    Const ForReading = 1, ForWriting = 2, ForAppending = 8

    IsWriteAccessible = False

    Dim oFso : Set oFso = CreateObject("Scripting.FileSystemObject")

    On Error Resume Next

    Dim nErr : nErr = 0
    Dim sDesc : sDesc = ""
    Dim oFile : Set oFile = oFso.OpenTextFile(sFilePath, ForAppending)
    If Err.Number = 0 Then
        oFile.Close
        If Err Then
            nErr = Err.Number
            sDesc = Err.Description
        Else
            IsWriteAccessible = True
        End if
    Else
        Select Case Err.Number
            Case 70
                ' Permission denied because:
                ' - file is open by another process
                ' - read-only bit is set on file, *or*
                ' - NTFS Access Control List settings (ACLs) on file
                '   prevents access

            Case Else
                ' 52 - Bad file name or number
                ' 53 - File not found
                ' 76 - Path not found

                nErr = Err.Number
                sDesc = Err.Description
        End Select
    End If

    ' The following two statements are superfluous. The VB6 garbage
    ' collector will free 'oFile' and 'oFso' when this function completes
    ' and they go out of scope. See Eric Lippert's article for more:
    '   http://blogs.msdn.com/b/ericlippert/archive/2004/04/28/when-are-you-required-to-set-objects-to-nothing.aspx

    'Set oFile = Nothing
    'Set oFso = Nothing

    On Error GoTo 0

    If nErr Then
        Err.Raise nErr, , sDesc
    End If
End Function

Answer 2

下面的脚本尝试写入文件30秒，然后放弃。当我们所有用户都必须点击脚本时，我需要这个。有可能是多个用户同时尝试写入。 OpenCSV（）尝试打开文件30次，延迟时间为1秒。

  Const ForAppending = 8

  currentDate = Year(Now) & "-" & Month(Now) & "-" & Day(Now) & " " & Hour(Now) & ":" & Minute(Now) & ":" & Second(Now)
  filepath = "\\network\path\file.csv"
  Set oCSV = OpenCSV( filepath ) 
  oCSV.WriteLine( currentDate )
  oCSV.Close

  Function OpenCSV( path )
    Set oFS = CreateObject( "Scripting.FileSystemObject" )
    For i = 0 To 30
      On Error Resume Next
      Set oFile = oFS.OpenTextFile( path, ForAppending, True )
      If Not Err.Number = 70 Then
        Set OpenCSV = oFile
        Exit For
      End If
      On Error Goto 0
      Wscript.Sleep 1000
    Next
    Set oFS = Nothing
    Set oFile = Nothing
    If Err.Number = 70 Then
      MsgBox "File " & filepath & " is locked and timeout was exceeded.", vbCritical
      WScript.Quit
    End If
  End Function

Answer 3

示例工作很好但是需要以下内容，否则你会得到错误5（非法程序）

Const ForReading = 1, ForWriting = 2, ForAppending = 8

Answer 4

或者，更简单：

假设您的 VBS 中已经有一个名为 FileName 的变量，其中包含您要测试的完整文件路径：

Dim oFso, oFile
Set oFso = CreateObject("Scripting.FileSystemObject")
Set oFile = oFso.OpenTextFile(FileName, 8, True)
If Err.Number = 0 Then oFile.Close

第 3 行尝试在启用附加权限的情况下打开您要测试的文件。例如它试图用写锁打开文件。

如果用写锁打开文件会产生错误，那么你的 VBS 将在第三行出错并且不会继续。到那时，您调用 VBS 的任何地方的错误处理都应该开始。如果您无法获得写锁定，错误消息将是“权限被拒绝”。

如果用锁打开文件不会导致错误，那么第 4 行再次关闭它。您现在可以打开文件或对其进行任何操作，确信它没有写锁定。

如何确定文件是否使用VBS锁定？

4 个答案: