默认Prolog谓词排序

Question

如果我在数据库中有一个简单谓词，是否有一种方法可以请求以特定顺序（asc / desc）返回结果，而不必将它们全部读入内存并执行sort / 2或做一个setof / 3？

例如，请考虑以下数据库：

animal(dog).
animal(cat).
animal(elephant).
animal(bird).
animal(aardvark).

我想以某种方式将动物声明为第一个术语的排序ASC，以便我可以简单地查询它：

?- animal(X).
X = aardvark ;
X = bird ;
X = cat ;
X = dog ;
X = elephant ;
No.

能够做到这一点对于更像传统数据库来处理我的知识库非常方便。

Answer 1

不，如果你不读它们就不能对它们进行排序。

Ofc你可以编写谓词排序或生成它们排序：

findall(sorted_animal(X),animal(X),Animals),
sort(Animals,SAnimals),
maplist(assertz(X),SAnimals),
compile_predicates([sorted_animal]/1).

或

findall(animal(X),animal(X),Animals),
sort(Animals, SAnimals),
retractall(animal(X)),
maplist(assertz(X),SAnimals),
compile_predicates([sorted_animal]/1).

但您必须将谓词animal/1声明为动态：

:-dynamic(animal/1).
animal(dog).
....

（在代码文件中）

我使用compile_predicates/1来提高速度;但是，这意味着您无法再对该谓词使用assert/1或retract/1，因此如果添加/删除动物，请跳过它。

或者，您可以使用ordered sets并将其作为参数传递

Answer 2

Prolog掩盖了复杂的排序问题，规定了DB访问，FIFO或LIFO的严格按时间顺序模型，默认为FIFO。这是合理的，因为这样的访问定义计算模型。

因此没有标准方法来更改子句检索顺序。

我认为goal_expansion / 2可用于引入此类功能，我将尝试原型。但我不确定我会得到任何可用的东西......

修改

首次尝试，但使用缓慢（但更简单）的撤回/断言。

/*  File:    order_by.pl
    Author:  Carlo,,,
    Created: Sep  5 2012
    Purpose: sort fact
*/
:- module(order_by,
      [order_by/2
      ]).

order_by(PredicateIndicator, Argument) :-
    (   PredicateIndicator = Module:Functor/Arity
    ;   PredicateIndicator = Functor/Arity, Module = user
    ),
    length(EmptyArgs, Arity),
    P =.. [Functor|EmptyArgs],
    findall(P, retract(Module:P), L),
    predsort(by_arg(Argument), L, S),
    maplist(assert_in_module(Module), S).

assert_in_module(Module, P) :-
    assertz(Module:P).

by_arg(Argument, Delta, E1, E2) :-
    arg(Argument, E1, A1),
    arg(Argument, E2, A2),
    (   A1 @< A2
    ->  Delta = <
    ;   Delta = >
    ).

测试文件（我在用户模块中测试过），请注意： - 动态声明是强制性的：

/*  File:    order_by_test.pl
    Author:  Carlo,,,
    Created: Sep  5 2012
    Purpose:
*/
:- [order_by].
:- dynamic animal/1.

animal(dog).
animal(cat).
animal(elephant).
animal(bird).
animal(aardvark).

test :-
    order_by(animal/1, 1),
    forall(animal(X), writeln(X)).

测试结果：

?- test.
aardvark
bird
cat
dog
elephant