Question

我在使用XSLT重命名xml标记时遇到了问题。下面是我输入的xml。

原始XML：

<soapenv:Envelope xmlns:soapenv="http://www.w3.org/2003/05/soap-envelope">
<soapenv:Body>
<ns:Response xmlns:ns="http://demo.test.classes.com">
   <ns:return>
      <ns:person>
         <ns:personName></ns:personName>
         <ns:personAge></ns:personAge>
         <ns:personAddress>
            <ns:addressType>official</ns:addressType>
            <ns:addressLine1>official address line 1</ns:addressLine1>
         </ns:personAddress>
         <ns:personAddress>
            <ns:addressType>residence</ns:addressType>
            <ns:addressLine1>residence address line 1</ns:addressLine1>
         </ns:personAddress>         
      </ns:person>
   </ns:return>
</ns:Response>
</soapenv:Body>
</soapenv:Envelope>

转换后的预期XML：这是我正在寻找的最终xml !!!

<MyResponse>
      <person>
         <personName></personName>
         <personAge></personAge>
         <personAddress>
            <addressType>official</addressType>
            <addressLine1>official address line 1</addressLine1>
         </personAddress>
         <personAddress>
            <addressType>residence</addressType>
            <addressLine1>residence address line 1</addressLine1>
         </personAddress>         
      </person>
</MyResponse>

这是XSLT，我现在正在使用。但这不是生成我需要的xml。问题是，如果我不包含模板match =“ns：Response”，则生成的xml类似于上面的xml，除了根标签为“Response”，它完全符合我的需要。但是当我引入match =“ns：Response”时，我们的xml没有格式化为xml，生成的xml包含名称空间xmlns：ns =“http://demo.test.classes.com”旁边的“MyResponse”标签。请让我知道下面的xslt应该修改什么？

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" />

    <xsl:template match="/|comment()|processing-instruction()">
        <xsl:copy>
            <xsl:apply-templates />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="*">
        <xsl:element name="{local-name()}">
            <xsl:apply-templates select="@*|node()" />
        </xsl:element>
    </xsl:template>

    <xsl:template match="@*">
        <xsl:attribute name="{local-name()}">
      <xsl:value-of select="." />
    </xsl:attribute>
    </xsl:template>

    <xsl:template xmlns:ns="http://demo.test.classes.com" match="ns:return">
    <xsl:apply-templates/>
    </xsl:template>

    <xsl:template xmlns:ns="http://demo.test.classes.com" match="ns:Response">
    <MyResponse><xsl:apply-templates select="node()|@*"/></MyResponse>
    </xsl:template>

</xsl:stylesheet>

Answer 1

此转化：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:x="http://demo.test.classes.com" exclude-result-prefixes="x">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="x:Response">
  <MyResponse>
   <xsl:apply-templates/>
  </MyResponse>
 </xsl:template>

 <xsl:template match="x:Response/*//*">
  <xsl:element name="{local-name()}">
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>
</xsl:stylesheet>

应用于提供的XML文档时：

<soapenv:Envelope xmlns:soapenv="http://www.w3.org/2003/05/soap-envelope">
<soapenv:Body>
<ns:Response xmlns:ns="http://demo.test.classes.com">
   <ns:return>
      <ns:person>
         <ns:personName></ns:personName>
         <ns:personAge></ns:personAge>
         <ns:personAddress>
            <ns:addressType>official</ns:addressType>
            <ns:addressLine1>official address line 1</ns:addressLine1>
         </ns:personAddress>
         <ns:personAddress>
            <ns:addressType>residence</ns:addressType>
            <ns:addressLine1>residence address line 1</ns:addressLine1>
         </ns:personAddress>
      </ns:person>
   </ns:return>
</ns:Response>
</soapenv:Body>
</soapenv:Envelope>

会产生想要的正确结果：

<MyResponse>
    <person>
        <personName/>
        <personAge/>
        <personAddress>
            <addressType>official</addressType>
            <addressLine1>official address line 1</addressLine1>
        </personAddress>
        <personAddress>
            <addressType>residence</addressType>
            <addressLine1>residence address line 1</addressLine1>
        </personAddress>
    </person>
</MyResponse>

Answer 2

这是另一个。这是对我对第一个问题的回答的调整。它比Dimitre的更冗长（3个模板而不是2个），但是为了补偿它可能更有效，因为匹配条件非常简单。

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:soapenv="http://www.w3.org/2003/05/soap-envelope"
    xmlns:ns="http://demo.test.classes.com"
    exclude-result-prefixes="xsl soapenv ns">
<xsl:output method="xml" indent="yes" />
<xsl:strip-space elements="*" />

<xsl:template match="*">
 <xsl:element name="{local-name()}">
  <xsl:apply-templates />
 </xsl:element>
</xsl:template>

<xsl:template match="ns:return">
  <MyResponse>
   <xsl:apply-templates/>
  </MyResponse>
</xsl:template>

<xsl:template match="soapenv:Envelope|soapenv:Body">
  <xsl:apply-templates/>
</xsl:template>

</xsl:stylesheet>

使用xslt替换xml中的标记时出现名称空间问题

2 个答案: