Question

关于F＃中元素组合的最优雅和简单实现的另一个问题。

它应该返回输入元素的所有组合（列表或序列）。第一个参数是组合中元素的数量。

例如：

comb 2 [1;2;2;3];;
[[1;2]; [1;2]; [1;3]; [2;2]; [2;3]; [2;3]]

Answer 1

比ssp更简洁，更快捷的解决方案：

let rec comb n l = 
    match n, l with
    | 0, _ -> [[]]
    | _, [] -> []
    | k, (x::xs) -> List.map ((@) [x]) (comb (k-1) xs) @ comb k xs

Answer 2

let rec comb n l =
  match (n,l) with
  | (0,_) -> [[]]
  | (_,[]) -> []
  | (n,x::xs) ->
      let useX = List.map (fun l -> x::l) (comb (n-1) xs)
      let noX = comb n xs
      useX @ noX

Answer 3

KVB的答案有更多简明版本：

let rec comb n l =
  match (n,l) with
    | (0,_) -> [[]]
    | (_,[]) -> []
    | (n,x::xs) ->
      List.flatten [(List.map (fun l -> x::l) (comb (n-1) xs)); (comb n xs)]

Answer 4

如果您熟悉树递归，那么接受的答案很华丽且很容易理解。由于寻求优雅，打开这个漫长的休眠线程似乎有点不必要。

但是，要求提供更简单的解决方案。迭代算法有时候对我来说似乎更简单。此外，性能被提及作为质量的指标，迭代过程有时比递归过程更快。

以下代码是尾递归并生成迭代过程。它需要三分之一的时间来从24个元素的列表中计算大小为12的组合。

let combinations size aList = 
    let rec pairHeadAndTail acc bList = 
        match bList with
        | [] -> acc
        | x::xs -> pairHeadAndTail (List.Cons ((x,xs),acc)) xs
    let remainderAfter = aList |> pairHeadAndTail [] |> Map.ofList
    let rec comboIter n acc = 
        match n with
        | 0 -> acc
        | _ -> 
            acc
            |> List.fold (fun acc alreadyChosenElems ->
                match alreadyChosenElems with
                | [] -> aList //Nothing chosen yet, therefore everything remains.
                | lastChoice::_ -> remainderAfter.[lastChoice]
                |> List.fold (fun acc elem ->
                    List.Cons (List.Cons (elem,alreadyChosenElems),acc)
                ) acc
            ) []
            |> comboIter (n-1)
    comboIter size [[]]

允许迭代过程的想法是将最后选择的元素的映射预先计算为剩余可用元素的列表。此地图存储在remainderAfter中。

代码不简洁，也不符合抒情米和押韵。

Answer 5

使用序列表达式的天真实现。我个人经常觉得序列表达式比其他更密集的函数更容易理解。

netaddr

Answer 6

取自离散数学及其应用的方法。结果返回存储在数组中的有序组合列表。索引是从1开始的。

let permutationA (currentSeq: int []) (n:int) (r:int): Unit = 
    let mutable i = r
    while currentSeq.[i - 1] = n - r + i do
        i <- (i - 1)
    currentSeq.[i - 1] <- currentSeq.[i - 1] + 1
    for j = i + 1 to r do
        currentSeq.[j - 1] <- currentSeq.[i - 1] + j - i   
    ()
let permutationNum (n:int) (r:int): int [] list =
    if n >= r then
        let endSeq = [|(n-r+1) .. n|]
        let currentSeq: int [] = [|1 .. r|]
        let mutable resultSet: int [] list = [Array.copy currentSeq];
        while currentSeq <> endSeq do
            permutationA currentSeq n r
            resultSet <- (Array.copy currentSeq) :: resultSet
        resultSet
    else
        []

这个解决方案很简单，辅助函数需要恒定的内存。

Answer 7

我的解决方案不那么简洁，效率较低（虽然没有使用直接递归），但它真正返回所有组合（目前只有对，需要扩展filterOut以便它可以返回两个列表的元组，稍后会做）。

let comb lst =
    let combHelper el lst =
        lst |> List.map (fun lstEl -> el::[lstEl])
    let filterOut el lst =
        lst |> List.filter (fun lstEl -> lstEl <> el)
    lst |> List.map (fun lstEl -> combHelper lstEl (filterOut lstEl lst)) |> List.concat

梳子[1; 2; 3; 4]将返回： [[1; 2]; [1; 3]; [1; 4]; [2; 1]; [2; 3]; [2; 4]; [3; 1]; [3; 2]; [3; 4]; [4; 1]; [4; 2]; [4; 3]

Answer 8

好的，只是尾部组合有点不同的方法（不使用库函数）

let rec comb n lst =
    let rec findChoices = function
      | h::t -> (h,t) :: [ for (x,l) in findChoices t -> (x,l) ]
      | []   -> []
    [ if n=0 then yield [] else
            for (e,r) in findChoices lst do
                for o in comb (n-1) r do yield e::o  ]

F＃中最优雅的元素组合

8 个答案: