Question

我想创建一个子程序，它向元素添加逗号，并在最后一个元素之前添加“和”，例如，使“12345”变为“1,2,3,4和5”。我知道如何添加逗号，但问题是我得到的结果是“1,2,3,4和5”，我不知道如何摆脱最后一个逗号。

sub commas {
  my @with_commas;
  foreach (@_) {
    push (@with_commas, ($_, ", ")); #up to here it's fine
    }
    splice @with_commas, -2, 1, ("and ", $_[-1]);
    @with_commas;
  }

你可以告诉我，我正在尝试删除新数组中的最后一个元素（@with_commas），因为它附加了逗号，并添加旧数组中的最后一个元素（@_，传递给来自主程序的子例程，没有添加逗号）。

当我运行它时，结果是，例如，“1,2,3,4和5” - 最后用逗号表示。这个逗号来自哪里？只有@with_commas才能得到逗号。

感谢任何帮助。

Answer 1

sub format_list {
   return "" if !@_;
   my $last = pop(@_);
   return $last if !@_;
   return join(', ', @_) . " and " . $last;
}

print format_list(@list), "\n";

这也处理只包含一个元素的列表，与大多数其他答案不同。

Answer 2

您可以使用join并修改最后一个元素以包含and：

my @list = 1 .. 5;
$list[-1] = "and $list[-1]" if $#list;
print join ', ', @list;

Answer 3

有一个CPAN模块，Lingua::Conjunction。我自己使用它，推荐它滚动你自己的解决方案。用法语法非常简单：

conjunction(@list);

Answer 4

#!/usr/bin/perl

use warnings;
use strict;

sub commas {
  return ""    if @_ == 0;
  return $_[0] if @_ == 1;
  my $last = pop @_; 
  my $rest = join (", ", @_);
  return $rest.", and ".$last;
}

my @a = (1,2,3,4,5);
print commas(@a), "\n";

Answer 5

添加逗号，然后添加“和”：

use v5.10;

my $string = join ', ', 1 .. 5;

substr 
    $string, 
    rindex( $string, ', ' ) + 2,
    0,
    'and '
    ;

say $string;

所以，在你有两个以上元素的情况下工作：

use v5.10;

my @array = 1..5;
my $string = do {
    if( @array == 1 ) {
        @array[0];
        }
    elsif( @array == 2 ) {
        join ' and ', @array
        }
    elsif( @array > 2 ) {   
        my $string = join ', ', @array;

        my $commas = $string =~ tr/,//;

        substr 
            $string, 
            rindex( $string, ', ' ) + 2,
            0,
            'and '
            ;

        $string;
        }
    };      

say $string;

Answer 6

正是在TIMTOWTDI的精神中（坦率地说，@ perreal的答案在可读性方面更好）：

sub commas {
    my $last_index = $#_;
    my @with_commas = map { (($_==$last_index) ? "and " : "") . $_[$_] }
                          0 .. $last_index;
    print join("," @with_commas)
}

这有点类似于Alan的答案（更复杂/复杂），但与之相比的好处是，如果您需要将“和”添加到除最后一个之外的任何OTHER元素，它将起作用;只有当你知道确切的偏移量（例如最后一个元素）

时，Alan才有效

Answer 7

小提示

for( 1 .. 10 ) {
     print ;
     $_ == 10 ? print '' : ($_ != 9 ? print ', ' : print ' and ');
}

在Perl中的逗号插值数组中的最后一个元素之前添加“和”

7 个答案: