Question

如果从.Net应用程序传递的字符串如下所示

2023|F66451,1684|648521,1684|600271,2137|019592

我已经开始使用下面的方法解析字符串了但我需要透视从Split返回的数据（由*'s包围）以便插入到#tmpExceptions表中

DECLARE @ExceptionsList as nvarchar(MAX)

SET @ExceptionsList = '2023|F66451,1684|648521,1684|600271,2137|019592'

SET NOCOUNT ON;

DECLARE @CurrentLineItem as nvarchar(255)

CREATE TABLE #ParsePassOne
(
    LineItem nvarchar(255)
)

CREATE TABLE #tmpExceptions
(
    AccountNumber int,
    ClaimNumber nvarchar(50)
)

INSERT INTO #ParsePassOne
    SELECT value FROM Split( ',' ,@ExceptionsList)

WHILE EXISTS(SELECT LineItem FROM #ParsePassOne)
    BEGIN
        SELECT TOP 1 @CurrentLineItem = LineItem FROM #ParsePassOne

        *******
            SELECT value FROM Split( '|' ,@CurrentLineItem) 
            *******

        DELETE FROM #ParsePassOne WHERE LineItem = @CurrentLineItem
    END

SELECT * FROM #tmpExceptions

DROP TABLE #ParsePassOne
DROP TABLE #tmpExceptions

到目前为止，返回的数据如下所示。我只需要将数据转移到列，以便我可以插入它。我该怎么做？

enter image description here

拆分功能

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
--Creates an 'InLine' Table Valued Function (TVF)
ALTER FUNCTION [dbo].[Split] 
   (  @Delimiter varchar(5), 
      @List      varchar(8000)
   ) 
   RETURNS @TableOfValues table 
      (  RowID   smallint IDENTITY(1,1), 
         [Value] varchar(50) 
      ) 
AS 
   BEGIN

      DECLARE @LenString int 

      WHILE len( @List ) > 0 
         BEGIN 

            SELECT @LenString = 
               (CASE charindex( @Delimiter, @List ) 
                   WHEN 0 THEN len( @List ) 
                   ELSE ( charindex( @Delimiter, @List ) -1 )
                END
               ) 

            INSERT INTO @TableOfValues 
               SELECT substring( @List, 1, @LenString )

            SELECT @List = 
               (CASE ( len( @List ) - @LenString ) 
                   WHEN 0 THEN '' 
                   ELSE right( @List, len( @List ) - @LenString - 1 ) 
                END
               ) 
         END

      RETURN 

   END

Answer 1

您可以用

替换WHILE EXISTS(SELECT LineItem FROM #ParsePassOne)循环

select *
from
(
select * from #parsepassone
    cross apply dbo.Split( '|' ,lineitem)  
) src
pivot
(max(value) for rowid in ([1],[2]))p

或用

替换整个事物

insert #tmpExceptions (AccountNumber, ClaimNumber)
select [1],[2]
from
(
select e.rowid e, p.* from dbo.Split( ',' ,@ExceptionsList) e
    cross apply dbo.Split( '|' ,e.value) p ) s
pivot
(max(value) for rowid in ([1],[2]))p

Answer 2

如果您使用的是SQL Server 2016，则可以使用String_Split（）函数并使用cross apply / pivot进入单行

create table #t (v varchar(50), i int)
insert into #t (v, i) values ('2023|F66451',1)
,('1684|648521',2), ('1684|600271', 3), ('2137|019592', 4)

--Inorder to get into same row -pivoting the data
select * from (
select * from #t t cross apply (select RowN=Row_Number() over (Order by (SELECT NULL)), value from string_split(t.v, '|') ) d) src
pivot (max(value) for src.RowN in([1],[2])) p

Answer 3

我有一个类似的问题，我需要在列中拆分和旋转值，并且需要在视图中全部显示。

我想出了以下代码（适用于SQL 2016及更高版本）

/* Table */
DECLARE @data TABLE (id INT IDENTITY(1,1), [Name] VARCHAR(128) NOT NULL, [Selection] VARCHAR(512) NULL)

INSERT INTO @data ([Name],Selection)
VALUES('Bob','PC; Mouse; Keyboard; Network; Smartphone'),
('Mo','Violin; Hammer'),
('Jon','Magic; Blood; Teleporter'),
('Mhary','Vampire')

/* Pivot */
;WITH Data_RowNumber AS (
    SELECT
        id,
        [name],
        split.value,
        ROW_NUMBER() OVER (PARTITION BY id ORDER BY id) AS RowNumber
    FROM @data
    CROSS APPLY STRING_SPLIT([Selection],';') AS split
)
SELECT 
    id,
    [name],
    [1],[2],[3],[4],[5],[6]
FROM Data_RowNumber
PIVOT (
    MAX([value])
    FOR [RowNumber] IN ([1],[2],[3],[4],[5],[6])
    ) AS p

拆分字符串然后旋转结果

3 个答案: