Question

我在Delphi中有一个基本的疑问。当我在设计时保留任何组件时，例如TADOConnectuion和按钮点击甚至我写下面的代码然后我没有得到任何错误：

begin
  ADOConnection.Free;  //No error
  ADOConnection.Free;  //No error
  ADOConnection.Free;  //No error
end;

但是如果我在运行时创建相同的对象，则会出现“Access Violation ...”错误

begin
  ADOConnection := TADOConnection.create(self);
  ADOConnection.Free;  //No error
  ADOConnection.Free;  //Getting an "Access Violation..." error
end;

即使我创建了如下对象，我也得到了同样的错误：

ADOConnection := TADOConnection.create(nil);

我想知道这种行为背后的原因，即为什么在设计时保留组件时没有错误？

Answer 1

如果释放组件，则清除其所有者中的相应字段。如果您添加设计时ADOConnection，那么

ADOConnection.Free; // Frees ADOConnection and sets ADOConnection to nil
ADOConnection.Free; // Does nothing since ADOConnection is nil

您可以通过在变量中捕获它来看到这一点：

var c: TADOConnection;
c := ADOConnection;
c.Free; // Frees ADOConnection and sets ADOConnection to nil
c.Free; // Error: c is not set to nil

即使在设计时创建ADOConnection，这也行不通。

以下是一个TButton组件示例，演示了您在设计时组件中看到的行为与特定于设计时组件的关系：

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  published
    Button: TButton;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  Assert(not Assigned(Button));
  TButton.Create(Self).Name := 'Button'; // Button field gets set
  Assert(Assigned(Button));
  Button.Free;                           // Button field gets cleared
  Assert(not Assigned(Button));
  Button.Free;                           // Okay, Free may be called on nil values
end;

end.

Answer 2

ADOConnection最初为零，所以如果你释放它，自由函数将不会做任何事情，因为传递给它的指针是零。指针在后续调用中保持为零，因此free保持不执行任何操作。使用create初始化ADOConnection时，ADOConnection中保存的指针不再为nil，因此第一次调用free将主动释放指针，但后续调用将看到内存已被释放并引发异常。调用free时指针不会改变。为此，你需要freeandnil。

Delphi中“免费”的基础

2 个答案: