Question

我正在尝试使用JDK Transformer（Oracle XML v2 Parser或JAXP）在XSLT转换期间使用参数传递的值将xmlns属性添加到生成的XML中，但它始终默认为http://www.w3.org/2000/xmlns/

我的源XML

<test/>

我的XSLT

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns="http://example.com">
    <xsl:param name="myNameSpace" select="'http://neilghosh.com'"/>
    <xsl:template match="/">
        <process>
            <xsl:attribute name="xmlns:neil">
                <xsl:value-of select="$myNameSpace"/>
            </xsl:attribute>
        </process>
    </xsl:template>
</xsl:stylesheet>

我的结果

<?xml version="1.0"?>
<process xmlns="http://www.w3.org/2000/xmlns/" xmlns:neil="neilghosh.com">
</process>

我想要的结果

<?xml version="1.0"?>
<process xmlns="http://example.com"  xmlns:neil="neilghosh.com">
</process>

Answer 1

首先，在XSLT数据模型中，您不想创建属性节点，而是要创建命名空间节点。

命名空间节点通常是自动创建的：如果在特定命名空间中创建元素或属性，则处理器会自动添加必需的命名空间节点（因此，在序列化时，命名空间声明）。

如果要创建一个不必要的命名空间节点（因为它没有在任何元素或属性的名称中使用），那么在XSLT 2.0中，您可以使用xsl：namespace。如果您仍然坚持使用XSLT 1.0，那么需要解决方法，包括在相关命名空间中创建一个元素，然后复制其命名空间节点：

<xsl:variable name="ns">
  <xsl:element name="neil:dummy" namespace="{$param}"/>
</xsl:variable>
<process>
  <xsl:copy-of select="$ns/*/namespace::neil"/>
</process>

Answer 2

Michael Kay为您提供了正确答案，但根据您的评论，您不确定如何在转型中使用它。

这是一个完整的转型：

 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pNamespace" select="'neilghosh.com'"/>

 <xsl:variable name="vDummy">
   <xsl:element name="neil:x" namespace="{$pNamespace}"/>
 </xsl:variable>

 <xsl:template match="/*">
  <xsl:element name="process" namespace="http://example.com">
    <xsl:copy-of select="namespace::*"/>
    <xsl:copy-of select="ext:node-set($vDummy)/*/namespace::*[.=$pNamespace]"/>
  </xsl:element>
 </xsl:template>
 </xsl:stylesheet>

在提供的XML文档上应用此转换时：

<test/>

产生了想要的正确结果：

<process xmlns="http://example.com" xmlns:neil="neilghosh.com" />

Answer 3

XML中的命名空间声明不是属性，即使它们看起来像属性。在XSLT 2.0中，您可以使用<xsl:namespace name="neil" select="$myNameSpace" />动态地向结果树添加名称空间声明，但该功能在XSLT 1.0中不可用。

Answer 4

不要尝试自己创建“xmlns”属性。在XSLT中创建名称空间，它们将自动完成。这个XSLT可以工作（用Saxon 9.4测试）：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:neil="neilghosh.com"    
xpath-default-namespace="http://example.com"
xmlns="http://example.com" version="2.0">

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:param name="myDynamicNamespace" select="'http://neilghosh.com'"/>

<xsl:template match="/">
    <xsl:element name="process">   
        <xsl:namespace name="neil" select="$myDynamicNamespace"/>
    </xsl:element>
</xsl:template>
</xsl:stylesheet>

并提供以下输出：

<?xml version="1.0" encoding="UTF-8"?>
<process xmlns="http://example.com" xmlns:neil="http://neilghosh.com"/>

Answer 5

最后得到了一个与我的XSLT处理器（Oracle XML V2 Parser）配合使用的解决方法

我必须transform it to a DOM Document，然后将DOM保存到文件系统，而不是直接输出到StreamResult

我在DOMResult

中使用了transform method

在XSLT片段工作之后，但是有一个额外的xmlns：xmlns =“http://www.w3.org/2000/xmlns/”，它可能被Document吸收，并没有出现在最终输出中当我坚持归档系统时。

 <process>    
      <xsl:attribute name="xmlns">
        <xsl:value-of select="'http://example.com'"/>
      </xsl:attribute> 
 <process>

我知道这不是最好的方法，但鉴于解析约束，这是我现在唯一的选择。

使用XSLT Transformation在XML中创建xmlns属性

5 个答案: