Question

我正在进行长循环下载数千个文件。我想显示剩余的估计时间，因为它可能需要数小时。但是，根据我的编写，我得到平均数毫秒。如何将此平均下载时间从毫秒转换为TDateTime？

查看我在哪里设置Label1.Caption：

procedure DoWork;
const
  AVG_BASE = 20; //recent files to record for average, could be tweaked
var
  Avg: TStringList; //for calculating average
  X, Y: Integer; //loop iterators
  TS, TE: DWORD; //tick counts
  A: Integer; //for calculating average
begin
  Avg:= TStringList.Create;
  try
    for X:= 0 to FilesToDownload.Count - 1 do begin //iterate through downloads
      if FStopDownload then Break; //for cancelling
      if Avg.Count >= AVG_BASE then //if list count is 20
        Avg.Delete(0); //remove the oldest average
      TS:= GetTickCount; //get time started
      try
        DownloadTheFile(X); //actual file download process
      finally
        TE:= GetTickCount - TS; //get time elapsed
      end;
      Avg.Add(IntToStr(TE)); //add download time to average list
      A:= 0; //reset average to 0
      for Y:= 0 to Avg.Count - 1 do //iterate through average list
        A:= A + StrToIntDef(Avg[Y], 0); //add to total download time
      A:= A div Avg.Count; //divide count to get average download time
      Label1.Caption:= IntToStr(A); //<-- How to convert to TDateTime?
    end;
  finally
    Avg.Free;
  end;
end;

PS - 我对计算过去20（或AVG_BASE）下载的平均速度有不同的方式，因为我确信我的字符串列表解决方案并不是最好的。我不想根据所有下载来计算它，因为速度可能会在那段时间内发生变化。因此，我只是查看过去的20个。

Answer 1

TDateTime值基本上是double，其中整数部分是天数，分数是时间。

在一天中有24 * 60 * 60 = 86400秒（在SysUtils中声明的SecsPerDay常量）所以得到A作为TDateTime do：

dt := A/(SecsPerDay*1000.0); // A is the number of milliseconds

计算时间的更好方法是在单位TStopWatch中使用Diagnostics构造。

示例：

sw.Create;
.. 
sw.Start;
// Do something
sw.Stop;
A := sw.ElapsedMilliSeconds;
// or as RRUZ suggested ts := sw.Elapsed; to get the TimeSpan

要获得平均时间，请考虑使用此moving average记录：

Type
  TMovingAverage = record
  private
    FData: array of integer;
    FSum: integer;
    FCurrentAverage: integer;
    FAddIx: integer;
    FAddedValues: integer;
  public
    constructor Create(length: integer);
    procedure Add( newValue: integer);
    function Average : Integer;
  end;

procedure TMovingAverage.Add(newValue: integer);
var i : integer;
begin
  FSum := FSum + newValue - FData[FAddIx];
  FData[FAddIx] := newValue;
  FAddIx := (FAddIx + 1) mod Length(FData);
  if (FAddedValues < Length(FData)) then
    Inc(FAddedValues);
  FCurrentAverage := FSum div FAddedValues;
end;

function TMovingAverage.Average: Integer;
begin
  Result := FCurrentAverage;
end;

constructor TMovingAverage.Create(length: integer);
var
  i : integer;
begin
  SetLength( FData,length);
  for i := 0 to length - 1 do
    FData[i] := 0;
  FSum := 0;
  FCurrentAverage := 0;
  FAddIx := 0;
  FAddedValues := 0;
end;

Answer 2

您可以使用TTimeSpan记录代替TDateTime，您可以创建一个新实例，将经过的刻度传递到constructor，然后您可以使用天，小时，分钟，秒和毫秒属性，用于显示已用时间。现在计算剩余时间，您需要下载的总字节数和当前下载的字节数。

如何将毫秒转换为TDateTime？

2 个答案: