Question

是否可以向现有MUI页面添加窗口（Label）;喜欢安装页面，欢迎页面？

我想在安装程序页面添加一个新标签。我的代码在窗口中添加了一个新的静态窗口，但它从未显示/位于其他窗口之上。 我知道窗口存在是因为我可以使用WinSpy ++看到它，但它位于另一个窗口后面。此外，新窗口还有一个有趣的风格“Style：50000000（隐藏，启用）”，而其他常规静态窗口则有风格“风格：5000008C（可见，启用）”。

如何显示我的标签（静态窗口）？

!include nsdialogs.nsh
!include MUI2.nsh

!define MUI_PAGE_CUSTOMFUNCTION_SHOW instshow

!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"

OutFile "test.exe"

Function instshow
    FindWindow $0 "#32770" "" $HWNDPARENT
    GetDlgItem $2 $0 1016
    System::Call 'USER32::CreateWindowEx(i0,t "STATIC",t "Some option",i ${WS_CHILD}|${WS_VISIBLE},i100,i100,i100,i20,i$2,i666,i0,i0) $R2'
    System::Call `user32::SetWindowPos(i $R2, i ${HWND_TOP}, i 0, i 0, i 0, i 0, i ${SWP_NOSIZE}|${SWP_NOMOVE})` # attempt to push new label to front

    # Attempt to refresh new labels parent window
    GetDlgItem $R0 $HWNDPARENT 1016
    ShowWindow $R0 ${SW_HIDE}
    ShowWindow $R0 ${SW_SHOW}
    # Attempt to refresh new label 
    ShowWindow $R2 ${SW_HIDE}
    ShowWindow $R2 ${SW_SHOW}
FunctionEnd


Section "Dummy"

SectionEnd

Answer 1

好的，他是怎么做的。感谢Anders的建议

!include nsdialogs.nsh
!include MUI2.nsh

!define MUI_PAGE_CUSTOMFUNCTION_SHOW instshow

!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"

OutFile "test.exe"

Function instshow
    FindWindow $0 "#32770" "" $HWNDPARENT
    System::Call 'USER32::CreateWindowEx(i0,t "STATIC",t "Some text",i ${WS_CHILD}|${WS_VISIBLE},i100,i100,i100,i20,i $0,i222,i0,i0) $R2'

    GetDlgItem $1 $0 1027
    GetDlgItem $2 $0 222
    SendMessage $1 ${WM_GETFONT} 0 0 $3
    SendMessage $2 ${WM_SETFONT} $3 1
FunctionEnd


Section "Dummy"

SectionEnd

将窗口添加到现有MUI页面

1 个答案: