Question

在问题Tacit function composition in Haskell 的评论中，有人提到为Num制作a -> r个实例，所以我认为我会使用函数表示法来表示乘法：

{-# LANGUAGE TypeFamilies #-}
import Control.Applicative

instance Show (a->r) where   -- not needed in recent GHC versions
  show f = " a function "

instance Eq (a->r) where     -- not needed in recent GHC versions
  f == g = error "sorry, Haskell, I lied, I can't really compare functions for equality"

instance (Num r,a~r) => Num (a -> r) where
  (+) = liftA2 (+)
  (-) = liftA2 (-)
  (*) = liftA2 (*)
  abs = liftA abs
  negate = liftA negate
  signum = liftA signum
  fromInteger a = (fromInteger a *)

请注意，fromInteger定义意味着我可以编写3 4，其评估为12，7 (2+8)为70，正如您所希望的那样。

然后这一切都奇妙，令人感到奇怪！如果可以的话，请解释这个奇怪的事情：

*Main> 1 2 3
18
*Main> 1 2 4
32
*Main> 1 2 5
50
*Main> 2 2 3
36
*Main> 2 2 4
64
*Main> 2 2 5
100
*Main> (2 3) (5 2)
600

[编辑：使用Applicative代替Monad，因为Applicative很普遍，但它对代码没有多大影响。]

Answer 1

在与2 3 4类似的表达式中，2和3都是函数。因此，2实际上是(2 *)，其类型为Num a => a -> a。 3是一样的。然后2 3为(2 *) (3 *)，与2 * (3 *)相同。根据您的实例，这是liftM2 (*) 2 (3 *)，然后是liftM2 (*) (2 *) (3 *)。现在这个表达式可以在没有任何实例的情况下运行。

那是什么意思？那么，函数的liftM2是一种双重组合。特别是，liftM2 f g h与\ x -> f (g x) (h x)相同。那么liftM2 (*) (2 *) (3 *)就是\ x -> (*) ((2 *) x) ((3 *) x)。简化一下，我们得到：\ x -> (2 * x) * (3 * x)。现在我们知道2 3 4实际上是(2 * 4) * (3 * 4)。

现在，为什么liftM2函数以这种方式工作？让我们看一下(->) r的monad实例（请记住(->) r是(r ->)但我们不能编写类型级操作符部分）：

instance Monad ((->) r) where  
    return x = \_ -> x  
    h >>= f = \w -> f (h w) w

所以return是const。 >>=有点奇怪。我认为从join方面来看更容易。对于函数，join的工作方式如下：

join f = \ x -> f x x

也就是说，它使用两个参数的函数，并通过使用该参数两次将其转换为一个参数的函数。很简单。这个定义也很有意义。对于函数，join必须将两个参数的函数转换为一个函数;唯一合理的方法是两次使用那个参数。

>>=为fmap，后跟join。对于函数，fmap只是(.)。所以现在>>=等于：

h >>= f = join (f . h)

只是：

h >>= f = \ x -> (f . h) x x

现在我们摆脱.来获取：

h >>= f = \ x -> f (h x) x

现在我们知道>>=如何运作，我们可以看一下liftM2。 liftM2定义如下：

liftM2 f a b = a >>= \ a' -> b >>= \ b' -> return (f a' b')

我们可以一点一点地这样做。首先，return (f a' b')变为\ _ -> f a' b'。结合\ b' ->，我们得到：\ b' _ -> f a' b'。然后b >>= \ b' _ -> f a' b'变成：

 \ x -> (\ b' _ -> f a' b') (b x) x

由于第二个x被忽略，我们得到：\ x -> (\ b' -> f a' b') (b x)，然后缩减为\ x -> f a' (b x)。所以这给我们留下了：

a >>= \ a' -> \ x -> f a' (b x)

再次，我们替换>>=：

\ y -> (\ a' x -> f a' (b x)) (a y) y

这减少到：

 \ y -> f (a y) (b y)

这正是我们之前用作liftM2的内容！

希望现在2 3 4的行为完全有道理。

数字作为乘法函数（奇怪但有趣）

1 个答案: