Question

我只是需要帮助在我的存储过程中实现删除级联，因为我有REFERENCE约束错误

Create PROCEDURE [dbo].[DeleteProject]
    @ProjectID uniqueidentifier
AS
BEGIN
    -- Insert statements for procedure here
    DELETE FROM [TaskManagementSystem_DB].[dbo].[Projects]
    WHERE projectID = @ProjectID
END

Answer 1

您没有在proc中实现删除级联。

您可以在foriegn键约束本身上实现delete cascase：

ALTER TABLE [ChildTable] WITH CHECK ADD CONSTRAINT [FK_ChildTable_Projects] FOREIGN KEY ([ProjectID})
REFERENCES [Project] ([ProjectID])
ON DELETE CASCADE

或者您需要在删除主记录之前显式删除子记录。

Create PROCEDURE [dbo].[DeleteProject]
@ProjectID uniqueidentifier
AS
BEGIN

DELETE child
FROM [TaskManagementSystem_DB].[dbo].[Projects] proj
    JOIN [TaskManagementSystem_DB].[dbo].[ChildTable] child
        ON proj.ProjectID = child.ProjectID

DELETE FROM [TaskManagementSystem_DB].[dbo].[Projects]
    WHERE projectID = @ProjectID

END

Answer 2

在这里，您可以找到一个实现，删除指定表中符合所选条件的所有行，同时删除任何子/孙记录等。
它首先读取sysforeignkeys表以查找任何子表，然后使用对此过程的递归调用从中删除即将成为孤立的记录。所有子记录消失后，将从选定的表中删除行：Awesome SQL Delete Cascade Stored Procedure!

这是代码，以防您在链接后遇到问题：

CREATE Procedure spDeleteRows
/* 
Recursive row delete procedure. 

It deletes all rows in the table specified that conform to the criteria selected, 
while also deleting any child/grandchild records and so on.  This is designed to do the 
same sort of thing as Access's cascade delete function. It first reads the sysforeignkeys 
table to find any child tables, then deletes the soon-to-be orphan records from them using 
recursive calls to this procedure. Once all child records are gone, the rows are deleted 
from the selected table.   It is designed at this time to be run at the command line. It could 
also be used in code, but the printed output will not be available.
*/
 (
 @cTableName varchar(50), /* name of the table where rows are to be deleted */
 @cCriteria nvarchar(1000), /* criteria used to delete the rows required */
 @iRowsAffected int OUTPUT /* number of records affected by the delete */
 )
As
set nocount on
declare  @cTab varchar(255), /* name of the child table */
 @cCol varchar(255), /* name of the linking field on the child table */
 @cRefTab varchar(255), /* name of the parent table */
 @cRefCol varchar(255), /* name of the linking field in the parent table */
 @cFKName varchar(255), /* name of the foreign key */
 @cSQL nvarchar(1000), /* query string passed to the sp_ExecuteSQL procedure */
 @cChildCriteria nvarchar(1000), /* criteria to be used to delete 
                                           records from the child table */
 @iChildRows int /* number of rows deleted from the child table */

/* declare the cursor containing the foreign key constraint information */
DECLARE cFKey CURSOR LOCAL FOR 
SELECT SO1.name AS Tab, 
       SC1.name AS Col, 
       SO2.name AS RefTab, 
       SC2.name AS RefCol, 
       FO.name AS FKName
FROM dbo.sysforeignkeys FK  
INNER JOIN dbo.syscolumns SC1 ON FK.fkeyid = SC1.id 
                              AND FK.fkey = SC1.colid 
INNER JOIN dbo.syscolumns SC2 ON FK.rkeyid = SC2.id 
                              AND FK.rkey = SC2.colid 
INNER JOIN dbo.sysobjects SO1 ON FK.fkeyid = SO1.id 
INNER JOIN dbo.sysobjects SO2 ON FK.rkeyid = SO2.id 
INNER JOIN dbo.sysobjects FO ON FK.constid = FO.id
WHERE SO2.Name = @cTableName

OPEN cFKey
FETCH NEXT FROM cFKey INTO @cTab, @cCol, @cRefTab, @cRefCol, @cFKName
WHILE @@FETCH_STATUS = 0
     BEGIN
 /* build the criteria to delete rows from the child table. As it uses the 
           criteria passed to this procedure, it gets progressively larger with 
           recursive calls */
 SET @cChildCriteria = @cCol + ' in (SELECT [' + @cRefCol + '] FROM [' + 
                              @cRefTab +'] WHERE ' + @cCriteria + ')'
 print 'Deleting records from table ' + @cTab
 /* call this procedure to delete the child rows */
 EXEC spDeleteRows @cTab, @cChildCriteria, @iChildRows OUTPUT
 FETCH NEXT FROM cFKey INTO @cTab, @cCol, @cRefTab, @cRefCol, @cFKName
     END
Close cFKey
DeAllocate cFKey
/* finally delete the rows from this table and display the rows affected  */
SET @cSQL = 'DELETE FROM [' + @cTableName + '] WHERE ' + @cCriteria
print @cSQL
EXEC sp_ExecuteSQL @cSQL
print 'Deleted ' + CONVERT(varchar, @@ROWCOUNT) + ' records from table ' + @cTableName

如何在存储过程中使用删除级联？

2 个答案: