Question

这两个模板之间有什么区别？

<xsl:template match="node()">

<xsl:template match="*">

Answer 1

<xsl:template match="node()">

是：

的缩写

<xsl:template match="child::node()">

匹配可通过the child::轴选择的任何节点类型：

元素
文本节点
处理指令（PI）节点
评论节点。

另一方：

<xsl:template match="*">

是：

的缩写

<xsl:template match="child::*">

匹配任何元素。

XPath表达式：someAxis :: *匹配给定轴的主节点类型的任何节点。

对于child::轴，主节点类型为元素。

Answer 2

只是为了说明其中一个差异，即*与text不匹配：

给出xml：

<A>
    Text1
    <B/>
    Text2
</A>

匹配node()

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

    <!--Suppress unmatched text-->
    <xsl:template match="text()" />

    <xsl:template match="/">
        <root>
            <xsl:apply-templates />
        </root>
    </xsl:template>

    <xsl:template match="node()">
        <node>
            <xsl:copy />
        </node>
        <xsl:apply-templates />
    </xsl:template>
</xsl:stylesheet>

给出：

<root>
    <node>
        <A />
    </node>
    <node>
        Text1
    </node>
    <node>
        <B />
    </node>
    <node>
        Text2
    </node>
</root>

匹配*：

<xsl:template match="*">
    <star>
        <xsl:copy />
    </star>
    <xsl:apply-templates />
</xsl:template>

与文本节点不匹配。

<root>
  <star>
    <A />
  </star>
  <star>
    <B />
  </star>
</root>

Answer 3

另请参阅XSL xsl:template match="/" 其他比赛模式。

XSLT中*和node（）之间的区别

3 个答案: