Question

如何使用actionscript 3随机化数组？

Answer 1

使用Array.sort（）函数有一个简短的版本：

var arr : Array = [0,1,2,3,4,5,6,7,8,9];

function randomize ( a : *, b : * ) : int {
    return ( Math.random() > .5 ) ? 1 : -1;
}

trace( arr.sort( randomize ) );

如果你没有“足够”随机性，你可以排序两次：）

编辑 - 逐行说明：

对于Array类方法sort()，您不仅可以传递Array.CASEINSENSITIVE, Array.DESCENDING等排序选项，还可以传递自己的自定义比较函数引用（回调），它接受两个参数（两个数组中的元素进行比较）。来自AS3文档：

比较函数应该有两个参数进行比较。给定元素A和B，compareFunction的结果可以具有负值，0或正值：


负返回值指定A在排序序列中出现在B之前。

返回值0指定A和B具有相同的排序顺序。

正返回值指定A在排序序列中出现在B之后。

注意：比较函数参数可能是键入的（如果您的数组是键入的）并且有任何您想要的名称，例如：

function compareElements ( elementA : SomeClass, elementB : SomeClass ) : int;

当您需要按特殊属性对数组元素进行排序时，此方法非常有用。在随机化的情况下，compareFunction随机返回-1, 0或1并使数组元素切换其位置（索引）。我发现，当方法仅返回-1和1时，更好的随机化（在我的主观和数学上未经测试的观点）。另外请记住，使用自定义比较函数doesn't compare elements sequentially排序函数，因此在某些特殊情况下，随机化结果可能与您的预期不同。

Answer 2

有一种更好的方法可以让你在适当的位置随机化数组，如果你需要，它不会让你创建更多的原始数组的单个副本。

package
{
    import flash.display.Sprite;

    public class RandomizeArrayExample extends Sprite
    {
        public function RandomizeArrayExample()
        {
            super();
            testDistribution();
        }

        private function testDistribution():void
        {
            var hash:Object = { };
            var tester:Array = [1, 2, 3, 4];
            var key:String;

            for (var i:int; i < 1e5; i++)
            {
                randomize(tester);
                key = tester.join("");
                if (key in hash) hash[key]++;
                else hash[key] = 1;
            }
            for (var p:String in hash) trace(p, "=>", hash[p]);
        }

        private function randomize(array:Array):Array
        {
            var temp:Object;
            var tempOffset:int;
            for (var i:int = array.length - 1; i >= 0; i--)
            {
                tempOffset = Math.random() * i;
                temp = array[i];
                array[i] = array[tempOffset];
                array[tempOffset] = temp;
            }
            return array;
        }
    }
}

Answer 3

我发现这非常有帮助。我希望它也可以帮助你。

// Array to Randomize
var firstArray:Array = ["One","Two","Three","Four","Five","six","seven","eight","nine","ten"];
trace(firstArray); // Prints in order

var newArray:Array = new Array();
function randomizeArray(array:Array):Array
{
    var newArray:Array = new Array();

    while (array.length > 0)
    {
        newArray.push(array.splice(Math.floor(Math.random()*array.length), 1));
    }

    return newArray;
}

var randomArray:Array = randomizeArray(firstArray);
trace(randomArray); // Prints out randomized :)

Answer 4

我有一个替代要求，我想随机地将大量源数组随机插入到目标数组中。和Rytis一样，我是数组上的forEach，map和sort函数的忠实粉丝。

var randomInsert:Function = function callback(item:*, index:int, array:Vector.<MyItem>):void
{
    var j:Number = Math.floor(Math.random() * targetArray.length);
    targetArray.splice(j,0,item);                   
}

targetArray = new Vector.<MyItem>();
sourceArray1.forEach(randomInsert, this);
sourceArray2.forEach(randomInsert, this);

Answer 5

这是一个更容易的功能。也适用于多维数组

function randomizeArray(array:Array):Array
{
    var newArray:Array = new Array();
    while (array.length > 0)
    {
        var mn=Math.floor(Math.random()*array.length)
        newArray[newArray.length]=array[mn]
        array.splice(mn,1)
    }
    return newArray;
}

Answer 6

如果你需要洗牌你的阵列（你的元素不能重复）。你可以使用这个功能：

/**
 * Shuffles array into new array with no repeating elements. Simple swap algorithm is used.
 */
public function shuffleArray(original:Array):Array
{
    // How many swaps we will do
    // Increase this number for better results (more shuffled array, but slower performance)
    const runs:int = original.length * 3;
    var shuffled:Array = new Array(original.length);

    var i:int;
    var a:int;
    var b:int;
    var temp:Object;

    // Copy original array to shuffled
    for(i=0; i<shuffled.length; i++){
        shuffled[i] = original[i];
    }

    // Run random swap cycle 'runs' times
    for(i=0; i<runs; i++){
        // There is a chance that array element will swap with itself,
        // and there is always small probability it will make your shuffle
        // results not that good, hence try to experiment with
        // different runs count as stated above
        a = Math.floor(Math.random() * original.length);
        b = Math.floor(Math.random() * original.length);

        // Swap messages
        temp = shuffled[a];
        shuffled[a] = shuffled[b];
        shuffled[b] = temp;
    }

    return shuffled;
}

用法：

var testArray:Array = ["Water", "Fire", "Air", "Earth"];
trace(shuffleArray(testArray).concat());

Answer 7

这就是我将36张牌的数组随机化为记忆游戏的方法

const QUANT_CARTAS: int = 36;

//get the 36 numbers into the array
for (var i: int = 0; i < QUANT_CARTAS; i++)
{
    cartas.push(i);
}

//shuffles them =)
for (var moeda: int = QUANT_CARTAS - 1; moeda > 0; moeda--)
{
    var pos: int = Math.floor(Math.random() * moeda);
    var carta: int = cartas[moeda];
    cartas[moeda] = cartas[pos];
    cartas[pos] = carta;
}
// and add them using the random order...

    for (i = 0; i < QUANT_CARTAS; i++)
{
    var novaCarta: Carta = new Carta();
    novaCarta.tipoCarta = cartas[i];
    etcetcetc.............
}

Answer 8

从数组中选择随机字符串

echo"_________________"

用法：

echo_________________

as3随机数组 - 随机化数组 - 动作脚本3

8 个答案: