Question

我已经使用了clojure一段时间，但刚刚开始使用core.logic。

鉴于像1 2 3 4这样的域名，我希望得到两个向量的向量，如([[1 2] [3 4]])。

注意：这只是我真正想要做的简化版本。 :)请参阅：https://github.com/adamhoward/lineup

我在网上找到了not-membero的这个定义：

(defne not-membero [x l]
  ([_ []])
  ([_ [?y . ?r]]
    (!= x ?y)
    (not-membero x ?r)))

我正试图像这样使用它：

(run 1 [q]
     (fresh [w x
             y z]
            (== q [[w x]
                   [y z]])
            (infd w x y z (domain 1 2 3 4))
            (everyg distinctfd [[w x] [y z]])
            (everyg #(not-membero % [y z]) [w x])))

在Emacs中运行此操作会给我一条Evaluation aborted.消息。

当我尝试为membero切换not-membero时，我会回到([[1 2] [1 2]])这对我有意义。第一个向量[w x]中的每个元素都是第二个向量[y z]的成员。

但是，当我致电run 2时，我会回来([[1 2] [1 2]] [[1 2] [1 3]])。我不明白[[1 2] [1 3]]对于上述规则是如何正确的。我不能正确理解everyg吗？任何指导（包括rtfmanual，rtfbook，rtfdissertation）将不胜感激。

感谢。

编辑：可能已经解决了这个问题。

仍然不确定来自membero的奇怪结果，但我发现我可以执行此操作而不是not-membero目标：

(everyg #(distinctfd (conj [y z] %)) [w x])

[w x]的每个元素与[y z]共同包含所有不同的值。这可能比非成员效率低，所以我仍然愿意接受任何帮助。

Answer 1

您的示例似乎与此相同：

(run* [q]
  (fresh [w x y z]
    (fd/in w x y z (fd/domain 1 2 3 4))
    (== q [[w x] [y z]])
    (fd/distinct [w x y z])))

但看到足球问题......

(ns test
  (:refer-clojure :exclude [==])
  (:use clojure.core.logic)
  (require [clojure.core.logic.fd :as fd]))

(defn game [g] (fresh [a b c d e] (== g [a b c d e])))

(def players (range 1 11))

(defne not-membero [x l]
  ([_ []])
  ([_ [?y . ?r]]
    (!= x ?y)
    (not-membero x ?r)))

(defne plays [player games]
  ([_ []])
  ([_ [?f ?s . ?r]]
   (membero player ?f) ; if you play this game
   (not-membero player ?s) ; do not play next game
   (plays player ?r))
  ([_ [?f ?s . ?r]]
   (membero player ?s)
   (not-membero player ?f)
   (plays player ?r)))

(defne goalies [games]
  ([[[_ _ _ _ ?a]
     [_ _ _ _ ?b]
     [_ _ _ _ ?c]
     [_ _ _ _ ?d]]]
    (fd/in ?a ?b ?c ?d (apply fd/domain players))
    (not-membero 1 [?a ?b ?c ?d]) ; star player != goalie
    (fd/distinct [?a ?b ?c ?d]))) ; not goalie twice

(defn -main [& args]
  (run 1 [q]
    (fresh [a b c d]
      (game a)
      (game b)
      (game c)
      (game d)
      (== q [a b c d])
      (goalies q)
      (everyg #(plays % q) players))))

将两个向量约束在同一个域中但不是彼此的成员

1 个答案: