Question

我创建了一个自定义Tpanel，在里面我放了各种自定义组件......

procedure Panel_Comp(Location: TWinControl; NumOfComp:     Integer;Left,Top,Height,width:Integer);  
begin  
  MyPanel := TsPanel.Create(Conf);  
  MyPanel.Name := 'MyPanel' + IntToStr(NumOfComp);  
  MyPanel.Parent := Location;  
  MyPanel.Left := Left;  
  MyPanel.Top := Top;  
  MyPanel.Height := Height;  
  MyPanel.Width := width;  
  MyPanel.Caption := '';  
end;

我称之为

Panel_Comp(Conf.ScrollBox1,1,8,10,70,322);

在同样的逻辑中，我把新的面板放在其他自定义组件中，包括tBitbtn，它有一个onclick事件..

procedure BitBtn_Comp(Location: TWinControl; NumOfComp: Integer; Left,Top,Height,Width,ImageNum: Integer);  
begin  
  MyBitBtn := TBitBtn.Create(Conf);  
  ......  
  MyBitBtn.tag := NumOfComp;  
  MyBitBtn.OnClick:= Conf.CloseCurrentPanel;
end;

主要Forn The TConf.CloseCurrentPanel;

procedure TConf.CloseCurrentPanel(Sender: TObject);  
var  
  panelComp: TComponent;  
begin  
  panelComp := FindComponentEx('Conf.MyPanel'+ IntToStr(TBitBtn(Sender).tag);
  TPanel(panelComp).Free;
  Application.ProcessMessages;  
end;

当我打电话说我遭到访问违规时...... 我认为在释放面板之前我必须释放面板内的所有组件，但是如何在面板之前释放BitBtn并继续执行click事件？

这是FindComponetEx函数而不是你需要它......

function FindComponentEx(const Name: string): TComponent;  
var  
  FormName: string;  
  CompName: string;  
  P: Integer;  
  Found: Boolean;  
  Form: TForm;  
  I: Integer;  
begin  
// Split up in a valid form and a valid component name  
  P := Pos('.', Name);  
  if P = 0 then  
  begin  
    raise Exception.Create('No valid form name given');  
  end;  
  FormName := Copy(Name, 1, P - 1);  
  CompName := Copy(Name, P + 1, High(Integer));  
  Found    := False;    
  // find the form  
  for I := 0 to Screen.FormCount - 1 do  
    begin  
      Form := Screen.Forms[I];  
   // case insensitive comparing  
      if AnsiSameText(Form.Name, FormName) then  
        begin  
          Found := True;  
          Break;  
        end;  
    end;  
  if Found then  
    begin  
      for I := 0 to Form.ComponentCount - 1 do  
        begin  
          Result := Form.Components[I];  
         if AnsiSameText(Result.Name, CompName) then Exit;  
        end;  
     end;  
  Result := nil;  
end;

Answer 1

AV的发生是因为您在处理Windows消息时正在销毁组件（MyBitBtn）。解决方案是通过PostMessage将销毁推迟到以后，类似于：

unit Unit1;

interface

uses
  Windows,
  Messages,
  SysUtils,
  Variants,
  Classes,
  Graphics,
  Controls,
  Forms,
  Dialogs,
  ExtCtrls,
  StdCtrls;

const
  UM_DESTROYPANEL = WM_APP + 623; // some "unique" number; UM = user message

type
  TConf = class(TForm)
    Panel1: TPanel;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  strict private
    procedure UMDestroyPanel(var Message: TMessage); message UM_DESTROYPANEL;
  public
    { Public-Deklarationen }
  end;

var
  Conf: TConf;

implementation

{$R *.dfm}

procedure TConf.Button1Click(Sender: TObject);
begin
  PostMessage(Handle, UM_DESTROYPANEL, 0, 0);
end;

procedure TConf.UMDestroyPanel(var Message: TMessage);
begin
  Panel1.Free;
end;

end.

如果需要，您可以使用wParam和lParam来传递如下参数：

procedure TConf.Button1Click(Sender: TObject);
begin
  PostMessage(Handle, UM_DESTROYPANEL, WPARAM(Panel1), 0);
end;

procedure TConf.UMDestroyPanel(var Message: TMessage);
begin
  TObject(Message.WParam).Free;
end;

修改在你的情况下，我可能会像这样重写TConf.CloseCurrentPanel：

procedure TConf.CloseCurrentPanel(Sender: TObject); var panelComp: TComponent; begin panelComp := FindComponentEx('Conf.MyPanel'+ IntToStr(TBitBtn(Sender).Tag); PostMessage(Handle, UM_DESTROYPANEL, WPARAM(panelComp), 0); end;

或者你可以通过标签（可能是更好的解决方案，因为涉及的投射更少）：

procedure TConf.CloseCurrentPanel(Sender: TObject); begin PostMessage(Handle, UM_DESTROYPANEL, TBitBtn(Sender).Tag, 0); end; procedure TConf.UMDestroyPanel(var Message: TMessage); var panelComp: TComponent; begin panelComp := FindComponentEx('Conf.MyPanel'+ IntToStr(Message.WParam)); panelComp.Free; end;

AFAICT不需要Application.ProcessMessages。

Answer 2

procedure TConf.CloseCurrentPanel(Sender: TObject);   
var     
   panelComp: TComponent;   
 begin     
   panelComp := FindComponentEx('Conf.MyPanel'+ IntToStr(TBitBtn(Sender).tag);  
   //Where you need to determine 'PanelComp' if there are.
   if Assigned(panelComp) and (PanelComp is TPanel) then
     TPanel(panelComp).Free;  
   Application.ProcessMessages;   
end;

我如何释放一个有TbitBtn的Tpanel，它可以调用Tpanel来释放它

2 个答案: