Question

输入：

<text>
    Please see the registered mark® .
    Please see the copy right ©.
    Please see the Trade mark™.
</text>

输出：

  <text>
        Please see the registered mark<registeredTrademark></registeredTrademark>.
        Please see the copy right <copyright></copyright>.
        Please see the Trade mark <trademark></trademark>.
  </text>

我需要用如上所示的元素替换所有特殊符号

任何人都可以提供帮助。

由于

Answer 1

由于这是XSLT 1.0，您将不得不使用递归命名模板依次检查每个字符。

首先，在XSLT中创建一种“查找”可能更灵活，您可以在其中指定符号列表和所需的元素名称以替换它们

<lookup:codes>
  <code symbol="®">registeredTrademark</code>
  <code symbol="©">copyright</code>
  <code symbol="™">trademark</code>
</lookup:codes>

（'lookup'命名空间实际上可以命名为任何东西，只要在XSLT中声明它就可以了。）

然后，要访问它，您可以定义一个变量来访问此查找

<xsl:variable name="lookup" select="document('')/*/lookup:codes"/>

而且，查找基于符号的实际代码会执行类似这样的操作（其中$ text）是包含您正在检查的文本的变量。

  <xsl:variable name="char" select="substring($text, 1, 1)"/>
  <xsl:variable name="code" select="$lookup/code[@symbol = $char]"/>

所有命名的模板都会这样做，检查文本的第一个字符，如果它在查找中存在，则将其替换为元素，然后以文本的剩余部分递归调用模板。

这是完整的XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:lookup="lookup" exclude-result-prefixes="lookup">
   <xsl:output method="xml" indent="no"/>

   <lookup:codes>
      <code symbol="®">registeredTrademark</code>
      <code symbol="©">copyright</code>
      <code symbol="™">trademark</code>
   </lookup:codes>

   <xsl:variable name="lookup" select="document('')/*/lookup:codes"/>

   <xsl:template match="text[text()]">
      <text>
         <xsl:call-template name="text"/>
      </text>
   </xsl:template>

   <xsl:template name="text">
      <xsl:param name="text" select="text()"/>
      <xsl:variable name="char" select="substring($text, 1, 1)"/>
      <xsl:variable name="code" select="$lookup/code[@symbol = $char]"/>
      <xsl:choose>
         <xsl:when test="$code"><xsl:element name="{$code}" /></xsl:when>
         <xsl:otherwise>
            <xsl:value-of select="$char"/>
         </xsl:otherwise>
      </xsl:choose>
      <xsl:if test="string-length($text) &gt; 1">
         <xsl:call-template name="text">
            <xsl:with-param name="text" select="substring($text, 2, string-length($text) - 1)"/>
         </xsl:call-template>
      </xsl:if>
   </xsl:template>

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

当应用于您的示例XML时，输出以下内容

<text> 
    Please see the registered mark<registeredTrademark /> . 
    Please see the copy right <copyright />. 
    Please see the Trade mark<trademark />. 
</text>

Answer 2

通过避免char-by-char递归和使用“最大可能步骤”递归，这种转换更有效：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <my:reps>
  <r char="®">registeredTrademark</r>
  <r char="©">copyright</r>
  <r char="™">trademark</r>
 </my:reps>

 <xsl:variable name="vReps" select="document('')/*/my:reps/*"/>

 <xsl:template match="text()" name="multReplace">
  <xsl:param name="pText" select="."/>
  <xsl:param name="pReps" select="$vReps"/>

   <xsl:if test="$pText">
     <xsl:variable name="vTarget" select="$pReps[1]/@char"/>
       <xsl:choose>
         <xsl:when test="not($vTarget)">
           <xsl:value-of select="$pText"/>
         </xsl:when>
         <xsl:otherwise>
           <xsl:variable name="vReplacement" select="$pReps[1]"/>

           <xsl:call-template name="multReplace">
            <xsl:with-param name="pText" select=
            "substring-before(concat($pText, $vTarget), $vTarget)"/>
            <xsl:with-param name="pReps" select="$pReps[position() >1]"/>
           </xsl:call-template>

           <xsl:if test="contains($pText, $vTarget)">
             <xsl:element name="{$vReplacement}"/>
             <xsl:call-template name="multReplace">
              <xsl:with-param name="pText" select="substring-after($pText, $vTarget)"/>
              <xsl:with-param name="pReps" select="$pReps"/>
             </xsl:call-template>
           </xsl:if>
         </xsl:otherwise>
       </xsl:choose>
   </xsl:if>
 </xsl:template>
</xsl:stylesheet>

应用于提供的XML文档：

<text>
        Please see the registered mark® .
        Please see the copy right ©.
        Please see the Trade mark™.
</text>

生成了正确替换的文字：

    Please see the registered mark<registeredTrademark/> .
    Please see the copy right <copyright/>.
    Please see the Trade mark<trademark/>.

用xslt中的元素替换版权符号和其他符号

2 个答案: