Question

我目前正在使用CMake构建我的项目，并使用CppUnit来测试它。在我的CMake文件中，我创建了两个可执行文件。 sample是已编译的源本身。使用sample_test我运行测试。如果我

这是CMakeLists.txt

的一部分

SET(SAMPLE_ROOT_PATH ${PROJECT_BINARY_DIR})
SET(SAMPLE_SOURCE_PATH ${SAMPLE_ROOT_PATH}/src)
SET(SAMPLE_TEST_SOURCE_PATH ${SAMPLE_ROOT_PATH}/test)
SET(SAMPLE_BIN_PATH ${SAMPLE_ROOT_PATH}/bin)
SET(SAMPLE_EXEC_NAME sample)
SET(SAMPLE_TEST_EXEC_NAME sample_test)

SET(EXECUTABLE_OUTPUT_PATH ${SAMPLE_BIN_PATH})

FILE(GLOB_RECURSE SAMPLE_SOURCE_FILES ${SAMPLE_SOURCE_PATH}/*.cpp)
FILE(GLOB_RECURSE SAMPLE_TEST_SOURCE_FILES ${SAMPLE_TEST_SOURCE_PATH}/*.cpp)
SET(SAMPLE_TEST_SOURCE_FILES ${SAMPLE_TEST_SOURCE_FILES} ${SAMPLE_SOURCE_FILES}
)
LIST(REMOVE_ITEM SAMPLE_TEST_SOURCE_FILES ${SAMPLE_SOURCE_PATH}/main.cpp)

SET(CMAKE_CXX_FLAGS "-g -Wall")

ADD_EXECUTABLE(${SAMPLE_EXEC_NAME} ${SAMPLE_SOURCE_FILES})
ADD_EXECUTABLE(${SAMPLE_TEST_EXEC_NAME} ${SAMPLE_TEST_SOURCE_FILES})

这是make

的输出

[  8%] Building CXX object CMakeFiles/sample.dir/src/KeyBuffer.cpp.obj
[ 12%] Building CXX object CMakeFiles/sample.dir/src/main.cpp.obj
[ 20%] Building CXX object CMakeFiles/sample.dir/src/Object.cpp.obj
[ 45%] Building CXX object CMakeFiles/sample.dir/src/World.cpp.obj
Linking CXX executable bin/sample.exe
[ 45%] Built target sample
[ 50%] Building CXX object CMakeFiles/sample_test.dir/test/KeyBufferTest.cpp.obj

[ 54%] Building CXX object CMakeFiles/sample_test.dir/test/ObjectTest.cpp.obj
[ 66%] Building CXX object CMakeFiles/sample_test.dir/src/KeyBuffer.cpp.obj
[ 75%] Building CXX object CMakeFiles/sample_test.dir/src/Object.cpp.obj
[100%] Building CXX object CMakeFiles/sample_test.dir/src/World.cpp.obj
Linking CXX executable bin/sample_test.exe

您可以看到Object.cpp，World.cpp和KeyBuffer.cpp被编译两次！我怎么能阻止它？或者有更好的方法来使用CMake处理CppUnit测试吗？

Answer 1

每个目标可能配置了不同的编译器标志，因此如果您将一个源文件添加到两个目标，则需要从这两个目标的源文件生成单独的目标文件。

通常的解决方案是将共享源文件编译成静态库，然后将其链接到两个应用程序目标。

add_library(base STATIC ${shared_SOURCES}) # except e.g. foo_main.cpp

add_executable(foo ${foo_only_SOURCES})
target_link_libraries(foo base)

add_executable(bar ${bar_only_SOURCES})
target_link_libraries(bar base)

Answer 2

从概念上讲，CMake将每个目标（即可执行文件或库）视为单独的构建单元。生成的构建系统将为属于目标的每个源文件生成目标文件。默认情况下，即使编译设置（编译标志，预处理器定义......）完全相同，CMake也不会避免多个目标中使用的源文件的冗余编译。

CMake 2.8.8引入了new feature名为OBJECT_LIBRARY的目标，以解决避免冗余编译的问题：

要生成对象库，请使用add_library：

FILE(GLOB_RECURSE SAMPLE_SOURCE_FILES ${SAMPLE_SOURCE_PATH}/*.cpp)
ADD_LIBRARY(sample_objects OBJECT EXCLUDE_FROM_ALL ${SAMPLE_SOURCE_FILES})

add_library或add_executable创建的其他目标可以使用$<TARGET_OBJECTS:objlib>形式的表达式引用对象：

ADD_EXECUTABLE(${SAMPLE_EXEC_NAME} $<TARGET_OBJECTS:sample_objects>)

FILE(GLOB_RECURSE SAMPLE_TEST_SOURCE_FILES ${SAMPLE_TEST_SOURCE_PATH}/*.cpp)
ADD_EXECUTABLE(${SAMPLE_TEST_EXEC_NAME} $<TARGET_OBJECTS:sample_objects> ${SAMPLE_TEST_SOURCE_FILES})

与使用常规静态库避免冗余编译相比，对象库的优点是不需要链接。最重要的是，它无法导入，导出或安装。

CppUnit和CMake：.cpp文件被编译两次

2 个答案: