Question

我在Outlook中有以下VBA代码，用于将邮件移动到个人文件夹（如果它已经过时）。这是代码：

我在Next objItem行上看到一个异常（看着手表没有设置）。

什么会导致objItem为null并因此在 Next objItem 行中导致类型不匹配异常？

Sub MoveOldMailFromInbox()

Dim objFolder As Outlook.MAPIFolder
Dim objNS As Outlook.NameSpace, objItem As Outlook.MailItem, mail As Outlook.MailItem

Set objNS = Application.GetNamespace("MAPI")

Dim Inbox As MAPIFolder
Set Inbox = objNS.GetDefaultFolder(olFolderInbox)

Dim mailToMove As New Collection

Dim EightyFiveDaysAgo As Date
EightyFiveDaysAgo = DateAdd("d", -85, Date)

Set objFolder = objNS.Folders("PersonalFolders").Folders("InboxOlderThan85Days")
If objFolder Is Nothing Then
    MsgBox "This folder doesn't exist!", vbOKOnly + vbExclamation, "INVALID FOLDER"
End If

For Each objItem In Inbox.Items
    If objFolder.DefaultItemType = olMailItem Then

        If objItem.Class = olMail And objItem.ReceivedTime < EightyFiveDaysAgo Then

            mailToMove.Add objItem

        End If
    End If
Next objItem


For Each mail In mailToMove
    mail.UnRead = False
    mail.Move objFolder
Next mail

Set objItem = Nothing
Set objFolder = Nothing
Set objNS = Nothing

End Sub

Answer 1

您正在遍历Inbox.Items，但您的变量objItem被定义为MailItem - 收件箱中的项目可能并不总是MailItem。

尝试

Dim objItem as Object

当收件箱中的项目声明为mailitems时，键入Mismatch错误

1 个答案: