Question

我有如下所示的XML：

    <w:body>
   <w:p>
    <w:pPr>
       <w:pStyle w:val="paragraph"/>
     </w:pPr>
  <w:r><w:t>1274394 The milk costs , $1.99 [12] test Figure 1</w:t></w:r>
</w:p>
 <w:p>
  <w:pPr>
  <w:pStyle w:val="paragraph"/>
  </w:pPr>
  <w:r><w:t>sample text Figure 1 and [1]</w:t></w:r>
</w:p>
</w:body>

我想用XSLT获得如下输出：

<w:body>
 <w:p>
  <w:pPr>
     <w:pStyle w:val="paragraph"/>
  </w:pPr>
  <w:r><w:t>1274394 The milk costs , $1.99 <ref>[12]</ref> test <fig>Figure 1</fig></w:t></w:r>
</w:p>
<w:p>
  <w:pPr>
  <w:pStyle w:val="paragraph"/>
  </w:pPr>
 <w:r><w:t>sample text <fig>Figure 1</fig> and <ref>[1]</ref></w:t></w:r>
</w:p>
</w:body>

我的XSLT是：

<xsl:template match="w:p[w:pPr/w:pStyle/@w:val='paragraph']//text()">
<xsl:param name="figregex">
  <xsl:text>(Figure)\p{Zs}([0-9]{1,2})</xsl:text>
</xsl:param>
<xsl:param name="matchedRegex">
  <xsl:text>(\[)([0-9]{1,2})(\])</xsl:text>
</xsl:param>
<xsl:variable name="fig-first" select="&quot;&lt;fig&gt;&quot;"/>
<xsl:variable name="fig-sec" select="&quot;&lt;/fig&gt;&quot;"/>
<xsl:variable name="r-first" select="&quot;&lt;ref&gt;&quot;"/>
<xsl:variable name="r-sec" select="&quot;&lt;/ref&gt;&quot;"/>
<xsl:analyze-string select="." regex="{$matchedRegex} | {$figregex} ">
<xsl:matching-substring>
<xsl:if test="matches(., $figregex)" >
    <xsl:value-of select="$fig-first" disable-output-escaping="yes"/><xsl:value-of select="."/>
    <xsl:value-of select="$fig-sec" disable-output-escaping="yes"/>
</xsl:if>
  <xsl:if test="matches(., $matchedRegex)" >
    <xsl:value-of select="$r-first" disable-output-escaping="yes"/><xsl:value-of select="."/>
    <xsl:value-of select="$r-sec" disable-output-escaping="yes"/>
  </xsl:if>
  </xsl:matching-substring>
  <xsl:non-matching-substring>
    <xsl:value-of select="."/>
  </xsl:non-matching-substring>
</xsl:analyze-string>
 </xsl:template>

它的工作正常，但如果两个都存在于同一行，则前面的第一个被转换。谁可以帮我这个事？我得到的输出是：

<w:body>
 <w:p>
  <w:pPr>
     <w:pStyle w:val="paragraph"/>
  </w:pPr>
  <w:r><w:t>1274394 The milk costs , $1.99 <ref>[12] </ref>test Figure 1</w:t></w:r>
 </w:p>
 <w:p>
  <w:pPr>
  <w:pStyle w:val="paragraph"/>
  </w:pPr>
  <w:r><w:t>sample text<fig> Figure 1 </fig>and [1]</w:t></w:r>
  </w:p>
 </w:body>

Answer 1

此XSLT 2.0样式表......

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:fn="http://www.w3.org/2005/xpath-functions"
  xmlns:w="www"
  exclude-result-prefixes='xsl fn'>
<xsl:output method="xml" indent="yes"/>

<xsl:template match="@*|node()">
 <xsl:copy>
  <xsl:apply-templates select="@*|node()"/>
 </xsl:copy>
</xsl:template>

<xsl:template match="w:t/text()">
 <xsl:variable name="phase1">
  <xsl:apply-templates select="." mode="fig" />
 </xsl:variable>
  <xsl:apply-templates select="$phase1" mode="ref" />
</xsl:template>


<xsl:template match="text()" mode="fig">
 <xsl:analyze-string select="." regex="Figure (\d{{1,2}})">
 <xsl:matching-substring>
  <fig>
   <xsl:value-of select="." />
  </fig>
 </xsl:matching-substring>
 <xsl:non-matching-substring>
  <xsl:value-of select="." />
 </xsl:non-matching-substring>
 </xsl:analyze-string>
</xsl:template>

<xsl:template match="text()" mode="ref">
 <xsl:analyze-string select="." regex="\[(\d{{1,2}})\]">
 <xsl:matching-substring>
  <ref>
   <xsl:value-of select="." />
  </ref>
 </xsl:matching-substring>
 <xsl:non-matching-substring>
  <xsl:value-of select="." />
 </xsl:non-matching-substring>
 </xsl:analyze-string>
</xsl:template>

<xsl:template match="@*|*|comment()|processing-instruction()" mode="ref">
 <xsl:copy>
  <xsl:apply-templates select="@*|node()" mode="ref"/>
 </xsl:copy>
</xsl:template>

</xsl:stylesheet>

...会将示例输入转换为...

<w:body xmlns:w="www">
    <w:p>
        <w:pPr>
            <w:pStyle w:val="paragraph"/>
        </w:pPr>
        <w:r>
            <w:t>1274394 The milk costs , $1.99 <ref>[12]</ref> test <fig>Figure 1</fig>
         </w:t>
        </w:r>
    </w:p>
    <w:p>
        <w:pPr>
            <w:pStyle w:val="paragraph"/>
        </w:pPr>
        <w:r>
            <w:t>sample text <fig>Figure 1</fig> and <ref>[1]</ref>
         </w:t>
        </w:r>
    </w:p>
</w:body>

备注

此样式表使用管道设计。第一阶段（'fig'）处理图模式，第二阶段（'ref'）处理ref模式。
这不是唯一的好解决方案。使用通用命名模板而不是ref和fig模式模板将是安静可行的，甚至可能更紧凑。其他一些Stackie可能会接受挑战并展示更简单的一次通过解决方案。
除非确实需要，否则尽量不要使用disable-output-escaping。在这样做时，您放弃了XSLT的许多功能。它类似于使用SQL表达式生成数据集，但随后使用一些汇编代码来计算其中一个列输出。
使用文字正则表达式时，请记住双重转义curlies。

在xslt中进行多次替换

1 个答案:

备注