Question

所以我正在尝试为使用d3.js，polymaps和Coffeescript的项目做一些地图标记聚类。

我根据底层数据计算集群，然后将集群阵列作为.data（集群）传递给d3

群集的位置似乎没问题。初始缩放级别的聚类似乎没问题，根据我的知识，它是100％准确的。当我改变缩放级别时，乍一看似乎一切正常，但是当我将鼠标悬停在圆圈上时，描述似乎与它们所处的位置不匹配，并且之前的路线位置似乎与它们的位置不匹配现在。

我在http://bl.ocks.org/3161013准备了一个包含完整代码的示例。

我看到两个主要的失败点：聚类和更新SVG。

集群的代码非常简单，基于Mark Tuupola的代码，但是在coffeescript而不是php中。

  cluster: (elements, distance) ->
    currentElements = elements.slice(0)
    pixelDistance = @pixelDistance()
    distLat = distance * pixelDistance.lat
    distLon = distance * pixelDistance.lon 

    clustered = []
    while currentElements.length > 0
      stop = currentElements.shift()

      cluster = []
      cluster.push stop

      i = 0
      while i < currentElements.length
        if Math.abs(currentElements[i].lat - stop.lat) < distLat and Math.abs(currentElements[i].lon - stop.lon) < distLon
          aStop = currentElements.splice i,1
          cluster.push aStop[0]
          i--
        i++
      clustered.push cluster  
    clustered

SVG更新的代码似乎是相当简单的d3代码。移动地图时，将调用此更新方法。如果缩放已更改，或预聚类数据已更改，我们将重新聚类和布局，否则我们只是翻译现有点。

  update: ->
    if not @stops
      @stops = []

    if not @prevNumStops
      @prevNumStops = 0

    if not @prevZoom
      @prevZoom = 0


    if @zoomLevel() != @prevZoom or @prevNumStops != @stops.length
      @prevZoom = @zoomLevel()
      @prevNumStops = @stops.length 

      start = new Date()
      @clusters = @cluster(@stops,10)
      console.log @clusters
      console.log "clustering: " + ((new Date()) - start)

      start = new Date()
      marker = @selector.selectAll("g").data(@clusters)
      marker.enter().append("g")
      .append("circle")
      .attr("class", "stop no-tip")
      marker.exit().remove()
      @selector.selectAll("g").selectAll("circle")
      .attr('r', (cluster) -> if cluster.length > 1 then 5 else 3.5)
      .attr("text", (cluster) -> "<ul>" + ((("<li>" + route + "</li>") for route in stop.routes).join("") for stop in cluster).join("") + "</ul>")

    @selector.selectAll("g").attr("transform", (cluster) => 
      @transform cluster[0]
    )

我觉得这里可能很容易让我失踪，但我仍然是d3的新手。

Answer 1

当数据发生变化时，现有标记内的“圆”元素不会更新（d3使用每个默认值的索引来确定是否添加（输入），删除（退出）或更新（默认）新元素）。这会使文本成为该缩放级别上已存在的所有元素的上一个缩放级别的旧文本。

它应该使用以下代码：

marker = @selector.selectAll("g").data(@clusters)

# update existing 'g' elements
marker.select('circle')
.attr('r', your_cluster_size_function)
.attr("text", your_text_function)


# add new 'g' elements
marker.enter().append("g")
.append("circle")
.attr("class", "stop no-tip")
.attr('r', your_cluster_size_function)
.attr("text", your_text_function)

# remove 'g' elements if there are too many
marker.exit().remove()

在d3.js中聚类SVG元素会产生意外结果

1 个答案: