Question

我在xml中有一个像integer =“1,2,3,4,5”的值。如何使用XSLT计算总数。因此，输出给我的计数为5

此致萨姆

Answer 1

这是一种方式（可能还有其他方式）。只需将所有逗号转换为空字符串，然后比较字符串长度的差异：

<xsl:value-of 
   select="string-length(@integer) 
           - string-length(translate(@integer, ',', '')) + 1" />

如果您需要处理空字符串，请尝试使用

<xsl:value-of 
  select="string-length(@integer) 
          - string-length(translate(@integer, ',', '')) 
          + 1 * (string-length(@integer) != 0)" />

Answer 2

如果要计算逗号分隔值，但也可以引用各个项目，则可以使用这样的递归模板。

这个XSLT 1.0样式表会将逗号分隔值转换为节点，然后计算它们......

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt">
<xsl:output method="text"/>

<xsl:template match="/">
 <xsl:variable name="as-nodes"> 
  <xsl:call-template name="parse-comma-separated-values">
   <xsl:with-param name="csv" select="t/@csv" />
  </xsl:call-template>
  </xsl:variable>
  <xsl:value-of select="count(msxsl:node-set($as-nodes)/*)" />
</xsl:template>

<xsl:template name="parse-comma-separated-values">
 <xsl:param name="csv" />
 <xsl:choose>
   <xsl:when test="$csv = ''"/>
   <xsl:when test="not( contains( $csv, ','))">
     <value-node value="{$csv}" /> 
   </xsl:when>  
   <xsl:otherwise>
     <value-node value="{substring-before($csv,',')}" /> 
     <xsl:call-template name="parse-comma-separated-values">
      <xsl:with-param name="csv" select="substring-after($csv,',')"/>
     </xsl:call-template>  
   </xsl:otherwise>  
  </xsl:choose>  
</xsl:template>

</xsl:stylesheet>

...当应用于此输入文档时......

 <t csv="1,2,3,4,5"/>

...生产......

XSLT计数逗号值计数

2 个答案: