Question

我正在编写一个库，用于将许多类型的几何体（球体，平面，NURBS曲面，stl文件......）导入到科学的Fortran代码中。这种问题似乎是为OOP而制定的，因为定义type :: geom然后type,extends(geom) :: analytic等等很简单。我遇到问题的部分是文件IO。

此时我的解决方案是编写定义形状的参数，包括一些告诉我它是哪种形状的标志。在阅读时，我实例化一个class(geom) :: object，（因为我不知道它将是哪个子类型），但我该怎么读呢？

我无法访问子类型的任何特定组件。我读到，向下转换是 verboten ，此外，新的allocate(subtype :: class)似乎不起作用。新的READ(FORMATTED)似乎不是由ifort或gfortran实现的。即。

module geom_mod
  type :: geom
  end type
  type,extends(geom) :: sphere
    integer :: type
    real(8) :: center(3),radius
   contains
    generic :: READ(FORMATTED)=> read_sphere ! not implemented anywhere
  end type
contains
  subroutine read_geom(object)
    class(geom),intent(out),pointer :: object     
    integer :: type

    read(10,*) object%type   ! can't access the subtype data yet

    read(10,*) type
    backspace(10)
    if(type==1) then
      allocate(sphere :: object)! downcast?
      read(10,*) object         ! doesn't work
    end if 

  end read_geom
end module

我是否认为这一切都错了？我可以使用多态之外的其他东西破解它，但这在其他地方看起来更干净。非常感谢协助。

编辑：使用IanH模块的示例程序

program test
  use geom_mod
  implicit none
  class(geom),allocatable :: object

  open(10)
  write(10,*) '1'
  write(10,*) sphere(center=0,radius=1)
  rewind(10)

  call read(object) ! works !
end program test

Answer 1

当前的gfortran和ifort没有实现定义的输入/输出。我没有看到任何证据表明这种情况在不久的将来会发生变化。但是，除了允许一些语法快捷方式之外，这个功能实际上并没有为你节省太多工作。

这种情况的一种方法是调用“工厂”来扩展geom，使用文件中的数据将参数分配给正确的类型，然后切换到读取类型特定数据的类型绑定过程。例如：

module geom_mod
  implicit none
  integer, parameter :: dp = kind(1.0d0)
  type, abstract :: geom
  contains
    procedure(read_geom), deferred :: read
  end type geom

  abstract interface
    subroutine read_geom(object)
      import :: geom
      implicit none
      class(geom), intent(out) :: object
    end subroutine read_geom
  end interface

  type, extends(geom) :: sphere
    real(dp) :: center(3), radius
  contains
   procedure :: read => read_sphere
  end type sphere
contains
  subroutine read(object)
    class(geom), intent(out), allocatable :: object
    integer :: type
    read (10, *) type
    ! Create (and set the dynamic type of object) based on type.
    select case (type)
    case (1)     ; allocate(sphere :: object)
    case default ; stop 'Unsupported type index'
    end select
    call object%read
  end subroutine read

  subroutine read_sphere(object)
    class(sphere), intent(out) :: object
    read (10, *) object%center, object%radius
  end subroutine read_sphere
end module geom_mod

当前ifort（12.1.5）存在可能需要解决方法的intent（out）多态参数问题，但一般方法保持不变。

（注意子程序读取不是类型绑定子程序 - 在常规子程序引用样式中读取通用geom对象使用''call read（object）'）。

在Fortran中使用多态数据类型的文件IO

1 个答案: